對產業景氣更敏感的偵測工具： 產業整體營收月增率

By | 2025-09-03
0 Comment
分享

產業整體營收月增率，如果連續數月上昇，代表整體景氣很明確的處於復甦狀態，連續數月下跌，代表整體產業進入衰退期，大部份的時候，月營收月增率總是漲漲跌跌，所以連續性的上漲或下跌，就變的很值得注意。

整體產業月營收的畫指標腳本樣本如下

input: _calcType(1, "計算方式", inputkind:=Dict(["加權平均",1],["簡單平均",2]), quickedit:=true);
Group: _group();
var: _i(0), _size(0), _lastestMonth(0);

var: _sumEarning(0), _earningCount(0), _avgEarning(0);
var: _sumWeightedEarning(0),_sumCapital(0);

_group = GetSymbolGroup("成份股");

// 檢查是否有資料
// 
_size = GroupSize(_group);
if _size = 0 then return;

// 迴圈運算前，初始化變數
// 
_sumEarning = 0;
_sumWeightedEarning = 0;
_sumCapital = 0;
_lastestMonth = 0;
_earningCount = 0;

// 迴圈計算每一檔成份股數值
// 
for _i = 1 to _size begin //大迴圈會跑遍每一檔成份股
if CheckSymbolField(_group[_i], "Close") then begin //確認股票當天有資料

// 實際要計算的內容===開始===
//

// STEP 1 換期時數值歸零
if GetSymbolFieldDate(_group[_i], "月營收月增率", "M") > _lastestMonth then begin //如果成份股有人提前公佈數值，目前計算的都歸零
_lastestMonth = GetSymbolFieldDate(_group[_i], "月營收月增率", "M");
_earningCount = 0;
_sumEarning = 0;
_sumWeightedEarning = 0;
_sumCapital = 0;
end;

// STEP 2 同樣期別時，數值計算
if GetSymbolFieldDate(_group[_i], "月營收月增率", "M") = _lastestMonth then begin //依最新的資料期別進行統計
_earningCount = _earningCount + 1;
_sumEarning = _sumEarning + GetSymbolField(_group[_i], "月營收月增率", "M");
_sumCapital = _sumCapital + GetSymbolField(_group[_i], "股本(億)", "D");
_sumWeightedEarning = _sumWeightedEarning + GetSymbolField(_group[_i], "股本(億)", "D") * GetSymbolField(_group[_i], "月營收月增率", "M");
end;

// 實際要計算的內容===結束===
//

end; 
end;

if _calcType = 2 then
_avgEarning = _sumEarning / _earningCount
else
_avgEarning = _sumWeightedEarning / _sumCapital;

// 要繪製的指標
// 
plot(1, _avgEarning, "月營收月增率");

 

把這個腳本應用到細產業指標裡，呈現的畫面如下圖

這個指標對景氣循環股是有其參考價值

 

 

 

分享