Author Archives: 發財橘子

下切線突破是一個型態學上，很常見的買進訊號，特別是如果這樣的突破，搭配著外資，投信站在買方，且近一日主力買超佔成交量達到一定的水準，更值得注意。

下切線突破的腳本如下

input:in1(60,"計算區間"),in2(false,"嚴格模式");
settotalBar(in1*2);
//尋找不同區間大小下目測所認為的高點。
value1=highest(H,in1);//找出一定區間的高點
if value1>value1[1] then value2=value1;
//如果高點變高則保留高點，這樣做的原因是可以找到一波下降之後的高點
condition1 = value2=value2[1];
//條件:保留之高點維持(階梯的平台)
condition2 = trueall(condition1,in1);
//在計算區間內高點都沒有變
if condition2 and not condition2[1]
then begin
value6=value5;
value5=value4;
value4=value3;
value3=value2;
end;
condition3 = 
value3-value2<value4-value3 
and value4-value3<value5-value4 
and (value5-value4<value6-value5 or not in2)//嚴格模式多判斷一階
and value3-value2>0
;//平台的高度一階比一階低
if condition3[1] and not condition3
and 
(getField("投信買賣超", "D")>0
or getField("外資買賣超", "D")>0)
then ret=1;

搭配近一日主力買超張數合計佔成交量5%以上的條件，回測過去七年，停損停利都設為7%，回測報告如下

這是一個長期以來都還蠻有用的短線交易策略。

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/528tz9

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

對於那些走在上昇趨勢上的中低價大型股，就像是一部走在固定方向的大巴士，在前方踫到阻礙時可能會減速甚或休息盤整，但只要突破了整理區之後，往往就是另一波漲勢的開始，這個三次到頂而破的選股策略，就是在尋找這樣的股票

整個策略包含三個條件

後面兩個條件專注在尋找中低價的大型股

三次到頂這個條件的腳本如下

variable:i(0),j(0),j1(0),BP(0);
value1=average(H,10);//求出高10日均線作為趨勢線
value2=value1-value1[1];//求出高10日均線的切線斜率
condition1 = value2>0;//條件一為趨勢成長
condition2 = trueall(condition1,15);//條件二為15日連續成長
condition3 = trueall(not condition1,20);
//條件三為20日連續下跌作為離開上漲波段判斷
if condition1 and not condition1[1] and not condition4 then value3 =0;
//如果終止一段漲幅且未進入第一次下轉區則重設關鍵價
if condition3 
then begin
value3=0;
condition4=false;
condition5=false;
end;
//如果連續下跌則離開第一次下轉區不予進場並重設關鍵價
if value1 crosses under value4 and condition4
then begin
condition5=true;

end;
//如果10日均線跌破關鍵價則進入平行整理區

if condition1 and not condition5
then begin
if H>value3 
then begin
value3=H;
value4=(L+H)/2;
end; 
end;
//設在成長期間的最高點的高低價平均為關鍵價
if condition2[1] and not condition2 
then begin

condition4=true;
condition5=false;
end;
//如果停止連續成長則進入第一次下轉區

if value1 crosses over value4 and condition5 and condition4
then begin
condition5=false;
condition4=false;
ret=1;
end;
//如果收盤價突破平行整理區則進場

把這個策略拿去回測過去七年，停損停利都設為7%，回測報告如下圖

這算是一個接近3戰2勝的短線交易策略

如果一檔股票的股價淨值比低於0.8，且離歷史低點區也沒有太遠，而且流動資產減流動負債後超過市值八成，代表這檔股票的下檔空間應該是愈來愈小了，如果這時候成交量又明顯回升，往往是一個長期的進場機會。

我一共寫了三個腳本來描敘上述的情境

一，PB跌到歷史低點區且低於0.8

value1=GetField("股價淨值比","Y");
value2=lowest(value1,4);
if value1<value2*1.3 and value1<=0.8
then ret=1;
outputfield(1, GetField("股價淨值比","Y"),2, "PB比", order := -1);

二，流動資產減流動負債超過市值N成

input:ratio(80,"佔總市值百分比%");
if (GetField("流動資產","Q")-GetField("負債總額","Q"))*100>GetField("總市值","D")*ratio/100
then ret=1;

三，無量變有量

input:v1(1000,"前一期成交量");
input:v2(1000,"最新期成交量");
if trueall(volume[1]<=v1,10) and volume>v2 
then ret=1;

把這三個腳本結合成一個選股策略，停損停利都設為20%，回測報告如下圖

如果過去五年的四季移動平均EPS都沒有很明顯的下跌，代表這家公司的獲利還蠻穩定的，這樣的公司，如果用最近四季合計EPS去計算，本益比不到八倍，股價應該算是長線的低點區。

我根據上述的概念，寫了一個選股腳本如下

//獲利穩定股目標價計算方法
value1=GetField("每股稅後淨利(元)","Q");
value2=summation(value1,4);
//最近四季的EPS總和
value3=highest(value2,20);
//過去20季以來四季EPS總和的最高值
value4=lowest(value2,20);
//過去20季以來四季EPS總和的最低值
value5=average(value2,20);
var:tp(0);//目標價
if value4>1
//連續四季合計的EPS在過去20季都大於1元
and value3-value4<3
//四季合計的EPS近20季以來最高與最低EPS差1.5元以內
then 
tp=8*value5;
input:discount(30,"折價率");
if close*(1+discount/100)<tp then ret=1;
//目標價與市價差30%以上
outputfield(1,tp,0,"目標價");
outputfield(2,(tp-close)/close*100,1,"預期報酬率");

用這個腳本去回測，停損停利都設為20%，回測報告如下圖

如果目前的股價低於過去十年的股利總和加上淨值，代表如果未來十年公司獲利能力沒有變差，目前的股價去買來再放十年，光收股利都不吃虧，特別是大部份的公司都有積極向上的鬥志，除非進入惡性循環，不然這樣的股價水準應該是要站在買方。

根據這樣的想法，我寫了以下的腳本，來找出目前股價遠低於十年股利加淨值的公司

value1=(getField(“股利合計”, “Y”)
+getField(“股利合計”, “Y”)[1]
+getField(“股利合計”, “Y”)[2]
+getField(“股利合計”, “Y”)[3]
+getField(“股利合計”, “Y”)[4]
+getField(“股利合計”, “Y”)[5]
+getField(“股利合計”, “Y”)[6]
+getField(“股利合計”, “Y”)[7]
+getField(“股利合計”, “Y”)[8]
+getField(“股利合計”, “Y”)[9])/10;

value2=value1+getField(“每股淨值(元)”, “Q”);
var:pg(“”);
input:ratio(20,”折價率”);
if close*(1+ratio/100)< value2
then ret=1;
outputfield(1,close/value2,2,”折價率”);

我如果把折價率設為三成，停損停利都設為20%，回測報告如下圖

如果再加上連續2日三大法人合計買超都大於200張這個條件，回測報告會更好

如果目前的總市值遠遠低於過去五年的平均總市值，且過去五年平均EPS超過3元，今年以來的累計營收年增率又超過5%，那麼股價就可能被低估，值得進一步留意

下面的選股策略，是根據上面的概念所撰寫出來的

其中用到的腳本如下：

value1=(GetField("總市值(億)","Y")+GetField("總市值(億)","Y")[1]+
GetField("總市值(億)","Y")[2]+GetField("總市值(億)","Y")[3]+
GetField("總市值(億)","Y")[4])/5;
value2=GetField("總市值(億)","D");
input:ratio(40,"低於平均市值的最低幅度");
if (value1/value2-1)*100>ratio then ret=1;
outputfield(1,(value1/value2-1)*100,0,"低於平均市值的幅度");

再搭配基本面的那兩個條件後形成選股策，這個策略停損停利都設20%的回測報告如下

這是一個勝率超過七成五的長線選股策略，缺點就是條件太嚴，出的訊號少了點。

如果一家公司，過去十年來自營運的現金流量總和，遠比總市值還高，那代表這家公司正處於股價的谷底，這時候如果法人有很明顯的買超，那可能代表連法人都知道這是長線抄底的好時機

根據這樣的想法，我寫了以下的選股策略

其中十年現金流量總和遠高過總市值的腳本如下

value1=getField("來自營運之現金流量", "Y")+getField("來自營運之現金流量", "Y")[1] 
+getField("來自營運之現金流量", "Y")[2]+getField("來自營運之現金流量", "Y")[3]
+getField("來自營運之現金流量", "Y")[4]+getField("來自營運之現金流量", "Y")[5]
+getField("來自營運之現金流量", "Y")[6]+getField("來自營運之現金流量", "Y")[7]
+getField("來自營運之現金流量", "Y")[8]+getField("來自營運之現金流量", "Y")[9];
//過去十年來自營運之現金流量總和,單位百萬
value2=getField("總市值(億)", "D");
input:ratio(65,"折價比例");
if (value1/100)/value2>=(1+ratio/100)
then ret=1;
outputfield(1,value1/100,0,"十年營運現金流總和(億)");
outputfield(2,value2,0,"總市值(億)");
outputfield(3,(value1/100)/value2,2,"佔比");

加上其他條件後，去跑所有普通股扣除營建，金融及KY股，停損停利設為20%，回測的報告如下圖

這是一個四戰三勝的長期投資交易策略。

蠻多公司的大股東，對於自己公司的股價心目中都有一個絕不能跌破的馬其諾防線，這個防線可能是某次增資時的價格，可能是老板對員工的承諾，我們可以找出過去十年每年的最低價，然後算出這十年最低價的平均值，一旦股價低於這個數字，可能就是股價開始要接近大股東心目中的防線了，如果這時候籌碼又從發散變成收集，那麼可能就值得留意。

要符合上述情況，我寫的選股策略如下圖

其中股價低於10年低點平均值的腳本如下

value1=(lowY(1)+lowY(2)+lowY(3)+lowY(4)+lowY(5)
+lowY(6)+lowY(7)+lowY(8)+lowY(9)+lowY(10))/10;
if close<value1
then ret=1;

另一個籌碼收集的腳本則如下

value1=GetField("分公司買進家數");
value2=GetField("分公司賣出家數");
value3=value2-value1;
value4=countif(value3>30,5);
//計算買進家數與賣出家數的差距夠大的天數
if value4>3
then ret=1;

在這裡我們計算最近五天的券商分點買進及賣出家數，如果賣出家數比買進家數多30家以上，被視為籌碼被收集，如果過去五天有超過三天籌碼被收集，這個選股條件就成立。

把這個策略拿去回測，停損停利都設為10%，回測報告如下圖

這個策略的勝率非常高，缺點就是太嚴謹，出的訊號不多，但總報酬率蠻好的。

蠻多公司的大股東，對於自己公司的股價心目中都有一個絕不能跌破的馬其諾防線，這個防線可能是某次增資時的價格，可能是老板對員工的承諾，我們可以找出過去十年每年的最低價，然後算出這十年最低價的平均值，一旦股價低於這個數字，可能就是股價開始要接近大股東心目中的防線了，如果這時候主力又出現蠻明顯的買超，那麼可能就值得留意。

要符合上述情況，我寫的選股策略如下圖

其中股價低於10年低點平均值的腳本如下

value1=(lowY(1)+lowY(2)+lowY(3)+lowY(4)+lowY(5)
+lowY(6)+lowY(7)+lowY(8)+lowY(9)+lowY(10))/10;
if close<value1
then ret=1;

把這個策略拿去回測，停損停利都設為10%，回測報告如下圖

這是個一年平均有100多個交易次數且勝率超過七成的交易策略。

EV（企業價值）是總市值+負債-現金-短期投資，是市場給這家公司的評價，如果企業價值營收比低於一，代表市場對這家公司的估值不如它一年可以取得的營業額。

那麼如果企業價值營收比低於0.7，且毛利率大於10%，代表這家公司被市場看的很衰

但如果在線型上搭配大跌後突破月線

極可能就是股價要絕地大反攻的開始

根據上述的想法，我寫了以下的選股策略

其中企業價值營收比的腳本如下

value1=getField("總市值(億)", "D");//億
value2=getField("負債總額", "Q");//百萬
value3=getField("流動資產", "Q");//百萬
value4=getField("應收帳款及票據", "Q");//百萬
value5=getField("營業收入淨額", "Y");//百萬
value6=(value1*100+value2-(value3-value4))/value5;
input:ratio(0.7,"比例上限");
if value6<ratio
and value6>0
then ret=1;
outputfield(1,value6,1,"企業價值營收比");
outputfield(2,value1,0,"總市值單位億元");
outputfield(3,value1*100+value2-(value3-value4),0,"企業價值單位百萬");
outputfield(4,value5,0,"年營收");

大跌後突破月線的腳本如下

if close*1.283<close[30]
and close*1.782>close[30]
and barslast(close cross over average(close,22))=0
and barslast(close cross over average(close,22))[1]>30

then ret=1;

這個選股策略過去七年停損停利都設10%的回測報告如下

這個策略有很高的勝率，但七年的交易機會只有119次，算是久久才出一次訊號的選股策略