Author Archives: 發財橘子

當多空勢力懸殊時

我們先來看以下的兩檔股票的委買委賣及一分鐘線圖

然後我們發現，當最新五檔委買及委賣出現很懸殊的對比時，短線上，股價往上的機率是比較高的。

在漲跌幅開放為10%之後，如果我們可以在開盤不久，就找到這類的股票，而且運氣好，挑到了今天眾家勢力都想染指的標的，那麼不管是當沖，隔日沖，短線，都是不錯的操作策略。

怎麼才能在盤中挑到這種委買與委賣張數對比很懸殊的股票呢？
我寫了一個腳本如下：

input:v1(2000),v2(500),v3(1500),v4(400),v5(100);
setinputname(1,"委買五檔總金額(萬)");
setinputname(2,"委賣五檔總金額(萬)");
setinputname(3,"委買委賣總差額(萬)");
setinputname(4,"單一價位委買金額下限");
setinputname(5,"單一價位委賣金額上限");
variable:bidtv(0),asktv(0),tb(0),ta(0),b1(0),b2(0),b3(0),b4(0),b5(0),s1(0),s2(0),s3(0),s4(0),s5(0);
condition1=false;
condition2=false;
condition3=false;
bidtv=q_SumBidSize;//總委買
asktv=q_SumAskSize;//總委賣

value1=q_BestBidSize1;//委買一
value2=q_BestBidSize2;
value3=q_bestbidsize3;
value4=q_bestbidsize4;
value5=q_bestbidsize5;

value6=q_bestasksize1;//委賣一
value7=q_bestasksize2;
value8=q_bestasksize3;
value9=q_bestasksize4;
value10=q_bestasksize5;

tb=bidtv*close/10;
ta=asktv*close/10;

if tb>v1 and ta<v2 and tb-ta>v3
then condition1=true;

b1=value1*close/10;
b2=value2*close/10;
b3=value3*close/10;
b4=value4*close/10;
b5=value5*close/10;
s1=value6*close/10;
s2=value7*close/10;
s3=value8*close/10;
s4=value9*close/10;
s5=value10*close/10;

if b1>v4 and b2>v4 and b3>v4 and b4>v4 and b5>v4
then condition2=true;

if s1<v5 and s2<v5 and s3<v5 and s4<v5 and s5<v5
then condition3=true;

if close<>q_DailyUplimit
then begin
if condition1 or (condition2 and condition3)
then ret=1;
end;

我自己在運用這個腳本時，有些心得跟大家分享
１．當先前很強的股票回檔整理後，如果開盤沒多久就出現這樣的訊號，往往是整理結束準備再次上攻的訊號。
２．如果股票一路大跌後，且盤中還是跌，出現這種訊號，要留意外盤成交的積極度，我有幾次去搶這種股票的帽子，結果沒啥人願意追價，最後只好認賠出場
３．買盤有人虛掛是很正常的，但如果連最近一檔都敢掛大單，那就代表掛單的人不怕被成交到，這種訊號的可信度較高。
４．原本冷門的股票突然間委買每一檔都掛了很多買單，這種搶帽子成功的機會比較大。
５．不要只看委買方，委賣方這種沒啥人掛賣單的現象，應該會因為委買掛了很多而往上掛，如果委賣委買的單子都很多，只能算勢均力敵。

隨著撮合時間的縮短，以及漲跌幅的放寬，加上掛牌的股票已經超過1500檔，用肉眼憑盤感挑股票有了極限，透過電腦先濾出這種買賣力懸殊的股票，然後再擇其中一些較有把握者，列入搶帽子的標的，不失為一個不錯的方法，提供給大家，至於其中的參數，各位可以視各人之偏好而更改。

修正式價量指標VPT(Volume price trend)

在推廣XS的過程中，我有一些年紀大的，不大有學習動機跟能力的朋友，會直接嗆我說:”你說的這些我都聽攏謀，霧煞煞” 。你直接給我一個指標，看漲看跌清清楚楚的，我學不了那麼多。

每次踫到這種，我都很想請他自己去買把槍，買個口罩及安全帽。

在我使用XS的過程中，我確實是設計過很多的指標，若要說有考慮到價跟量，又能指出多空趨勢，又要能夠濾掉那些因為一時衝動所造成的假訊號的，倒是有個指標。

這個指標我稱之為修下式價量指標。

這個指標的概念很簡單
1.先算出每天的Midprice。也就是每天的開高低收四個值的平均值。
2.然後把這個值乘以每天價格的漲跌幅，再乘上當天的成交量。
3.然後一路累加這個數值。

這樣計算出來的指標，在盤整時整條線會很貼近水平線，只有在漲跌趨勢很明確時才會上漲或是下跌，所以如果拿它跟它自身的一定週期移動平均線來對照，我們可以看到非常明確的進出場訊號。
我把上述的概念及算法用XS語法寫的指標如下:
移動平均線的天期就勞煩各位自己調整了

input:days(10);
setinputname(1,"移動平均線天數");
var:tvp(0),mpc(0);
mpc=(open+high+low+close)/4;

if mpc[1]<>0
then
tvp=tvp[1]+(mpc-mpc[1])/mpc[1]*volume
else
tvp=tvp[1];
value1=average(tvp,days);
plot1(tvp,"修正型價量指標");
plot2(value1,"移動平均");

我們來看兩個例子

這兩檔股票都曾經歷經很長的整理期，tvp展現出來的就是長期橫向的水平走勢，我們每天看到小紅小黑，心裡七上八下，但從tvp指標來看，有沒有真的離開橫向盤整的格局，其實就很清楚了。

除權前後的操作策略

如果你是大股東，手中有數萬張的公司股票，公司每年配息給你十億，但因為兩稅合一，公司繳過營所稅的部份可以扣抵你的股利收入，因為營所稅率是17%，個人綜合所得稅最高稅率是40%，所以你股利部份要多繳的稅率是40%-17%=23%，你一共要繳2.3億的稅，如果您想避這個稅，設投資公司，保留盈餘扣10%的稅，未來分配照樣要繳稅，23%的稅也還好，所以只要公司展望還OK，還是會參加除息。

今年稅制改變，兩稅合一減半扣抵，綜所稅年所得淨額逾1,000萬元，增列稅率45％課稅級距。
你如果你跟往年一樣，參與配息，您要繳的稅是 45%-17%×50%=36.5% ，一共是要繳3.65億的稅

這時候，你該怎麼辦?

大部份上市櫃公司的大股東們，如果息值很高，
除非他們公司今年的爆發性很大，很有把握可以填息後還能持續大漲
不然最好的方法是除息前能漲到一個高點大家先賣一賣，除息後再找低點慢慢補回來。

因此，對於高股息的個股，我們要留意兩個時點

1.除息前會不會見高點
2.除息後何時大股東會回補

第一種一般符合三個條件
1.高股息
2.先前大漲過
3.快接近除息日

於是我用XS設了以下的三個條件

各位不妨自行調整參數，找出符合第一種條件的股票

第二種一般則需符合三個條件
1.除息日已過
2.除息前大跌過
3.高股息

我也用XS設了四個選股條件

這是政策改變造成大股東行為的改變
我們一方面不要被掃到颱風尾
二方面也不妨留意這中間有沒有一些套利的空間

改良版的移動平均線~四大力道線

我們經常用收盤價作移動平均線，然後尋找不同天期的均線，出現黃金交叉時買進，出現死亡交叉時賣出。

之所以這麼做，是因為我們覺得收盤價是當天多空爭戰的最後結果，所以拿收盤價的移動平均代表了一段時間多空爭戰的軌跡。

但如果我們細看每根K棒，我們其實除了收盤價之外，還有當天的開盤價，最高價，最低價，我們可以運用這些價位，更精確的勾勒出當天多空爭鬥的力道。

就像上面的這張圖
我們可以
1.把每天最高價到收盤價的距離，視為當天上檔的賣壓
2.把每天最低價到收盤價的距離，視為下檔的支撐
3.把每天開盤價到收盤價之間的距離，視為多方或空方的戰績
4.把前一天收盤價到今天開盤價的距離，視為前一日收盤後多空消息消化後的結果

當我們把這種多空力道都考慮進去之後，我們可以計算一段時間這些力道的總和，這樣的總和，會比收盤價更能表現出這檔商品多空力道的消張。

根據這樣的想法，我寫了一個指標，這個指標的寫法如下:

input:days(10),period(20);
setinputname(1,"短期參數");
setinputname(2,"長期參數");

value1=summation(high-close,period);//上檔賣壓
value2=summation(close-open,period); //多空實績
value3=summation(close-low,period);//下檔支撐
value4=summation(open-close[1],period);//隔夜力道
if close<>0
then
value5=(value2+value3+value4-value1)/close;
value6=average(value5,days);
plot1(value5,"四大力道線");
plot2(value6,"移動平均線");

我把這個指標稱為四大力道線
從上圖我們可以發現，這個指標在趨勢轉折時，比較可以敏感地偵測出多空力道的微妙變化，在盤整時，則會在零附近呈現鋸齒狀波動。

所以我們可以拿這個指標，來輔助我們找到多空方向在微妙轉變的股票。

尋找可能斷頭的股票

在漲跌幅開放為10%之後，融資維持率從120調高到130，這使得股票如果從融資的價位跌了兩成，一旦短線再跌，就開始有被券商發出追繳通知的風險，萬一沒有錢補，斷頭的賣壓就會出現在隔一天的早盤。

我用XS寫了一個選股腳本，專門尋找那些可能有斷頭危機的股票，腳本如下:

input:period(30);//波段的天期
setinputname(1,"波段天期");
SetTotalBar(100);
value1=GetField("融資餘額張數","D");//取得最新融資餘額張數
value2=nthhighestbar(1,close,period);//找出波段最高點落在那一根bar
if value1>average(volume,5)//融資餘額大於五日均量
and value1[value2]>10000//波段高點的融資餘額超過一萬張
and close*1.2<=close[value2]//波段高點迄今跌幅超過兩成
then ret=1;

用這個腳本，可以在大盤下跌趨勢中，找到那些股票比較可能出現多殺多的情況

盤感好的股票

漲跌幅放寬到一成之後，有愈來愈多的操作者，更用力的砥礪自己的當沖技能，想要享受一天賺10%的快感。

朋友中的強者，一直跟我強調，如果要做當日沖，根本不要管什麼基本面，籌碼面，這些都是歷史，最重要的是當天的盤感。

盤感好的股票易漲難跌。

我根據他的說法，寫了一個即時的腳本如下:

value1=q_AvgLongUnits;//委買均張
value2=q_AvgShortUnits;//委賣均張
value3=q_InSize;//當日內盤量
value4=q_OutSize;//當日外盤量

value5=q_BestBidSize;//委買張數
value6=q_BestAskSize;//委賣張數
value9=q_BestBidSize1;//委買一張數
value10=q_BestAskSize1;//委賣一張數
value11=q_BestBidSize2;
value12=q_BestAskSize2;
value13=q_BestBidSize3;
value14=q_BestAskSize3;
value15=q_BestBidSize4;
value16=q_BestAskSize4;
value17=q_BestBidSize5;
value18=q_BestAskSize5;
condition1=false;
condition2=false;

if value1-value2>1 and value4>value3 and value5-value6>200
then condition1=true;

if minlist(value9,value11,value13,value15,value17)>50
and maxlist(value10,value12,value14,value16,value18)<30
then condition2=true;
if condition1 and condition2 then ret=1;

他的精神很簡單，就是當天外盤成交的多，委買的是大咖的，委賣的是散單
然後五檔委買勇於掛進，掛在五檔委賣的都是小單

他認為這種股票比較有機會收上去。

各位可以拿這腳本做基礎，改成您的盤感偵測器。

短線交易比例

放寬漲跌幅之後，短線大家追逐強勢股的趨勢更加明顯，這時候最怕的就是愛到最高點，愛到反轉點。

我研究這些強勢股的多空轉折點時，發現股價在大漲後，如果成交量暴增，當沖及融資買進佔成交量比重接近六成時，往往是短線過熱的一個指標，這種股票就不宜再追高，如果手中有持股，不妨先獲利了結。

基於這樣的觀察，我寫了一個指標:

input:p1(5);
setinputname(1,"移動平均線天期");
value1=GetField("融資買進張數");
value2=GetField("現股當沖張數");
value3=GetField("資券互抵張數");

value4=value1+value2+value3;

if volume>0
then value5=value4/volume;
value6=average(value5,p1);

plot1(value5,"短線交易比例");
plot2(value6,"移動平均線");

從腳本的寫法看得出來，這個指標是在計算融資買進加資券互抵加現股當沖合計佔成交張數的比例。

我們以最近最熱的旅遊股雄獅做例子

股票短線急漲後，出現量增且短線交易比例接近0.6時，股價就出現反轉了。

基於這樣的指標，我寫了一個選出短線過熱股票的選股腳本

input:p1(5),p2(20),p3(15);
setinputname(1,"成交量比前一天多?%");
setinputname(2,"漲幅計算區間");
setinputname(3,"區間漲幅下限");

settotalbar(100);

value1=GetField("融資買進張數");
value2=GetField("現股當沖張數");
value3=GetField("資券互抵張數");

value4=value1+value2+value3;

if volume>0
then value5=value4/volume;

if volume>volume[1]*(1+p1/100)
and value5>=0.59
and close>close[p2-1]*(1+p3/100)
then ret=1;

各位不妨把這腳本拿出選股，看看短線過熱後股票後市怎麼走?

靜極思動

漲跌幅開放到10%之後，我們初步發現，羊群效應更明顯，大家更只願意在熱門股中交易，對於那些冷門股，就算再便宜，在沒有出量之前，大家都興趣缺缺，因為漲跌幅放寬大家會更重視流動性的問題。

但熱門股漲太多時，多少會有點買不下手。

於是，我想了幾個原則，來去找那些才剛轉熱沒多久的股票，我設了幾個條件

1.近三天的平均真實波動區間比過去十五日的真實波動區間大超過2%

2.近三天的平均成交量比過去十五天平均成交量高出2成以上

3.最高價比過去五天的最高價還高

4.成交量大於五百張

根據這些條件，對應的腳本如下

input:r1(3),r2(15),r3(5);
setinputname(1,"短天期均量及真實波動區間的長度");
setinputname(2,"長天期均量及真實波動區間的長度");

settotalbar(100);

if average(truerange,r1) >= average(truerange,r2)*1.02
and average(volume,r1)>=average(volume,r2)*1.2
and high>=highest(high[1],r3)
and close<=close[r3]*1.1
and volume>500
then ret=1;

WVAD威廉變異離散量

WVAD威廉變異離散量的理論，建立在幾個基礎上
1.每天的收盤價減開盤價，是當天盤中多空真正的角力結果
2.每天的最高價減去最低價，則是多空拉距過的最大痕跡
3.所以真正可以代表多空力道的成交量，應該是第一項除以第二項之後的比例去乘以當天的成交量。
4.把每天的這個成交量累計五天，就是WVAD威廉變異離散量

以下是根據這樣的理論所寫出來的腳本

input:length(5);
variable:wvad(0);
value1=close-open;
value2=high-low;
if high<>low
then value3=value1/value2*volume
else
value3=value3[1];
wvad=summation(value3,length);
plot1(wvad,"威廉變異離散量");
plot2(0);

因為它的計算原理是這樣來的，所以在應用上大約可以把握幾個原則

1.指標由負翻正代表近五日盤中買力贏過賣力，是短多的徵候。

2.指標低檔或高檔背離是一個領先的反轉訊號

3.在零附近游走代表多空勢力相差不大。

Q指標

看到Q您會想起誰? Meggi Q ，這麼回答的可不是技術指標狂，做為一個技術分析重度狂熱者，看到Q就想到Q指標。

這個指標的設計蠻有意思，它的概念是這樣

1.先算出一定期間內，每天的收盤價跟前一天收盤價差的累計值。這個值如果股價一路往上，愈漲愈兇時會一路走高，相反的，如果是一路走低愈跌愈傪時會一路下跌，如果是盤整盤，那就在零上下波動。

2.把一段期間來，每天股價漲跌取絕對值，然後再算這段期間的移動平均值，這個值就是這檔股票每天平均的漲跌值。

3.然後把這兩個值相除再乘以5，代表的是這檔股票短期內的漲跌累計值的移動平均，和較長期間的波動絕對值相比，佔的比例是多少?

對應的腳本如下:

input:t1(10);
input:t2(5);
input:t3(20);
setinputname(1,"計算累積價格變動的bar數");
setinputname(2,"計算價格累積變化量移動平均的期別");
setinputname(3,"計算雜訊的移動平均期別");
value1=close-close[1];//價格變化
value2=summation(value1,t1);//累積價格變化
value3=average(value2,t2);
value4=absvalue(value2-value3);//雜訊
value5=average(value4,t3);//把雜訊移動平均
variable:Qindicator(0);
if value5=0
then Qindicator=0
else
Qindicator=value3/value5*5;
plot1(Qindicator,"趨勢值");

如果這個值大於零，代表最近的累積上漲幅度比跌幅度大。
這個值愈高，代表漲勢愈大。

相反地，低於零代表在漲少跌多。

這個指標的妙用之處是在於化繁為簡，看K線看到眼花時，看看Q指標，就知道現在到底趨勢是在那邊

如果在零以下打平後往上走，就是個買進訊號

如果在零以上打平後往下彎，就是個賣出訊號