行情走到這裡，有點驚驚漲的味道，加權指數接下來是續漲? 作頭? 下跌?

我今天想跟大家討論一個觀察的方式，這也是我師父以前常說的，當Top down看不懂的時候，就用bottom up。

當然要我們一檔檔都能了解個別公司未來的基本面變化，是有些困難，但我們可以透過統計方式，試著看看那些公司在uptrend，那些在downtrend，那些在盤整，從這些類別的成份公司，以及家數的變化，或許我們可以對這個大盤的多空方向，有更多的掌握。

舉個例子

上圖是OTC指數的對照圖，大家會發現，OTC指數漲的比加權指數兇的時候，是多頭市場的主昇段，反之，OTC 指數跌的比加權指數兇的時候，是空頭市場的主跌段，這是因為在主昇段的時候，各方勢力一起作多，這時候什麼股票都想表現一下，反之一旦各方勢力撤退，中小型的股票因為缺乏承接的買氣，會是下跌趨勢最明顯的族群。

基於這種觀察，我用R平方這個先前跟大家介紹過的指標來衡量個股目前是屬於上昇趜勢，下降趨勢，盤整，多翻空還是空翻多?

然後透過每天這些類別家數的變化，我們就可以更清楚掌握目前的多空態勢。

我用一個選股腳本來做這件事

input:Length(20); //"計算期間"
setoutputname1("趨勢訊號");
LinearReg(close, Length, 0, value1, value2, value3, value4);
//做收盤價20天線性回歸
{value1:斜率,value4:預期值}
value5=rsquare(close,value4,20);//算收盤價與線性回歸值的R平方
condition1=false;
condition2=false;
condition3=false;
condition4=false;
condition5=false;

if value1>0 and value1[1]>0 then condition1=true;
if value1>0 and value1[1]<0 then condition2=true;
if value1<0 and value1[1]<0 then condition3=true;
if value1<0 and value1[1]>0 then condition4=true;
if value5>0.2 then condition5=true;

if condition1 and condition5
then
begin
ret=1;
outputfield1("上昇趨勢");
end;

if condition2 and condition5
then
begin
ret=1;
outputfield1("翻多");
end;

if condition3 and condition5
then
begin
ret=1;
outputfield1("下降趨勢");
end;

if condition4 and condition5
then
begin
ret=1;
outputfield1("翻空");
end;

if condition5=false
then
begin
ret=1;
outputfield1("盤整");
end;

用這個腳本每天收盤後去跑選股，會看到如下面的畫面

上圖是用價格排序的結果，我們會發現高價股中，超過350元以上的大多在下降趨勢，反而是那些200元到300出頭的不少是在上昇趨勢中。

如果我把昨天的1554檔股票這個資料匯出到excel去計算數據

我們會發現，處於上昇趨勢的股票共有850檔，處於下降趨勢的股票共有215檔，盤整的，沒有明顯趨勢的有467檔。

另外下圖是多翻空及空翻多的個股

翻空的比翻多的多了幾檔。

從這樣的架構，我們每天做追蹤，就可以更清楚地掌握大盤的方向，更重要的是，這可以讓我們在多空轉折點時，更明快的作出決定。

若是對於R平方的意義想要多了解一點，請參考以下這個連結

尋找目前趨勢還向上的股票

行情走到這邊，我發現不少異軍突起的股票，都是屬於那種低股價淨值比的，低PB的股票我們用XS選股每天隨時都可以挑出來，但不是每一檔低PB的股票都會漲，特別是如果盤中我們想要在這類股票一發動時就進場，那麼我們最好能夠在盤中就掌握低PB的股票人氣回籠的徵兆。

怎麼判斷呢?

預估量是一個方法，這些低PB的股票之所以低PB，很大的原因是因為乏人問津。一般乏人問津的股票，其具體的表現就是沒有量，所以當一檔低PB的股票預估當日成交量會比十日均量高出三成且主要都是外盤成交時，就很值得留意了。

那麼我們怎麼透過XS來在盤中找到這種股票呢?

首先我們可以用XS選股挑出低PB的股票

接下來就要拿這341檔來跑預估量會暴增的策略

先前我們有介紹過預估量的函數，其腳本如下:

variable:CloseTime(133000); // 收盤時間
variable: OpenMinutes(270);//一天有幾分鐘開盤
variable: MinutestoClose(270); //到收盤還有幾分鐘
variable: Length(20); //用過去幾天日資料計算
variable: AvgDayVol(0); //平均日量
variable: AvgMinVolinDay(0); //平均分鐘量
variable: LeftVol(0); //剩餘時間的估計量

variable: estVol(0); //最終估計量

AvgDayVol = average(V,Length);

AvgMinVolinDay = AvgDayVol/OpenMinutes; //過去這段時間每分鐘的平均量

MinutestoClose = Timediff(CloseTime,currenttime,"M"); //現在到收盤還有幾分鐘

LeftVol = MinutestoClose *AvgMinVolinDay;// 剩餘時間乘上每分鐘均量 = 盛夏時間可能有多少量

if ( barfreq ="D") then //是日線才會對
begin
if Date =currentdate then //今天才回估量
estVol =volume + LeftVol //估計量 等於 現在的日總量 加上 剩下時間估計的量
else
estVol =v; //過去的話就直接回實際的量
end;
estvolume =estVol;

有了這個預估量的函數，我們就可以很容易的寫出預估量暴增的腳本

value1=q_InSize;//當日內盤量
value2=q_OutSize;//當日外盤量
if estvolume > average(volume[1],10)*1.3//預估量比十日均量多出三成
and value2>value1//外盤量比內盤量多
then ret=1;

接下來我們就用這個腳本來設定策略雷達

如上圖，我們在指定範圍設成PB<0.8的選股法，然後把”觸發設定”設成日內單次觸發，這樣一來，我們就可以讓電腦在盤中只要有那一檔PB<0.8的個股預估量爆增，馬上透過警示中心通知我們。

如下圖:

以今天為例，我大約9:28分啟動這個策略，到中午11:30左右為止，符合低PB且預估量暴量的股票如下:

從上圖我們可以發現，雖然今天指數到11:28分是下跌的，但上面大部份的股票是上漲的。

以在名單上的康那香為例

09:47的時候，康那香符合預估量爆增的條件，那時候的康那香價位是12.15，到了11點之後，康那香的股價已經來到12.85。

透過這個策略我們確實可以在這些低PB乏人問津股票出量的第一時間就掌握進場的時機，但在這邊還是要跟大家說明的是，這些股票能走多遠，還是要看基本面有沒有變化而定。

以在名單中的昱晶為例，到第二季財報為止，它的每股淨值是29.7，如果以股價低於PB X 0.8來算，當股價跌破23.8時，它就符合低PB的條件，我們從K線圖上可以發現，必須要K線也配合是屬於中長紅的格局時，才是多頭人氣重新匯聚的徵兆。

如果是在大漲之後，或者是在下降趨勢之中，則不應輕取妄動。

整體來說，這個低PB暴量的策略如果挑出來的股票又符合多次到底而破，整理後突破等策略，其後市看漲的機率就更高了。

透過switch..case的語法，可以在一個變數的數值不一樣時，往不同的流程進行，例如要計算外資過去十天買超超過七天時，可以運用以下的語法來寫腳本 :

範例：外資近日買超天數比例

//1.宣告參數：利用input宣告輸入的參數。

input:day(10);//過去幾天

input:ratio(0.7);//外資買超的天數佔多少比例

//2.宣告變數，利用variable

value1=GetField("Fdifference");//外資買賣超

variable:count(0);

variable:xi(0);

for xi= 1 to day

begin

//============================================

switch(value1[xi])

begin

case >0:count=count+1;

case <0:count=count;

case 0:count=count;

end;//所有case都表達完之後，最後必須加end;來表示各種數值選項已結束

//============================================

end;

//6.設定警示條件：if.. then ret=1;

if day<>0 and count/day>=ratio

then ret=1;

有的時候，當符合if後面的敘述式時，我們希望電腦幫我們執行的，不只一行的敘述式時， 電腦要怎麼知道有那敘述是在前面條件符合時批次都要執行的呢?我們在DJ Script的語法中，使用begin …….end;的方式， 來標示所有要執行的敘述式。

例如若要找出前N日漲幅超過X%且今天跳空開高超過Y%的股票，我們可以寫一個腳本如下:

//宣告參數：利用input宣告輸入的參數。
input:N(3);//前N日
input:X(10);//前n日漲幅%
input:_Y(4);//缺口大小%
if open>high[1] then //跳空開高
//用begin來呈現if 之後要執行的不只一件的事情
begin
value1=(1-close[1]/close[N])*100;//計算前N天的漲幅
value2=(open-high[1])/close*100;//計算跳空缺口的大小
 
end;
//最後用end來宣告if之後要執行程式的結束
 
if value1>=X and value2>=_Y
then ret=1;

 這樣的流程控制算是if ….then裡最複雜的，用白話文說就是如果……那就開始一連串的動作，反之如果不符合上述條件，就開始進到第二個如果…..那就開始另一連串的動作 以上述的例子的引申為例，我們也可以把上面的例子改寫成以下的腳本 :

一個腳本的完成，有幾個步驟:

1. 我們透過參數及變數的宣告，準備好要加以運算的數據。
2. 我們透過運算因子，完成各種數值間的運算。

接下來，我們必須為這些運算的結果安排其先後順序，以及建構與輸出語法間的的因果關係，這些工作，我們都是透過流程控制的語法來完成， 前面我們有用到的IF ……..THEN就是一個典型的流程控制語法。

接下來的章節，我們就一一來介紹這些控制流程的語法，完成這部份的學習，XS的基本語法，就大致完備了。

if then的流程控制，在腳本中我們最常運用到的流程控制，應該就是如果…………那就……….，也就是if ……..then了

例如我們要電腦在股價創今天高點時通知我們，我們會寫成 :

close=q_dailyhigh then ret=1;

但在撰寫腳本時，並不是每個想法都只是單純的if……..then ，有時候我們在符合某個條件時，想要電腦幫我們處理的， 不只有一行敘述，有時候符合條件時我們希望電腦幫我們執行某動作，在不符合條件時執行另一個動作，因此， 本節我們來學習if…….then這個我們最常用的流程控制語法，到底有那幾種不同的寫法，用來處理不同的情境。

這一種是我們最常用也最簡單的寫法，例如我們要電腦在股票出現K棒三連陽時通知我們，我們只要寫以下的兩行腳本 :

if trueall(close>close[1],3)
then ret=1;

這樣的敘述很單純，就是如果IF後面的那個敘述式為真，那就執行then後面的那一個敘述式。

但有的時候，我們在寫腳本的時候，除了希望在某敘述式為真時，請電腦幫我們執行某敘述，有時候我們也希望當該敘述式false時， 可以為我們執行另一個敘述，這時候的寫法很簡單，就是在then之後的那個敘述式的下方，用else起頭，寫下另一個敘述式就可以了。

例如我們在計算真實波動區間時，我們需要找真實的高點及真實的低點，所謂真實的高點是 :

1. 如果昨天收盤比今天的高點高，那麼昨天的收盤價就是今天的真實高點
2. 如果昨天收盤不比今天的高點高，那麼今天的最高價就是今天的真實高點

在寫成腳本時，我們就可以用if……then …….else的語法來處理如下方的敘述式

if Close[1] > High then TrueHigh = Close[1]
else TrueHigh = High;

我們最常用的語法是如果…….就……否則就……………，但有的時候，我們必須設下不止一層的過濾器，也就是在上面的語法的”否則就……”， 不是一個指示下一個直接運算的敘述式，而是另一個if….then的判斷式敘述。

 

 

 例如我們如果想找開盤就漲停或開盤跳空上漲後，不到九點十五就漲停的股票，我們可以運用以下的腳本 :

if open=q_DailyUplimit then ret=1;

if open>close[1]*1.025 and close=q_DailyUplimit and time<091500 then ret=1;

這樣的架構就是為觸發設定兩個不同的條件，當符合條件A時就觸發，但如果沒有符合條件A，如果符合條件B也可以觸發。

這當中有件事要請各位特別留意，那就是在語法上，要千萬記得

If……..

Then …….

else………..;

如果有else，前面then 之後的敘述式結束時，不要打逗號，要等到else後面的敘述式結束後才打逗號。

這幾日，有一檔股票走勢頗強勁，但從損益表來看，這根本就是一家沒啥前途的公司，但如果從資產負債表來看，感覺這是一家股價遠低於其變現價值的公司，於是，我寫了一個選股的腳本，把有類似這樣情況的公司通通找出來，這家公司叫做矽統，這類的公司，其特點就是市值遠低於帳上扣掉負債後，容易變現的資產。

故事的起頭是，前幾天，我用一個策略雷達挑出了矽統這檔股票。

我看這家公司的損益表，直覺是這家公司基本沒救了。

因為這家公司股本61億，結果一個月營收很久以來都沒有超過3000萬，因此，每年本業總要虧個2到3億。

因為我真的很少看到這種營收比營業費用還小的公司，所以一開始我是覺得這樣的公司下市收掉算了。

但後來又想，這兩天在買股票的人應該也不是傻子，所以我把它的資產負債表拿出來看，一看就看出一些還蠻有趣的地方

上面是它的流動資產及長期投資，其中帳上有13億的現金，至於47億的長期投資，如果我們看他的轉投資，就會發現，聯電這檔股票就佔了41億。

也就是說，這家公司61億的資本額，其中光現金及聯電的股票就值54億。

接下來我們再看一下它的固定資產

帳上是列了7.8億，其中土地就列了4.76億，我看了一下該公司的網站，再用google map的街景圖，找到了它的固定資產應該就是下面這棟位於竹科的廠辦

這顯示它的固定資產應該值帳上列的這個錢。

看完了資產我們來看它的負債

這家公司竟然是一家幾乎無負債的公司，短期借款是零，長期負債也是零。

看到這裡，我們來算一下，它這一波最低跌到4.41 元，以它的股本61億來算，在這種價位附近真的把它買下來，等於花30億買到54億的現金+聯電股票，外加一棟位於竹科的廠辦。

難怪它的股價會很快的就回到五元以上。

這種公司我要是早點找到，這趟反彈就押上去了。這次就算了，下次如果它再跌下來我就知道該怎麼做。

不過因為研究過矽統這檔股票，所以我很好奇這市場上還有沒有矽統第二，所以我就寫了以下這個腳本

input:percent(20);
setinputname(1,"每股易變現資產與股價間的落差比");
value1=GetField("現金及約當現金","Q");//百萬;
value2=GetField("短期投資","Q");//百萬
value3=GetField("應收帳款及票據","Q");//百萬
value4=GetField("長期投資","Q");//百萬
value5=GetField("負債總額","Q");//百萬
value6=GetField("最新股本");//單位: 億
value7=(value1+value2+value3+value4-value5)/(value6*10);
if value7>close*(1+percent/100)
then ret=1;
outputfield1(value7);
setoutputname1("每股快速變現價值");
outputfield2(close/value7);
setoutputname2("股價與快速變現價值");

根據上述的算法，我試著找出股價跟每股快速變現價值差距超過兩成的股票

附圖就是我挑到的股票，有興趣的朋友，不妨也一檔一檔找找看這當中有沒有便宜的太過份的股票。

要先說明的是，這個名單只是初步篩選的結果，能不能真的下去買，還得一檔一檔下去仔細分析才行。

我以藍天為例，這家公司的股本是68億，現金，短期投資加應收帳款有61億，負債66億，但它的長期投資帳上是910億，說穿了，藍天這家公司到底值多少錢，就看這900多億的長期投資值多少錢?

可惜藍天的轉投資主要都是海外的控股公司，像這種的我們就無從查出這裡頭到底真正值多少錢，我們拿來分析矽統的方法，也就不合適拿來套在藍天上面。

在使用這個方法時，有幾個眉角還是要跟大家交代一下

1.短投資裡，如果是上市櫃公司佔多數那還好，不過也要考慮流動性，但如果轉投資裡都是一堆未上市或投資公司，那就得還要再花精神研究這些東西會不會其實已經變成壁紙

2.固定資產我們沒有拿進來算，因為變現不容易，不過如果是位於市區的辦公大樓，其實也可以考慮進去。

3.在挑這一類股價跌過頭的股票時，一定要留意公司經營者的誠信，帳上現金再多，如果經營者是屬於惡搞型的，那也可能兩三下就五鬼搬運光了。

4.這類的公司如果有要減資或是被人借殼，反而股價會比較有表現的機會。

先跟大家分享幾檔股票這幾天的走勢。

眼尖的各位，從上面這幾張圖可以發現，一段時間量縮橫向整理後的中長紅，後市往往還有高點。

是的，這是自從我開始從事程式交易以來，最靠譜的交易策略

這個策略有三個原則

1.超過十個交易日股價橫向整理

2.在整理期間成交量明顯萎縮

3.以中長紅的姿態突破整理

4.突破時帶著比先前多出不少的成交量

過去為了找到這樣的股票，我曾經寫過也用過幾個策略

例如我常推薦大家使用的多次到頂而破策略雷達

input:HitTimes(3); setinputname(1,"設定觸頂次數");
input:RangeRatio(1); setinputname(2,"設定頭部區範圍寬度%");
input:Length(20); setinputname(3,"計算期數");

variable: theHigh(0); theHigh = Highest(High[1],Length); //找到過去其間的最高點
variable: HighLowerBound(0); HighLowerBound = theHigh *(100-RangeRatio)/100; // 設為瓶頸區間上界
variable: TouchRangeTimes(0); //期間中進入瓶頸區間的低點次數,每跟K棒要歸0

//回算在此區間中 進去瓶頸區的次數
TouchRangeTimes = CountIF(High[1] > HighLowerBound, Length);

if TouchRangeTimes >= HitTimes and ( q_ask> theHigh or close > theHigh) then ret=1;

要使用這個策略，可以直接在雲端策略中心中訂閱多次到頂突破這個策略即可

訂閱後每天可以從警示中心這一頁盤中即時跳出符合這個策略的股票

這個腳本的最大問題是只考慮價沒有考慮量，而且只考慮向上突破而沒有考慮先有是否有量縮盤整。

後來我有寫過另一個叫股票箱突破的策略雷達

腳本如下:

input:length(12);
value1=NthHighest(1,high,length);
value3=nthhighest(3,high,length);
value4=Nthlowest(1,low,length);
value5=nthlowest(3,low,length);

if
value1[1]<=1.03*value3[1]
and value5[1]<=value4[1]*1.03
and value1[1]<=value4[1]*1.1
and close>value1[1]
then ret=1;

這個腳本昨天出現訊號的股票如下圖

大家不妨參考對照未來的走勢。

除了上述兩個腳本之外，各位也可以根據上面的那四個定義，另外再寫出一個符合上述邏輯的策略，我覺得只要follow這四個精神，應該可以找到短多的股票，而且，勝率真的夠高。

這個交易策略背後的邏輯是，當股價脫離原先的盤整區域，代表原來的多空平衡已被破壞，一根中長紅代表的是多方正式撃潰空方的最後防線，接下來就是長驅直入了，我們在這時候進場，圖的就是這種空頭全面潰敗，多頭乘勝追擊追撃的過程，這個過程很重要的是

1.要一確定中長紅就跟進去。

2.最好挑那種對峙很久的，這種一被撃潰就後防空虛，多頭可以一路追撃。

3.最好上面沒有太多解套賣壓的。

根據上述這三個原則，各位可以把這個策略的腳本改寫的更精準。