價值型轉機股

By | 2016-02-23

今年開紅盤以來 ,漲幅超過兩成的股票共有42檔,其中31檔股價在 50元以下,32檔最近一個月的月營收年增率是成長的,29檔本益比在20以下,其中有一部份是虧錢的公司,這些數字顯示,這一波的領頭羊是那些低PB且營運具轉機的個股,我稱之為價值型轉機股,今天來跟大家介紹一些這方面的選股腳本。

當我想知道現在是什麼類型的股票在帶頭上漲時,我會用底下的腳本去跑選股:

input:startdate(20160203);
input:ratio(15,"漲幅下限");
value1=getbaroffset(startdate);
if close[value1]<>0
then value2=(close-close[value1])/close[value1]*100;
if value2>ratio
then ret=1;
outputfield(1,value2,1,"區間漲跌幅");
outputfield(2,GetField("股價淨值比","D"),2,"股價淨值比");
outputfield(3,GetField("月營收年增率","M"),2,"月營收年增率");
outputfield(4,GetField("本益比","D"),1,"本益比");

這個腳本跑出來的股票,我透過股價,股價淨值比,月營收年增率及本益比四個面象,去判斷現在是流行成長股,價值型股,低價股/高價股,還是低本益比股。

從封關到昨天收盤為止,透過這個腳本選出來的,漲幅超過兩成的股票中,PB較低的股票如下:

022001

我們會發現,這當中不少股票,最近一個月的月營收年增率有著明顯的成長。

這種股票,我幫它取了一個名字: “價值型轉機股”。

這種股票有兩個特徵:

1.股價跌到其市值低於其真實價值

2.營運最壞的時候過去了。

後者比較容易判斷,只要看月營收的數字即可,前者比較麻煩,什麼叫作真實價值呢? 有的股票適合用股價淨值比來衡量,有的適合用本益比來衡量,於是,我乾脆寫了一個腳本,把各種衡量價值型股票的常見方法全部寫出來,然後個股只要符合其中一個條件我就把它挑出來,然後再把這一整群的個股搭配營收是否成長的選股條件,這樣就可以找出所謂的”價值型轉機股”。

我寫的腳本共有六個:

一,本益比小於 15 倍 股價淨值比小於 2 倍 殖利率大於 3%

{本益比小於 15 倍 股價淨值比小於 2 倍 殖利率大於 3%}
if GetField("本益比","D") < 15 and
 GetField("股價淨值比","D") <2 and
 GetField("殖利率","D") > 3 and
 GetField("營收成長率","Q") >0 
  then ret=1;

這個腳本是最基本的篩選條件

二,用月營收推估的低本益比股

value1=GetField("月營收","M");//單位:億元
value2=GetField("月營收月增率","M");
value3=GetField("月營收年增率","M");
value4=GetField("營業利益率","Q");
value5=GetField("最新股本");//單位:億元
condition1=false;
condition2=false;
input:peraito(12);
setinputname(1,"預估本益比上限");
if value5<>0
then
value6=(value1*value4*12)/(value5*10);//單月營收推估的本業EPS
if value6<>0
then 
value7=close/value6;

if value7<peraito and value7>0

then ret=1;

這個腳本是用單月營收去推算來自本益的盈餘,然後再用這個盈餘去計算本益比

三,每股的流動資產遠大於股價

input:percent(20);
 setinputname(1,"每股易變現資產與股價間的落差比");
 value1=GetField("現金及約當現金","Q");//百萬;
 value2=GetField("短期投資","Q");//百萬
 value3=GetField("應收帳款及票據","Q");//百萬
 value4=GetField("長期投資","Q");//百萬
 value5=GetField("負債總額","Q");//百萬
 value6=GetField("最新股本");//單位: 億
 value7=(value1+value2+value3+value4-value5)/(value6*10);
 if value7>close*(1+percent/100)
 then ret=1;

這個腳本是找出那些每股可以快速變現的價值高於每股股價

四,流動性資產減負債超過市值N成

input:ratio(80,"佔總市值百分比%");
if (GetField("流動資產","Q")-GetField("負債總額","Q"))/100>GetField("總市值","D")*ratio/100
then ret=1;

這個腳本找出那些股價已經很接近淨流動性資產的股票

五,高現金總市值比的公司

//現金總市值比高的公司 
value1=GetField("現金及約當現金","Q");//單位百萬
value2=GetField("短期投資","Q");//單位百萬
value3=(value1+value2)/100;//單位億之現金及短期投資合計金額
value4=GetField("總市值","D");//單位:億
if value4<>0
then value5=value3/value4;//現金總市值比;
if value5>0.7 and value3>3 //現金總市值比大於0.7且現金及短投合計超過3億
then ret=1;

這個腳本是找出那些有大量閒置現金,但股價低的公司

六,高自由現金流量總市值比

input:ratio(50);
 setinputname(1,"近四季自由現金流總合佔總市值最低比率單位:%");
if (GetField("來自營運之現金流量","Q")+GetField("來自營運之現金流量","Q")[1]+
 GetField("來自營運之現金流量","Q")[2]+GetField("來自營運之現金流量","Q")[3]-
 GetField("資本支出金額","Q")-GetField("資本支出金額","Q")[1]
 -GetField("資本支出金額","Q")[2]-GetField("資本支出金額","Q")[3])
 >GetField("總市值","D")*100*ratio/100
 then ret=1;

這個腳本可以用來尋找那些有創造出高自由現金流量但股價低估的公司

我把這六項腳本全部放到一個選股法中,然後設定任何一檔個股只要符合這六項的其中兩項就被選出來

設定的畫面如下:

022501

如些設定後挑出的股票共有269檔,我把符合條件較多項的列在下方

022502

 

這269檔股票就是我們一般定義的價值型股,接下來我們就可以留意這269檔股票的營運是否出現轉機,若是出現轉機,就符合我所謂價值型轉機股的定義,而這種股票,應該會是今年大家買的較為安心的族群。

以上的流程,對於價值型股票的定義,大家可以自行調整或設計,但是尋找價值型轉機股的這個方法,大家不妨持續不斷地嚐試,小弟過往依賴這個方法,有不錯的實戰效果。