Author Archives: 發財橘子

要怎麼判斷一檔低價股開始重新獲利市場的青睞? 例如像底下達運這樣的走勢呢?

我的老市場朋友給了我兩條不算複雜的規則

規則一: 資金明顯回流到這檔股票

規則二: 連續多日主力買超

就這麼簡單嗎?

哦! 還有一個是盤不能太差

意思是大盤不太差時如果低價股出現資金明顯回流且主力連續多日買超，就該留意。

問題來了，資金要回流到什麼程度才算呢?

於是我寫了以下的腳本，回測了幾個不同的比例，最後發現，如果資金流向的比例是過去60天移動平均的四倍，回測出來的勝率最高，以下是我寫的腳本

//所有股票
//進場後20天出場

value1=GetField("資金流向");
value2=GetField("主力買賣超張數");

if value1 crosses over average(value1,60)*4
//資金流向明顯回昇
and trueall(value2>200,5)
//過去五日主力都買超超過兩百張
and tselsindex(10,6)=1
//大盤外資買多於賣
and close<40
//股價不高於40元
then ret=1;

回測報告如下

大家也可以用這個簡單的腳本作基礎，調整資金回流的比例，然後再加上其他技術面的條件，可能會有更好的結果。

近期的股價修正，讓抄底策略開始有了用武之地，之前跟大家提過，在股價修正四成之後，有不少抄底型的交易策略勝率會大幅攀昇，今天跟大家介紹的方法是，把不同的抄底策略全部綜合在一個腳本中，只要股價修正超過四成之後，符合其中任何一種現象，都會觸發訊號。

自從有了XS之後，我應該寫超過500個腳本，回測下來，跌幅超過四成後的各種訊號，勝率真的比較高。

例如到昨天收盤價為止，近百日跌幅超過四成，成交量超過五百張且股價高於十元的股票如下圖

這些股票反彈起來，有不少還真的是又兇又猛。

並不是所有跌四成的股票都能買，之前跟大家分享過幾個抄底策略，如果下跌四成後又出現這些現象，進場作多的勝率往往超過六成。我把這些策略綜合在一個腳本中，希望可以節省各位的時間，

我寫的腳本如下

if close*1.4<highest(close,60)then begin
variable:count(0);
count=0;
//之前無長紅，最近兩根長紅
input:ratio(5,"長紅的漲幅下限");
if countif(close[5]>=close[6]*(1+ratio/100),60)=0
and countif(close>=close[1]*(1+ratio/100),5)>=2
then count=count+1;

//均線糾結後上漲
input: s1(5,"短期均線期數");
input: s2(10,"中期均線期數");
input: s3(20,"長期均線期數");
input: Percent(2,"均線糾結區間%");
input: Volpercent(25,"放量幅度%");
//帶量突破的量是超過最長期的均量多少%
variable: shortaverage(0);
variable: midaverage(0);
variable: Longaverage(0);

if volume > average(volume,s3) * (1 + volpercent * 0.01)
//放量25%
and lowest(volume,s3)<1000
//區間最低量小於一千張
and volume>2000
//今日成交量突破2000張
then begin
shortaverage = average(close,s1);
midaverage = average(close,s2);
Longaverage = average(close,s3);
value1= absvalue(shortaverage -midaverage);
value2= absvalue(midaverage -Longaverage);
value3= absvalue(Longaverage -shortaverage);
value4= maxlist(value1,value2,value3);
if value4*100 < Percent*Close
and linearregangle(value4,5)<10
then count=count+1;
end;
//低檔五連陽
if trueall(close>open,5) 
then count=count+1;
//急拉
value11=barslast(close>=close[1]*1.07);
if value11[1]>50
//超過50天沒有單日上漲超過7%
and value11=0
//今天上漲超過7%
and average(volume,100)>500
and volume>1000
then count=count+1;
//連續跳空上漲

if countif(open > close[1],5)>=3
//過去五天有三天以上開盤比前一天收盤高
and average(volume,5)>2000
//五日均量大於2000張
then count=count+1;

//連續多日價量回溫
input:period(5,"回溫期數");
value21=GetField("資金流向");
value22=GetField("強弱指標","D");
if countif(value21>value21[1]and value22>0,period)>= 4
and volume>average(volume,20)*1.3
then count=count+1;

//主力回頭收集
input:period1(20);
value31=GetField("分公司賣出家數")[1];
value32=GetField("分公司買進家數")[1]; 
if linearregslope(value31,period1)>0
//賣出的家數愈來愈多
and linearregslope(value32,period1)<0
//買進的家數愈來愈少
and 
close*1.03<close[1]
//今天又跌超過3%
 
then count=count+1;


if count>=1 then ret=1;
end;

我拿這個腳本去回測，並且對照單一腳本在沒有選股，沒有大盤濾網下的回測數據，作成以下的這張表

以上是跑所有股票，回測過去兩年，二十天後出場的回測數據比較。

這個綜合的策略，交易次數夠多，勝率也夠高，除了在大空頭市場之外，表現非常的平穩。

抄底策略不只這幾個，例如我先前介紹過的大跌後的吊人線等，各位可以把收集得到，勝率夠高的策略都用同樣的寫法放在一起，這是小弟我認為最靠譜的交易策略了。

這種抄底策略的另一個好處是，停損點很好設，破底就停損。

因著雲端策略中心愈來愈普及於券商的下單系統，開始出現一種需求，希望可以綜合多個交易策略來考量，只有在特定幾個交易策略近N天內出現多個以上的交易訊號時才出現進場訊號。 這個需求PM應該是有收到，但考慮到 XQ一年才換三次版，且前面已經排了不少需求，所以我想從腳本下手，找出一個方法可以綜合多個腳本考量後再出訊號。

我想舉雲端策略中心裡的例子來跟大家說明這個方法

假設雲端策略裡長線作多的策略裡，我訂閱的策略如下表

共有

1.跌不下去的高殖利率股

2.股價突破籌碼沈澱區

3.投信強買發動

4.爆量剛起漲

5.突破糾結均線

6.低PB股的逆襲

7.即將鎖第一根漲停的中小型股

一共七個策略，或希望如果這個七個腳本有超過兩個在三天內都有出訊號時，系統再通知我，我的作法是寫一個函數來計算近三天這七個腳本共出現多少個訊號。

我寫的函數腳本如下:

var:count(0);
count=0;

condition1=false;
condition2=false;
condition3=false;
condition4=false;
condition5=false;
condition6=false;
condition7=false;

//跌不下去的高殖利率股

 
condition8 = L = Lowest(L,20);
condition9 = H = Highest(H,20);
 
if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),60)
//大盤處於多頭市場
then begin 
 if condition9
 //股價創區間以來高點
 and TrueAll(Condition8=false,20)
 //這段區間都未破底
 and close<close[19]*1.05
 //區間股價漲幅不大
 then condition1=true;
end;

if barslast(condition1=true)<3
then count=count+1;

//股價突破籌碼沈澱區

condition10=false; 

if v[1] > 0 then value1 = (v[1] - GetField("當沖張數")[1])/v[1];
//實質成交比例
 
if value1[1] >0 then value2 = 100*value1/value1[1]-100;
//實質成交比例日變動百分比
value3 = standarddev(value2,5,1);
//實質成交比例日變動百分比的不同天期標準差
value4 = standarddev(value2,10,1);
value5 = standarddev(value2,20,1);
if value3 = lowest(value3 ,20) and
 value4 = lowest(value4 ,20) and
 value5 = lowest(value5 ,20) 
//現在各不同天期的成交比例日變動百分比標準差都處在期間最低點
then condition10=true;
 
// 成交量判斷
 

if tselsindex(10,6)=1
and condition10 
and close crosses over highest(high[1],10)
then condition2=true;
if barslast(condition2=true)<3
then count=count+1;

//投信強買發動

variable: SumForce(0), SumTotalVolume(0),Kprice(0), Kdate(0);
SumForce = Summation(GetField("投信買賣超")[1], 3);
sumTotalVolume = Summation(Volume[1], 3);

if SumForce > SumTotalVolume * 15/100 And Average(Volume[1], 5) >= 1000 then 
begin
 Kprice =highest(avgprice[1],3);
 Kdate = date[1];
end; 

Condition11 = C crosses above Kprice and datediff(date, kdate) <= 60; 
Condition12 = Average(Volume[1], 5) >= 1000;
Condition13 = Volume > Average(Volume[1], 5) * 1.2;
Condition14 = C > C[1];
condition15 = tselsindex(10,6)=1;
if Condition1 And Condition2 And Condition3 And Condition4 And condition5
then condition3=true;
if barslast(condition3=true)<3
then count=count+1;


//爆量剛起漲

 
Condition16 = H=highest(H,60);
 //今日最高創區間最高價
 
Condition17 = V=highest(v,60);
 //今日成交量創區間最大量
 
Condition18 = highest(H,60) < lowest(L,60)*(1 + 14*0.01);
 //今日最高價距離區間最低價漲幅尚不大
 
if Condition1 And Condition2 And Condition3
and tselsindex(10,6)=1
then condition4=true;
if barslast(condition4=true)<3
then count=count+1;

//突破糾結均線
variable: Shortaverage(0),Midaverage(0),Longaverage(0);
variable: AvgHLp(0),AvgH(0),AvgL(0);

//透過Z的時間安排來決定現在用的是那一根Bar的資料 
variable: Z(0);
if currenttime > 180000 
or currenttime < 083000 then 
 Z =0 
else 
 Z=1;

Shortaverage = average(close,5);
Midaverage = average(close,10);
Longaverage = average(close,20);
AvgH = maxlist(Shortaverage,Midaverage,Longaverage);
AvgL = minlist(Shortaverage,Midaverage,Longaverage);

if AvgL > 0 then AvgHLp = 100*AvgH/AvgL -100;

condition19 = trueAll(AvgHLp < 5,20);
condition20 = V > average(V[1],20)*(1+25/100) ;
condition21 = C > AvgH *(1.02) and H > highest(H[1],20);
condition22 = average(volume[1], 5) >= 1000; 
condition23 = tselsindex(10,6)[Z]=1;

if condition19
and condition20 
and condition21 
and condition22
and condition23
then condition5=true;
if barslast(condition5=true)<3
then count=count+1;

//低PB股的逆襲

if GetSymbolField("tse.tw","收盤價") > average(GetSymbolField("tse.tw","收盤價"),10)
then begin
 if close<12
 and H = highest(H,20)
 and close<lowest(low,20)*1.07
 and highest(h,40)>close*1.1
 then
 condition6=true;
end;
if barslast(condition6=true)<3
then count=count+1;

//即將鎖第一根漲停的中小型股
 
Condition24 = Close >= GetField("uplimit") * (1 - 1/100);
Condition25 = TrueAll(Close < GetField("uplimit"), 20);
Condition26 = Average(Volume, 5) >= 1000;
Condition27 = Close > Highest(High[1], 20);
Condition28 = Volume >= Highest(Volume[1], 20);
Condition29 = GetSymbolField("tse.tw","收盤價") > average(GetSymbolField("tse.tw","收盤價"),10); 
if Condition24 And Condition25 And Condition26 And Condition27 And Condition28 and condition29
then condition7=true;
if barslast(condition7=true)<3
then count=count+1;
entrycount=count;

這個腳本的作法是用計數器的寫法來計算每個腳本是否符合三天內出訊號的條件，用barslast這個函數來計算特定策略三天內是否出現訊號，最後完成這個函數，透過這個函數寫的警示腳本就可以變的很簡單

if entrycount cross over 1 then ret=1;

有了這個函數之後，如果我們要找出這七個腳本在三天內不只出現一個訊號，一行就寫完了。

各位可以利用這樣的寫法，把同頻率的策略雷達合成一個腳本去跑，如果要當天同時都出訊號，就不要用barslast就可以。

透過這樣的方法，就可以達到綜合多個策略考量，當不只一個策略出訊號時才通知的效果。

William J. ONeil(威廉歐尼爾)是美國知名的成長型投資大師，他寫的笑傲股市這本書到現在賣超過100萬本，他創的投資者日報，全美訂戶超過30萬戶，他在研究每年美國上漲最兇猛的股票後，發明了CANSLIM選股法則，今天就以CANSLIM法則來做例子，跟大家分享如何透過XS選股中心這個平台，運用系統內建的選股條件，加上系統內建的排行條件，加上自己寫的選股腳本，再加上自己寫的排行條件，完成一個自創的選股系統。

首先我先說明CANSLIM是那七個條件

C：當季EPS成長率至少18~20%(Current quarterly earning per share must be up at least 18~20%)。

A：過去五年EPS顯著成長，複合成長率超過15%(Annual earning per share should be meaningful growth over the last five years, the annual compounded growth rate of earnings in the superior firms should be from 15% to 50%, or even more per year)。

N：新產品、新管理階層或股價創新高 (Buy companies with new products, new management, or significant new changes in their industry conditions, and most important, buy stocks as they initially make new highs in price. Forget cheap stocks—they are usually cheap for a good reason)。

S：流通在外股數少，非大型股，非老公司(Shares outstanding should be small or of reasonable number, not large capitalization, older companies)。

L：漲幅領先市場其他股票，股價表現是績優生(Leader :the 500 best performing stocks from 1953 to 1990 averaged a relative price strength of 87)。

I：機構法人買超(Institutional sponsorship：Buy stocks with at least a few institutional sponsors with better than average recent performance records)。

M：市場走向(Market Direction)。

基於上述的規則，我的選股系統，需符合下面幾個規則:

C:最近兩季EPS平均年增率排在前面

A:過去五年EPS複合成長率超過15%

S:總市值小於300億台幣

L:過去兩年漲幅屬於領先群

I: 投信，外資持有一定張數

在XS上，要完成一個選股系統，得先在選股中心的UI上按新增的ICON，接著就會跳出以下的畫面

依序填好選股策略名稱及選股範圍之後，XS的選股中心一共提供了四種的選股條件產生方式

1. 系統內建的條列式選股條件，使用者只要調整參數即可
2. 系統內建的排行規則，使用者也只要調整參數即可
3. 使用者可以自行透過編輯器撰寫的選股腳本，系統會把符合腳本條件的股票，再跟其他條件一起透過AND 或OR的關連來篩選股票
4. 使用者可以自行透過編輯器撰寫選股函數，再透過自訂排行條件的功能，自建一個排行規則。

XS選股平台為何會提供這麼多種選股條件的產生方式呢? 這是因為，在制定選股條件時，有時必須某值超過某絕對值，例如EPS要超過兩元，但有時只需要在所有股票裡排在前面即可，例如外資一個月的買超累計排名前30名，所以必須分成絕對值的篩選及排行的篩選，而系統內建的條件不見得能滿足使用者的想法，所以才會再提供讓使用者可以透過編輯器自行撰寫選股及排行條件的功能。

以上圖CANSLIM的條件為例

總市值小於300億這個條件系統有內建，我們直接從”選股條件”這個頁籤裡，找出總市值這個欄位，就會找到這個選股條件，把參數填上 3 00，再如上圖的按加號即可以把這個條件加入選股系統中

接下來使用系統內建的排行規則，可以找到年漲跌幅排在前510名的股票。

接著要找出最近兩季EPS平均年增率排在前面的股票，要怎麼挑呢?

首先我們先寫一個函數來計算出最近兩季EPS平均年增率這個值，寫法如下

value1=GetField("每股稅後淨利(元)","Q");
value2=(value1/value1[4]-1)*100;//年增率
value3=(value2+value2[1])/2;
ret=value3;

然後從選股中心裡開啟一個新的選股條件，然後用自訂排行條件這個功能，分別設定這兩個函數計算結果的排行榜，例如都取前一百名，然後透過and這個條件，就可以挑出符合兩個條件排行前一百名的股票。

最後是在股價面上，如果要符合CANSLIM的標準，必須符合兩個條件

1.股價創一年新高。

2.大盤在多頭。

符合上述兩個條件的警示腳本如下:

if high=highest(high,200)
and GetSymbolField("tse.tw","收盤價")>
average(GetSymbolField("tse.tw","收盤價"),20)
then ret=1;

這是股價創兩百日新高且加權指數在月線之上。

綜合以上的選股及警示腳本，就可以完成私房版的CANSLIM交易策略，而這當中的選股方法，我們用到了系統內建的條列式選股條件，也用到了系統內建的排行榜，用了一個自己寫的選股腳本，也用了一個自訂的函數來作排行，這是XS選股平台所提供的四種不同的選股條件產生方式，再搭配上AND與OR的串接，來努力把user的選股思維化成一個電腦可以自動執行的對應程式。這應該是XS選股平台跟坊間其他產品最大的不同吧。

初學程式交易時，寫不了浩然壯闊的大作，僅能用開，高，低，收，成交量這五個欄位，東拼西湊，期能有所收穫。彼時，光跳空相關的策略，就寫了不少，自己覺得效果不錯的，有三個，今天就來跟大家介紹這三個跟跳空有關的策略。

第一個策略叫跳空後的補空，概念如下

1.前一日跳空上漲2%以上

2.今天補空2%以上

3.100日均量超過500張

腳本如下:

if open[1]>close[2]*1.02
and open[1]=low[1]
//前一日跳空
then begin
if close*1.02<=open[1]
//補空2%
and average(volume,100)>500
then ret=1;
end;

第二個策略是加速趕底式的跳空

條件如下

1.前20個交易日下跌超過一成

2.前一日下跌

3.開盤跳空重挫5%

腳本

if close[1]<close[2]
and open*1.05<close[1]
and close[20]>close*1.1
then ret=1;

第三個策略是個股隨大盤跳空大跌

條件如下

1.前一日下跌

2.開盤跳空大跌超過5%

3.當天大盤也跳空下跌

腳本
if close[1]<close[2]
and open*1.05<close[1]
and GetSymbolField(“tse.tw”,”開盤價”)
<GetSymbolField(“tse.tw”,”收盤價”)[1]
then ret=1;

這三個跳空的腳本，寫起來都很短 ，介紹給大家。

書上市後，好像在辦人生交友回顧會，以前的老戰友看完書，考了我一題: 你覺得用技術面，籌碼面，還是基本面寫交易策略比較有用?? 是用1分鐘線有用?還是日線有用? 還是從頭到尾用週線就好?(老戰友是週線應用天王)，我的腦海裡想起一首伍佰的歌:”台灣製造”，裡頭有一句歌詞叫作

“攏乎咱摻摻做伙”

沒錯，根據機率學，如果彼此沒什麼相關性的交易策略，都出現買進訊號，那麼這時候進場買進的勝率，應該要更高才對。

以昨天的雲端策略中心出的訊號為例

昨天一開盤，多次到頂而破這個從技術面出發的策略，出了好幾個訊號，但只有尼克森也同時符合主力默默收集籌碼後攻堅這個籌碼面的交易策略，結果尼克森是所有昨天多次到頂而破跳出來的股票裡，走勢最強的。

再例如，我之前就有聽說過，有個老師最拿手的一招，就是挑出主力買超且BBand出現買進訊號的股票。

我單獨寫了一個bband的進場腳本

setbackbar(20);
input:length(20);
variable:up1(0),down1(0),mid1(0),bbandwidth(0);
up1 = bollingerband(Close, Length, 2);
down1 = bollingerband(Close, Length, -2 );
mid1 = (up1 + down1) / 2;

bbandwidth = 100 * (up1 - down1) / mid1;

if linearregslope(up1,10)[1]<0
and linearregslope(down1,10)[1]>0
and bbandwidth[1]*1.1<average(bbandwidth,20)[1]
and close crosses over mid1
and close crosses over highest(high[1],2)
then ret=1;

用這腳本去跑過去一年的所有股票，回測報告如下，

勝率是48.21%，如果我加上主力前一日買超大於800張這樣的籌碼面條件，腳本如下

condition1=false;
condition2=false;

setbackbar(20);
input:length(20);
variable:up1(0),down1(0),mid1(0),bbandwidth(0);
up1 = bollingerband(Close, Length, 2);
down1 = bollingerband(Close, Length, -2 );
mid1 = (up1 + down1) / 2;

bbandwidth = 100 * (up1 - down1) / mid1;

if linearregslope(up1,10)[1]<0
and linearregslope(down1,10)[1]>0
and bbandwidth[1]*1.1<average(bbandwidth,20)[1]
and close crosses over mid1
and close crosses over highest(high[1],2)
then condition1=true;

value1=GetField("主力買賣超張數");
if value1[1]>800
and volume>=average(volume,20)*1.3
then condition2=true;
if condition1 and condition2 then ret=1;

這時同區間回測出來的交易次數只剩下11次，但其中8次賺錢，勝率超過72%

這一年的數據來看，BBAND的買進訊號，如果考慮到前一晚主力有大買超，勝率會比較高。不過這個策略如果回測的時間拉長，其實勝率也就五成上下，應該是沒有市場傳的那麼神勇。這也是自己寫腳本自己回測的好處，任何聽到的策略，都可以實地測看看。

如果要說技術面與籌碼面整合的不錯的交易策略，小弟倒是可以提供一個，先來看腳本

//全部股票，出場設20天
input:period(20);
value1=GetField("分公司賣出家數")[1];
value2=GetField("分公司買進家數")[1]; 

if linearregslope(value1,period)>0
//賣出的家數愈來愈多
and linearregslope(value2,period)<0
//買進的家數愈來愈少
and
 close*1.05<close[period]
//但這段期間股價在跌
and 
close*1.03<close[1]
//今天又跌超過3%
and close*1.5<close[100]
and tselsindex(10,6)=1
then ret=1;

從這腳本就可以看出，我們是在尋找那種股價在近百日大跌五成但近十日主力卻逆向在收集籌碼的股票，把這個腳本去回測過去五年的所有股票，20天後出場，勝率超過六成，如果持有超過四十天，勝率更超過65%。

這個策略是在尋找那些股價大跌後，主力有沒有重新回補的股票，例如下面這張圖

這個策略實際操作起來，是靠大賺來頂勝率沒有非常高的缺點，如果能輔以基本面的研究，過濾那些基本面有疑慮的股票，應該可以做的更好。

以上大致是我摻摻作伙的操作方式，大抵上就是把技術面跟籌碼面的策略一起考慮進來，濾出來的股票再從基本面去double check。

摻摻作伙，我覺得還行，盍興乎來!!