Author Archives: 發財橘子

我們有個優秀的同事，給了我一個蠻不錯的策略，這個策略是從財報上的預收帳款數據，去找到接下來基本面可能好轉的公司，如果這些公司價量及籌碼面也配合，那在波段操作上，就有不錯的勝率。

我同事寫了兩個腳本來組合這個策略。

第一個是預收帳款成長：

settotalbar(12);

input: ratio_1(1.1, "本季比去年同期增長N倍");
input: ratio_2(15, "預收款項成長佔股本X%");

// 計算過去四季預收款項成長的幅度佔股本比例
value1 = summation(GetField("預收款項", "Q"), 4);
value2 = summation(GetField("預收款項", "Q"), 4)[4];
value3 = value1 - value2;
value4 = value3 / (GetField("股本(億)","D") * 100);


if 
GetField("預收款項", "Q") >= GetField("預收款項", "Q")[4] * ratio_1
and value4 > ratio_2 / 100
then
ret = 1;

outputfield(1, GetField("預收款項", "Q"), 2, "預收款項");
outputfield(3, GetField("預收款項", "Q")[4], 2, "去年同期預收款項");
outputfield(5, value4, 2, "預收款項成長佔股本比例");

第二個是暴量剛起漲：

input: period(15, "日期區間");
Input: ratioLimit(10, "區間最大漲幅%");

if 
close = highest(close, period) //今日最高創區間最高價 
and volume = highest(volume, period) //今日成交量創區間最大量 
and highest(high, period) < lowest(low, period) * (1 + ratioLimit * 0.01)
//今日最高價距離區間最低價漲幅尚不大
then
ret = 1;

若最近四季稅後淨利合計大於零的公司，符合上述這兩個腳本，再加上籌碼面，若符合下面三個條件的其中一個，就讓電腦觸發訊號：

一、近一日關鍵券商買超大於100張

二、近一日主力買超張數大於100張

三、近一日三大法人買超合計大於100張

我拿這個策略去回測所有的普通股，停損停利都設為10%，回測報告如下圖：

這個策略有很不錯的勝率，總報酬及收益曲線也OK，MDD在可忍受範圍，就是交易次數少了一點，但如果把參數放鬆，勝率及報酬率又會受影響，顯然預收帳款增加金額佔股本要達到一定的比重，對EPS才會有足夠明顯的影響，並進一步帶動股價走出波段行情。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

以前有部棒球電影叫作KANO，裡頭有句話：不要想著贏，要想不能輸。棒球有進攻有防守，前者想著贏，後者則是想著不能輸，有一派操作者的想法也是這樣，只有在股價超跌到下檔風險十分有限時才會進場，今天就來跟大家介紹一個這種概念發展出來的交易策略。

這個策略有三大部份：

一、先計算一家公司股票的參考價值，然後看看目前的市價離參考價值是不是很遠，這樣投資風險值就夠低。

二、這家公司的體質，以及近期的表現都不差

三、近一日法人買超佔成交量一定比例

簡單說，就是股價超跌後法人開始用力買。

我寫了一個腳本來尋找投資風險值夠低的股票，腳本如下：

value1=getField("月營收", "M")+getField("月營收", "M")[1]+getField("月營收", "M")[2]
+getField("月營收", "M")[3]+getField("月營收", "M")[4]+getField("月營收", "M")[5]
+getField("月營收", "M")[6]+getField("月營收", "M")[7]+getField("月營收", "M")[8]
+getField("月營收", "M")[9]+getField("月營收", "M")[10]+getField("月營收", "M")[11];
//過去12個月營收，單位:億
value2=getField("股本(億)", "D");
value3=value1/value2*10;
//過去12個月的每股營收
value4=getField("每股淨值(元)", "Q");

value6=getField("常續性利益(稅後)", "Q")+getField("常續性利益(稅後)", "Q")[1]
+getField("常續性利益(稅後)", "Q")[2]+getField("常續性利益(稅後)", "Q")[3];

value7=value6/(value2*10);
//近四季每股常續性利益

var:DRV(0);
DRV=(value3+value4*1.5+value7/3)/3;
//參考價格
value8=(close-DRV)/close*100;
//偏離值

if value3<100
//每股營收小於100
and value8<-75
//偏離值小於負75
and value7>2
//近四季每股常續性收益大於2元
and value4>15
//每股淨值大於15元
then ret=1;


outputfield(1,value8,1,"偏離值");
outputfield(2,DRV,1,"下跌風險值");
outputfield(3,value3,1,"過去12個月的每股營收");
outputfield(4,value7,1,"近四季常續性稅後盈餘");
outputfield(5,value4,1,"每股淨值");

這個腳本裡的參考價公式是：

(每股營收+每股淨值*1.5+近四季每股常續性利益/3) / 3

至於為啥是用這個公式，我也是書上看來的，想說就拿來試看看，沒有想到效果不錯，就拿來用。

另外在這個腳本中，有設了一些公司獲利品質的標準：

一、每股營收小於100，過濾掉那些代理等業務

二、每股淨值大於15元

三、近四季每股常續性收益超過2元

除了這個腳本之外，另外加上兩個條件：

一、近一日三大法人買超合計佔成交量大於10%

二、毛利率大於10%

綜合上述的條件，寫出來的選股策略，去回測過去七年，停損停利都設為10%，回測報告如下圖：

這是一個表現很不錯的波段交易策略，就是交易次數不算多，大家可以調整各種參數，看看能不能在夠高的勝率下，有更多的交易次數。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

現在這種消息面不確定因素多的市場，漲多的比較容易有獲利了結的賣壓，所以在操作上，寧可找那些近期在盤整的股票，今天跟大家討論的，就是一個盤整後佔全市場成交量佔20日新高且上漲的交易策略。

我在看盤時，觀察到，如果一檔股票在過去20多天裡，高點與低點之間相差小於7%，然後最近一個交易日出現了幾個現象。

一、有著較明顯的漲幅

二、投信買超

三、近一日佔全市場成交量創20日新高

如果符合這些條件，短線上繼續上漲的機率會比較高。

於是我試著把它寫成一個選股策略。

首先我寫了兩個腳本：

一、近N日震盪幅度小於M%

input:n(7,"區間波動範圍%");
input:period(25,"區間長度");

if lowest(close[1],period)*(1+n/100)>highest(close[1],period)
then ret=1;

二、佔全市場成交量創20日新高

value1=GetField("佔全市場成交量比","D");

SetTotalBar(20);

if 
value1=highest(value1,20) 
then ret=1;

接著我搭配了其他選股條件，變成以下的選股策略：

拿這選股策略去回測，停損停利設成7%，回測報告如下圖：

勝率接近三戰兩勝，MDD與總報酬率都算可以，當然空頭市場時無法逆勢，但長期來看，收益率算是穩定增長。

因著總交易次數有320次，所以有興趣的朋友可以再看看怎麼優化，但盤整後資金流向創新高這個概念，應該是有其道理的。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

如何找出目前在整理，但未來蠻值得注意的個股？先前有跟大家聊過，可以注意在整理期間籌碼被收集的個股，今天就來介紹一個根據這樣的想法寫出來的波段操作策略。

首先我寫了一個籌碼被收集的整理股的腳本：

value1=GetField("分公司買進家數", "D");
value2=getField("分公司賣出家數", "D");
if trueall(value2>value1*1.3,5) then begin
if close> average(close,60)
and (highest(high,20)-lowest(low,20))/close*100<7
then ret=1;
end;

這個腳本可以找到過去五日籌碼被收集，且長期趨勢向上，但近20日基本盤整的個股。

把這個腳本搭配其他過濾條件，組成如下圖的選股策略：

把這個策略拿去回測過去七年，停損停利都設為10%，回測報告如下圖：

這是一個報酬率不算大，但穩定，勝率高且MDD在可接受範圍的選股策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

市場有一派的作法是專門追強勢股，今天跟大家分享一個績效還滿穩健的追高策略。這個策略的概念就是去找那些籌碼被收集的創波段新高股。

以下是我寫的腳本：

 
input:Len(10); 
input:Period(5); 
Var:BTotal(0),STotal(0),BSRatio(0); 
BTotal=GetField("分公司買進家數"); 
STotal=GetField("分公司賣出家數"); 
BSRatio=100*(STotal-BTotal)/(STotal+BTotal); 
//賣出家數減買進家數差佔總交易家數的比例 
//---------------------------------------- 

if C>=C[1]*1.02 
//漲幅超過2%
and C*1.02>=H 
//收盤接近最高價
and C>=Highest(H[1],Len)
//收盤創波段高點 
and Average(GetField("成交金額(億)","D"),period)>=0.15
//成交值超過1500萬 
and trueall(BSRatio>5,period)
//籌碼在被收集中
and BSRatio=Highest(BSRatio,10)
//籌碼收集的情況持續中
then ret=1;

這個腳本設了幾個條件：

一、當日漲幅超過2%

二、收盤價創近10日來新高

三、收盤價接近當日最高價

四、成交值超過1500萬

五、近五日籌碼都被收集而非發散（這裡用買進與賣出券商數的差額來代表籌碼是被收集還是發散）

六、最近一個交易日籌碼收集的情況是近十日最明顯的

我另外加了三個條件過濾掉股本太大及漲幅過高的股票。

組成如下圖的選股策略：

我拿這個選股策略去回測過去七年，停損停利都設為7%，回測報告如下圖：

這是一個MDD很理想，時間加權報酬也很OK，但勝率差強人意的交易策略，朋友們可以試著在這樣的基礎下再去做調整，但追高時留意籌碼收集抑或發散，絕對是很值得參考的觀念。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

波段交易科技股時，有一個策略值得跟大家分享，這個策略是去尋找研發費用佔總市值比例夠高的中小型低價股。

當初會發展出這個策略，是因為我觀察到，蠻多中小型的科技股，持續的投入研發，如果這些股票能有一定的營業利益率，代表這家公司的產品有一定的競爭力，研發的投入可以得到一定的成果。

如果這樣的公司，其研發費用佔總市值的比例，在過去半年穩定的走高，一種可能是股價沒什麼動，但研發投入一季比一季高，另一種可能就是股價有明顯的拉回。

如果符合這樣條件的個股，投信開始買超，往往就代表股價已經跌到值得法人回頭買進的價位區了。

於是我寫了以下的腳本去找這樣的股票：

Input:SPeriod(8); 
Var:Amount(0),Ratio(0); 

// 計算 
Amount=GetField("投信買賣超","D"); 
Ratio=100*Summation(Amount,SPeriod)
/Summation(V-GetField("當日沖銷張數"),SPeriod); 

// 連續三季研發費用佔總市值比率達到一定的水準 
value1=getField("總市值(億)", "D");
value2=getField("研發費用", "Q");
value3=value2/(value1*100)*100;

Condition1=value3>2.1
and value3[90]>1.8
and value3[180]>1.5; 
// 營業利益率>5% 
Condition2=GetField("營業利益率", "Q")>5; 

// 均成交金額>0.2E 
Condition3=Average(GetField("成交金額(億)","D"),5)>=0.20; 
// 投信買超
Condition4=Ratio>0.5; 
// 個股條件(籌碼相關) 
if condition1 and condition2 and condition3 and condition4
then ret=1;

在這個腳本中，除了符合營業利益率超過5%，以及研發費用佔總市值比愈來愈高之外，我另外加了成交金額超過2000萬及投信買超兩個條件。

然後我再加上股本小於50億及收盤價小於60元兩個選股條件，組合成一個選股策略，下圖是這個策略過去七年，停損停利設為10%的回測報告：

這是一個勝率，總報酬率及MDD都非常不錯的交易策略，有興趣的朋友，可以參考這樣的思路，發展自己的中小型科技股交易策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

XQ選股中心有很多的籌碼數據，用來偵測大股東，外資，投信，自營商，代操及主力的買賣情況，我心血來潮，想要試看看，如果一檔股票，上述的勢力大多站在買方，且買超張數佔成交量的比重非常高，而且當天漲幅不大，且當週漲幅也不大，這樣會不會是一個不錯的進場點？

於是我寫了以下的腳本

setBarback(200);
value1=GetField("關鍵券商買賣超張數","D");
value2=GetField("地緣券商買賣超張數","D");
value3=GetField("綜合前十大券商買賣超張數","D");
value4=GetField("外資買賣超","D");
value5=GetField("投信買賣超","D");
value6=GetField("自營商自行買賣買賣超","D");
value7=GetField("主力買賣超張數","D");
value8=value1+value2+value3+value4+value5+value6+value7;
//這些各方勢力買超合計的張數
value9=value8/volume*100;
//合計佔成交量的比重
var:count(0);
condition1=false;
count=0;
if value1>0 then count=count+1;
if value2>0 then count=count+1;
if value3>0 then count=count+1;
if value4>0 then count=count+1;
if value5>0 then count=count+1;
if value6>0 then count=count+1;
if value7>0 then count=count+1;
if volume>500
//成交量大於500張
and count>=5
//七項至少六項是買超
and value9>75
//合計買超張數佔成交量達75%以上
then condition1=true;
if barslast(condition1)=0 
//最近一期符合上述條件
and barslast(condition1)[1]>100
//很久沒有符合這個條件
then ret=1;
outputfield(1,count,0,"符合條件數");

然後組合成以下的選股策略

我拿這個策略去回測過去七年，停損停利都設為7%，回測的結果如下圖

這個策略的勝率不算特別好，有優化的空間，但交易次數多，MDD也夠小，加上總報酬穩定向上，個人覺得還算是蠻值得持續優化的策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

我有很多的交易策略，靈感都是來自跟市場老手的對話，像最近有不少個股大漲後又急跌，那麼這類的股票什麼時候可以買呢？符合什麼特徵的股票可以買呢？這一題的答案，我曾經在一位市場老手那裡，聽到蠻有意思的觀察，我把這樣的觀察寫成策略，回測的結果的確有它蠻有意思的地方，今天來分享這樣的觀察。

這位老手對於大漲後急跌的個股，有幾個心得：

一、從起漲到現在，漲幅要超過12%，但也不要已經漲超過80%了

二、最近的這波下跌，最近五個交易日要跌超過15%

三、這樣的公司，不是啥都能接，只有那些股東權益報酬率表現不錯的公司才可以接。

這位老手跟我說，要完全符合這些條件的個股，不是很多，其次是空頭市場這策略也不能用，但是如果在多頭市場一直用這個策略挑股票，報酬率會蠻好的。

於是我把這些條件用【XQ選股中心】訂成選股策略，如果停損停利都設為7%，回測報告如下圖：

這一招還真的長期下來有很不錯的報酬率，但就是在大空頭市場MDD有點大。

下圖是最近出現的兩個交易記錄：

所以5天跌15%的好公司，似乎是一個值得留意的止跌訊號。

而且像出現這種訊號時，如果把持股放久一點，例如把停損停利拉長到10%，回測的效果會更好，例如下圖：

當然MDD超過四成的策略不能直接放給它自動交易，而且這個策略平均一年出不到20個訊號，對交易型投資人而言，不能單押這個策略。

但像我的個性，就是隨著時間的積累，不斷的收集一些有不錯勝率及報酬率的交易策略，然後當我收集夠多的交易策略後，全部把它們加到每日自動執行的排程中，這樣每天就偶爾會有一些我很有興趣的標的會出現在螢幕上。

===

●「XQ選股中心」就在【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

先前從一本介紹短期交易的書中，學到一招： 如果低價股近一季以來，第一次出現外資跟投信同步大買，往往短線上是有作多的機會。

今天心血來潮，就把這個概念寫成【XQ選股中心】的策略，跟大家分享。

首先是寫一個腳本來描敘投信與外資同步大買，我寫的腳本如下：

input:days(60,"計算期間");
input:M1(200,"最低買超張數");
value1=getField("外資買賣超", "D");
value2=getField("投信買賣超", "D");
condition1=value1>m1 and value2>m1;
if condition1
and barslast(condition1)[1]>=days
then ret=1;

在腳本中用到Barslast這個函數，它的意思是符合函數中條件的最後一次發生的那天，距離最近一個交易日有幾根Bar。如果 barslast(close=20)=0，那就代表今天收盤價是剛好是20元。

除了這個腳本之外，我另外加上收盤價小於60元作為低價股的過濾條件，組合成這個策略。

我把這個策略拿去回測過去七年，停損停利都設為7%，回測報告如下圖：

七年的總交易次數達到588次，時間加權報酬率是378%，MDD是-14%  ，比較弱的是勝率，62.4%不算特別好，但從收益曲線來看，這算是一個可以長期穩定貢獻報酬的策略了，只是要嚴格的執行交易紀律。

至於如何提昇勝率，就看各位老大如何進一步優化這策略了。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

江湖上有個傳說，說股價大跌後，如果第一次站上月線，而且法人大買超，這樣的股票可以買，今天我們就來實驗看看，這個傳說有沒有道理？

先來定義一下什麼叫作大跌，根據我們AI  Team的研究，30個交易日裡，股價跌了28.3%，抄底的勝率最高，所以我就先寫一個條件如下：

if close[30]>close*1.283
then ret=1;

拿這個腳本去回測，回測報告如下：

接下來就再加上股價近一個月來第一次突破月線的腳本，合起來的腳本如下：

if close[30]>close*1.283
and barslast(close cross over average(close,22))=0
and barslast(close cross over average(close,22))[1]>30

then ret=1;

用這個腳本去回測，回測報告如下：

顯然績效反而很差。

但如果再加上近一日三大法人合計買超佔成交量10%以上的這個條件，近五年的回測報告如下：

不管是勝率，總報酬率，MDD的表現都很好。

從收益曲線來看，這個策略在大跌之後，的確會有不錯的表現，所以如果股市波段大跌過，就可以用這個策略，至於多頭或盤整時，這個策略出的訊號就會很少。

但總的來說，這個江湖傳說是有它的道理的。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！