Author Archives: 發財橘子

這一期的股市傳說，我們來討論大股東連續買超，到底是不是一個很值得參考的買進訊號。

以下圖為例：

彩晶在連續四天代表大股東進出的關鍵券商都買超>500張之後，開啟了一波反彈行情。

所以我們今天就來聚焦這個議題： 大股東連續買進是不是一個買進訊號？

首先還是先解釋一下XQ關鍵券商的定義：

所謂的關鍵券商，其實就是公司派，要被列入為一檔個股的關鍵券商，一定是近三年內，這檔個股有真的實施庫藏股，然後系統根據庫藏股的公告，回頭去找那段時間大買超的券商分公司，把這些券商分公司就列為該個股的關鍵券商，也因此，如果近三年沒有實施庫藏股，那麼那檔個股就不會有關鍵券商。

為什麼這麼做呢？因為我們想要從籌碼中找出公司派進出的號子，一個常用的做法是透過地緣關係，但這個方法不適用雙北的公司，所以我們就想說實施庫藏股時，公司要買的金額通常會比較大，而且一定會下在跟公司常往來的券商分點，所以就決定用這個方法來定義關鍵券商。

接下來對照這個概念的腳本如下：

value1=GetField("關鍵券商買賣超張數","D");
if trueall(value1>500,4) 
then ret=1;
outputfield(1,value1,0,"關鍵券商買超張數");

這個腳本是找出連續四天大股東買超都超過500張的股票。

把這個腳本拿去回測過去五年，停損停利都設為7%，回測的報告如下：

勝率達到64% ，MDD只有12.6%。

這算是一個還蠻值得更深入研究的市場傳說，大股東進場果然是股價止跌回升的重要參考因素。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

今天我們來討論的江湖傳說是：如果目前的總市值遠低於「過去十年來自營運的現金流量的總和」，那麼就值得長期投資。

這個江湖傳說好像起源於美國那些價值型投資者，他們的意思是，如果有家公司目前的總市值，遠低於過去十年本業可以賺進來的現金流量，那麼應該是一個長線的買點。

美國有很多獲利穩定的公司，但台灣這種公司比較少，這樣的規則是否依然適用？

我寫了以下的腳本，想要來回測看看：

value1=getField("來自營運之現金流量", "Y")+getField("來自營運之現金流量", "Y")[1] 
+getField("來自營運之現金流量", "Y")[2]+getField("來自營運之現金流量", "Y")[3]
+getField("來自營運之現金流量", "Y")[4]+getField("來自營運之現金流量", "Y")[5]
+getField("來自營運之現金流量", "Y")[6]+getField("來自營運之現金流量", "Y")[7]
+getField("來自營運之現金流量", "Y")[8]+getField("來自營運之現金流量", "Y")[9];
//過去十年來自營運之現金流量總和,單位百萬
value2=getField("總市值(億)", "D");
input:ratio(80,"折價比例");
if (value1/100)/value2>=(1+ratio/100)
then ret=1;
outputfield(1,value1/100,0,"十年營運現金流總和(億)");
outputfield(2,value2,0,"總市值(億)");
outputfield(3,(value1/100)/value2,2,"佔比");

這個腳本設的折價幅度是打八折，回測過去五年，持有60天，報告如下：

勝率是56.5%。

如果折價幅度變成六成的話，回測七年的報告如下：

勝率接近60%，且績效遠優於大盤。

顯然這個江湖傳說在台灣也有一部份是可以適用的。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期來談增資股出籠是不是重大利空？

先說結論：現增股快上市前兩天再去放空輸多贏少，反而是一個作多時機。

但如果是上市前15天去空，則輸少贏多。

市場上的傳說是，如果現增張數佔股本的比例夠高，且無法放空鎖單，或放空的張數不多，在增資股出籠前，會有一波賣壓，可以做個短空。

為了驗證這個江湖傳說，我寫了以下的腳本：

value1=GetField("現增新股上市日");
value2=GetField("現增比率");//每千股可認股數
value3=GetField("現增價格");
value4=GetField("融券餘額張數","D");
value5=GetField("普通股股本","Q");//單位:億

if value1>date and datediff(value1,date)<2//增資股快上市了
and 
value5*10000*value2/1000>10000//增資張數大於10000張
and 
value4[30]>value4-1000//近一個月融券增加沒有超過1000張
and
value3*1.1<close//股價仍比現增價格高超過一成
then ret=1;
outputfield(1,value1,0,"新股上市日");
outputfield(2,value2,0,"現增比率");
outputfield(3,close-value3,0,"現增價差");

一樣回測過去五年，停損停利都設7%，回測報告如下：

如果是等到增資股快出籠前兩天才去空，勝率很低，反而是作多，勝率竟然高達67%。

顯示大部份的公司，都不願意馬上就讓現金增資的參加者虧到錢。

如果把腳本改成以下的腳本：

value1=GetField("現增新股上市日");
value2=GetField("現增比率");//每千股可認股數
value3=GetField("現增價格");
value4=GetField("融券餘額張數","D");
value5=GetField("普通股股本","Q");//單位:億

if value1>date and datediff(value1,date)<15//增資股快上市了
and 
value5*10000*value2/1000>10000//增資張數大於10000張
and 
value4[30]>value4-2000//近一個月融券增加沒有超過2000張
and
value3*1.1<close//股價仍比現增價格高超過一成
then ret=1;
outputfield(1,value1,0,"新股上市日");
outputfield(2,value2,0,"現增比率");
outputfield(3,close-value3,0,"現增價差");



作空的回測報告如下

這顯示如果在離增資股出籠較早之前，像是前15日，然後放寬融券餘額上限到2000張，這時放空反而比較有勝算。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來談的是，股價站上布林值上軌且主力買超達到一定水準，是不是一個好的交易策略？

我寫的腳本如下：

value1=GetField("籌碼鎖定率","D");
Input: Length(20, "期數"), UpperBand(2, "通道上緣");
settotalbar(3);
if value1 >= 7
and close >= bollingerband(Close, Length, UpperBand)
then ret=1;

這裡的籌碼鎖定率，是股本減去董監持股作分母，主力買超作分子。

回測過去七年，停損停利都設為7%，回測報告如下：

雖然勝率也是接近50%，但績效不好。

如果是單純的K棒突破布林值上緣：

close cross Above bollingerband(Close, Length, UpperBand)

回測報告如下：

也就是說，股價突破布林值上限，本身是一個不錯的概念，可以搭配再去找其他的獲利因子，但主力大買超顯然未必是靠譜的因子。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來做實驗的市場傳說是：法人持續一直買的低價股是不是好的買進標的？

下面這張圖是這一概念下的成功例子：

這個選股方法要符合以下幾個條件：

一、股價目前不在近期最高點

二、前一日法人買超>800張

三、最近一日法人買超>1000張

四、過去一陣子大部份的日子法人都買超

五、目前股價<40元

我寫的腳本如下：

value1=getField("法人買賣超張數", "D");
input:period(12);
if close<highest(close,period)
//股價低於計算區間的最高點
and countif(value1>0,period)>period*0.75
//3/4的日子裡法人買超
and value1>1000
//近一個交易日法人買超達1000張以上
and value1[1]>800
//前一個交易日法人買超達800張以上
and close<40
then ret=1;

回測過去兩年，停損停利都設7%，報告如下：

勝率有6成，MDD是-17%，交易次數有226次。

這是一個聽起來很有道理，在多頭市場末升段漲到低價股時表現會特別好的選股策略。

我們面對這種勝率高，交易次數不多，在特定時段特別有用的選股策略，有兩個做法，一個是作為可以運用的選股策略之一，但不能單單使用這一交易策略；另一個做法則是研究其勝率高的原因，重新調整參數或加入其他條件。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期我們來討論一個常見的江湖傳說：當KD與MACD同時出現買進訊號時，是不是一個多頭訊號？

我在好多個地方都有看到KOL在教大家，同時用多個技術指標來綜合研判進場點，類似像下面這張圖：

這個選股策略要符合幾個條件：

一、MACD的OSC翻紅

二、KD低當黃金交叉

三、RSI在50以上

要符合上述三個條件，我寫了以下的腳本：

input: Length_D(9,"日KD期間");
variable:rsv_d(0),kk_d(0),dd_d(0),c5(0);
stochastic(Length_D, 3, 3, rsv_d, kk_d, dd_d);

input:FastLength(12, "DIF短期期數");
input:SlowLength(26, "DIF長期期數");
input:MACDLength(9, "MACD期數");
variable: difValue(0), macdValue(0), oscValue(0);

MACD(weightedclose(), FastLength, SlowLength, MACDLength, difValue, macdValue, oscValue);

if kk_d crosses over dd_d
and kk_d<30
and oscValue Crosses Above 0
and rsi(close,10)>=50
then ret=1;


這個腳本回測過去七年，停損停利都設為7%，回測報告如下：

雖然勝率有55%，但其實績效算蠻差的，根本不是一個真的可能拿來實戰的交易策略。

要從裡頭挑像上圖這種看起來很威的標的是不難，但要真的這樣下去操作，恐怕會白忙一場。

我有試著把RSI這條件拿掉，改成近5日RSI趨勢是往上。

and linearRegSlope(rsi(close,10),5)>0

回測的結果如下：

雖然回測的數據好一點，但仍然輸給大盤不少，這樣無法實戰，我的建議是，在技術指標出現買進訊號時，不要再去搭配其他技術指標，試著加一些籌碼面的過濾條件，效果可能會好一些，如果一定要加其他技術指標，最好加一些比較具互補性的指標。

舉個例子，我寫過一篇DMI搭配VHF的文章

這裡面我提到了如何用VHF指標來過濾掉DMI指標跑出來的假買進訊號。

我們使用這樣的概念，再配合主力買超佔成交量兩成這個條件，可以寫出以下的腳本：

input: Length(24, "天數");
Variable: hp(0), lp(0), numerator(0), denominator(0), _vhf(0);
hp = highest(Close, Length);
lp = lowest(Close, Length);
numerator = hp - lp;
denominator = Summation(absvalue((Close - Close[1])), Length);
if denominator <> 0 then
_vhf = numerator / denominator
else
_vhf = 0;
input:period(14); setinputname(1,"計算期數");
variable: pdi(0), ndi(0), adx_value(0);
DirectionMovement(period, pdi, ndi, adx_value);
value1=getField("主力買賣超張數", "D");
if volume<>0 then 
value2=value1/volume*100;
if pdi>pdi[1] and ndi<ndi[1] and pdi crosses over ndi
and rsi(_vhf,5)>70
and value2>=20
then ret=1;

用這個腳本去回測過去七年，停損停利都設為7%，回測的結果如下圖：

雖然勝率只有58%，但收益曲線算是蠻平滑，MDD接近16%，在可接受範圍，在空頭市場也有一定的抵抗力，大家根據這樣的思維，可以試著打造自己的多指標交易策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

這一期的市場傳說，我們來討論分點重押的股票有沒有搞頭？

這種分點重押的股票，這兩天剛好有一個不錯的例子如下圖：

根據坊間KOL的說法，一檔股票要符合分點重押股的條件有以下幾個：

一、券商分公司淨買超的點要不到賣超的券商分點數的一半，這代表籌碼是從多數人的手裡集中到小數人的手中，這是一種籌碼收集的動作

二、這種籌碼被收集的情況，已經持續一段時間

三、最近一個交易日主力買超張數超過成交量的一成

四、累計營收年增率大於0，代表公司基本面仍在良性循環中

五、月營收年增率大於5%，代表最近一個月的業績表現仍可以

六、股價在季線之上。表示目前還在多頭格局

綜合KOL的說法，我寫成選股腳本如下：

腳本

value1=getField("分公司淨買超金額家數", "D");
value2=getField("分公司淨賣超金額家數", "D");
value3=getField("主力買賣超張數", "D");
value4=getField("累計營收年增率", "M");
value5=getField("月營收年增率", "M");
if volume<>0
then value6=value3/volume*100;

if value1*2<=value2
//買家數不到賣家數的一半
and countif(value2>value1,20)>12
//過去20天籌碼被收集的天數大於12天
and value6>=10
//主力買超佔成交量超過一成
and value4>0
//累計營收年增率大於0
and value5>5
//月營收年增率大於5%
and close>average(close,60)
//股價在季線之上
then ret=1;

根據這個腳本去回測過去七年，停損停利都設為7%，回測報告如下：

勝率是57%，報酬率在先前是穩定往上，但交易次數蠻多的，代表這個概念是可行的，但必須加上其他條件來優化，有興趣的朋友可以往這個方向，再把條件設得更多更嚴來試看看。

我個人是覺得這個KOL算是蠻不錯的了，他訂的這些條件在多頭市場會穩定賺錢，在空頭市場出的訊號會少蠻多，大家拿到這些市場秘技，也可以像我這樣，自己多寫多測看看。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

今天來跟大家討論的股市傳說是，如果有一檔股票，先前主力不疼、法人不愛，但最近幾個月的營收表現，出乎市場預期，於是法人開始安排去call公司，call完之後發現這家公司未來發展前景超乎預期，於是開始進場大買，如果出現這樣的現象，往往有波段作多的機會。

這樣的個股，要符合幾個條件：

一、在每月十一日到十五日之間

二、最近三個月的月營收年增率逐月遞增

三、法人連續兩天買進超過500張

四、主力連續兩天買進超過1000張

五、股價站在季線之上

舉個例子：

三晃化工在2021的11月16日就符合這五個條件：

我把上述五個條件寫成腳本如下：

value2=getField("法人買賣超張數", "D");
value3=getField("主力買賣超張數", "D");
value4=datevalue(currentdate,"d");
if value4>10 and value4<=15
then begin
if getField("月營收年增率", "M")>getField("月營收年增率", "M")[1]
and getField("月營收年增率", "M")[1]>getField("月營收年增率", "M")[2]
and getField("月營收年增率", "M")[2]>getField("月營收年增率", "M")[3]
and trueall(value2>500,2)
and trueall(value3>1000,2)
and close> average(close,60)
then ret=1;
end;


這個腳本回測過去七年，停損停利俱用7%，勝率超過六成，總報酬率148%。

回測報告如下：

這個市場傳說，看來有其一定的道理，有興趣的朋友，可以根據這樣的思路，重新調整這個交易策略，例如加上法人持股比例不高，或是股本之類的限制，或者對於法人及主力買超的張數，條件未必要設的如此之高，總之概念對了，戲法就請各位自行發揮了。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

前兩集寫的都是言過其實的股市傳說，這一集來討論一個我覺得有道理，且回測也有還可以的勝率的交易策略。這個策略是專門在營收公佈前，買進那些主力有持續且明顯買超的個股。

這個策略的前題假設是，當該月營收有蠻明顯成長，而且還沒有公佈時，那些可能已經事先得知此消息的市場參與者，會趁營收公佈前，先進場買進，等著一旦營收公佈，讓我們這些散戶們見利多而進場抬轎。

我稱這種股票叫「營收公佈前主力的異常買超」。

為了找到這些股票，我寫了一個腳本，專門在每個月的1號到10號，去找這段期最新一個月營收還沒有公佈，然後連續兩天主力買都超過1000張，且連續兩天主力買超佔成交量超過兩成的股票。

腳本如下:

var:dd(" ");
var:dr(" ");
dd=datetostring(currentdate);
dr=rightstr(dd,2);
value11=strtonum(dr);
input:d1(1,"起始日");
input:d2(10,"截止日");
if value11>=d1
and value11<=d2
then begin
value1=getFieldDate("月營收", "M");
//取得月營收日期
value2=datevalue(date,"M");
//取得最近一根K棒的月份數值
value3=datevalue(value1,"M");
//取得月營收日期的月份數值
value4=getField("主力買賣超張數", "D");
if volume<>0 then 
value5=value4/volume*100;

if value2-value3=2
//如果K棒月份數值比公佈的數值差2
and trueall(value4>1000,2)
and trueall(value5>20,2)
then ret=1;
end;

我拿這個腳本去回測過去七年，停損停利都設7%，回測報告如下：

勝率是58%，MDD是-18%，這已經是一個可以往下繼續深化的交易策略，我根據坊間KOL的教學，加上一個股價必須在季線之上的條件：

and close> average(close,60)

回測報告如下：

勝率就有達到六成，收益曲線還蠻漂亮的，只是這策略的績效不如大盤，所以必須再優化，或是只能作為每月1到10日的特有交易策略，其餘時段必須搭配其他交易策略。

這個市場傳說看來是有其一定的可信度，大家可以進一步發展成自己的交易策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

投信認養股是除了外資認養之外，第二個最常被傳的股市傳說，今天我們就來研究看看這個傳說能不能禁得起考驗。

投信認養的股票要怎麼定義？由於投信單一持股不能超過基金的10%，加上國內股票型基金的規模有限，所以江湖傳說是說只要投信持股比例超過0.5就可以算是投信認養股。但如果是這樣的標準，那符合條件的股票會有259檔：

所以我把條件拉高為「投信持股比例佔超過1成」才算是投信認養股。

接著第二個條件是股價要突破投信成本區：

if close cross over getField("投信成本", "D")
then ret=1;

把這兩個條件合併成一個選股策略，停損停利各設7%，回測報告如下圖：

這個傳說跟上個外資認養股的傳說一樣，聽起來很有道理，回測下去勝率也有過五成，但是績效卻遠遠不如大盤。

原因就在於，投信外資如果持股都很高，過成本線的結果不一定是利多，說不定法人反而會獲利了結，成了利空了。

關於投信的相關選股策略，我寫過不少，其中有一個我一直覺得蠻好用的，這個策略一共三個條件如下：

這是去挑先前表現不好、投信持股不大，但近一日投信買得很積極的股票。有興趣的朋友可以回測看看，最近五年勝率有到65%。

不過這個策略在空頭市場表現就無法逆市上漲。

以上是投信認養股這個江湖傳說的驗證，大家在看這些江湖傳說時，千萬不要被舉的例子給迷惑了，一定要自己回測看看，真的績效可以的才能拿來用喔！

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！