如何判斷一檔股票可以長抱?

By | 2018-03-05
0 Comment
分享

如何判斷一檔股票可以長抱，而不會只賺個三五毛就被洗掉。書上的建議是尋找大型股，外資持股高的股票。我自己挑長抱股票的邏輯則是， 每年有一定的獲利與配息，且月營收年增率12個月移動平均維持在零以上的，至於進場的法則，我用的是如果九十天跌超過三成就進場。

 

營收年增率12個月移動平均維持在零以上的腳本如下

value1=GetField("月營收年增率","M");

if average(value1,12)>=0
then ret=1;

綜合的選股條件如下表

2018030401

我昨天選出來符合條件的股票如下

2018030402

接下來我把這個選股法存成每日選股清單，然後用綜合抄底法這個腳本來跑策略雷達

if close*1.3<highest(close,90)then begin
variable:count(0);
count=0;
//之前無長紅，最近兩根長紅
input:ratio(5,"長紅的漲幅下限");
if countif(close[5]>=close[6]*(1+ratio/100),60)=0
and countif(close>=close[1]*(1+ratio/100),5)>=2
then count=count+1;

//均線糾結後上漲
input: s1(5,"短期均線期數");
input: s2(10,"中期均線期數");
input: s3(20,"長期均線期數");
input: Percent(2,"均線糾結區間%");
input: Volpercent(25,"放量幅度%");
//帶量突破的量是超過最長期的均量多少%
variable: shortaverage(0);
variable: midaverage(0);
variable: Longaverage(0);

if volume > average(volume,s3) * (1 + volpercent * 0.01)
//放量25%
and lowest(volume,s3)<1000
//區間最低量小於一千張
and volume>2000
//今日成交量突破2000張
then begin
shortaverage = average(close,s1);
midaverage = average(close,s2);
Longaverage = average(close,s3);
value1= absvalue(shortaverage -midaverage);
value2= absvalue(midaverage -Longaverage);
value3= absvalue(Longaverage -shortaverage);
value4= maxlist(value1,value2,value3);
if value4*100 < Percent*Close
and linearregangle(value4,5)<10
then count=count+1;
end;
//低檔五連陽
if trueall(close>open,5) 
then condition3=true;
//急拉
value11=barslast(close>=close[1]*1.07);
if value11[1]>50
//超過50天沒有單日上漲超過7%
and value11=0
//今天上漲超過7%
and average(volume,100)>500
and volume>1000
then count=count+1;
//連續跳空上漲

if countif(open > close[1],5)>=3
//過去五天有三天以上開盤比前一天收盤高
and average(volume,5)>2000
//五日均量大於2000張
then count=count+1;

//連續多日價量回溫
input:period(5,"回溫期數");
value21=GetField("資金流向");
value22=GetField("強弱指標","D");
if countif(value21>value21[1]and value22>0,period)>= 4
and volume>average(volume,20)*1.3
then count=count+1;

//主力回頭收集
input:period1(20);
value31=GetField("分公司賣出家數")[1];
value32=GetField("分公司買進家數")[1]; 
if linearregslope(value31,period1)>0
//賣出的家數愈來愈多
and linearregslope(value32,period1)<0
//買進的家數愈來愈少
and 
close*1.03<close[1]
//今天又跌超過3%
 
then count=count+1;

//三長下影線
input: Percent1(1.5,"下影線佔股價絕對百分比");
settotalbar(5);
condition1 = (minlist(open,close)-Low) > absvalue(open-close)*3; 
//下影線的長度是實體的三倍以上
condition2 = minlist(open, close) > low* (100 + Percent1)/100;
//下影線的幅度超過股價的1.5%
if countif( condition1 and condition2, 5)>=3
//最近五天有三天有長下影線
and close[20]> close[2]*1.1
//到前天為止的前二十天跌幅超過一成
and close>10
and volume>1000
then count=count+1;

if count>=1 then ret=1;
end;

出場則是跌破季線後出場，這樣去回測，勝率不錯，大抵可以維持在六成左右。

除了上述的條件之外，通常我會另外再觀察其毛利率是否有明顯的衰退，或是法人是否賣超來當作輔助的參考標準。

 

 

 

分享