Author Archives: 發財橘子

要如何避免自己的持股變成處份股票？

這一波不少股票急漲急跌，甚至不是漲停就是跌停，很多原本氣勢如虹的股票，在交易所宣佈成為處置股票之後，多頭氣竭，反轉直下，為了避免手中的持股可能變成處置股票，我們同事根據相關法規，寫了一個選股腳本，每天找出可能被宣佈成為處置股票的高危險群，如果大家手中的持股名列其中，那就要很小心，因為如果今天盤中又符合相關條件，那今天收盤後被宣佈成為處置股票的機率就急遽升高。

這個選股腳本很長，我先把腳本po在下面

SETBARFREQ("AD");
setbarback(100);
Input:Len(90);
Var:TSEClose(0),TSEVolume(0),StockChangeRatio(0),TSEChangeRatio(0);
Var:AlertCount41(0),AlertCount42(0),AlertCount43(0),AlertCount44(0),AlertCount47(0),AlertCount48(0),AlertCount49(0),AlertCount410(0),AlertCount411(0),AlertCount412(0);
Var:AlertCount61(0),AlertCount21(0);

// 計算
// TSE成交價
TSEClose=GetSymbolField("TSE.TW","收盤價","D");
// TSE成交量
TSEVolume=GetSymbolField("TSE.TW","成交量","D");
// TSE漲跌幅
TSEChangeRatio=GetSymbolField("TSE.TW","漲跌幅","D");
// 個股漲跌幅
StockChangeRatio=GetField("漲跌幅","D");

// 【上市】
{===============================================================================================================================================================
Condition50
第四條第一項第一款
4.1. 最近一段期間累積之收盤價漲跌百分比異常者。
本要點第四條第一項第一款「有價證券最近一段期間累積之收盤價漲跌百分比異常者」，係指有價證券當日達下列各款情事【之一】者：
Condition1
一、最近六個營業日（含當日）累積之收盤價漲跌百分比超過百分之三十二，且其漲跌百分比與全體有價證券及同類有價證券依本項規定計算之平均值的差幅均在百分之二十以上者。
Condition2
二、最近六個營業日（含當日）累積之收盤價漲跌百分比超過百分之二十五，且其漲跌百分比與全體有價證券及同類有價證券依本項規定計算之平均值的差幅均在百分之二十以上，
及最近六個營業日（含當日）起迄兩個營業日之收盤價價差達新臺幣五十元以上者。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價漲跌百分比，不納入前項標準之計算。
二、有價證券或指數在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價或收盤指數漲跌百分比時，排除此項變動因素。
Condition3
三、有價證券（不含認購（售）權證）當日收盤價未滿新臺幣五元者不適用前項標準。
四、同類有價證券未達五種者不適用前項有關類股之規定。
Condition4
五、有價證券本益比為負值或達六十倍以上者不適用前項有關類股之規定。
六、公開資訊觀測站公告有價證券當日之前一個營業日溢（折）價百分比達下列情事之一者，不適用前項標準：
（一）未超過百分之十。
（二）與前項所達標準漲（跌）之方向相反。
}
// 基本條件
Condition1=100*(C-C[5])/C[5]>32 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]>=20;
Condition2=100*(C-C[5])/C[5]>25 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]>=20 and C-C[5]>=50;
// 除外條件 
Condition3=C<5;
Condition4=GetField("本益比","D")<0 or GetField("本益比","D")>=60 ;
// 條件整合
Condition50=Condition1 or Condition2 and (Not Condition3 or Not Condition4);

// 篩選
If Condition50 Then Begin 
AlertCount41=1;
End;

{===============================================================================================================================================================
Condition100
4.2. 第四條第一項第二款
本要點第四條第一項第二款「有價證券最近一段期間起迄兩個營業日之收盤價漲跌百分比異常者」，係指有價證券當日達下列各款情事【之一】者：
Condition51
一、有價證券最近三十個營業日（含當日）起迄兩個營業日之收盤價漲跌百分比超過百分之一百，且符合下列二項條件【之一】：
（一）其漲幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之八十五以上，及當日收盤價須高於當日開盤參考價者。
（二）其跌幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之八十五以上，及當日收盤價須低於當日開盤參考價者。
Condition52
二、有價證券最近六十個營業日（含當日）起迄兩個營業日之收盤價漲跌百分比超過百分之一百三十，且符合下列二項條件【之一】：
（一）其漲幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之一百一十以上，及當日收盤價須高於當日開盤參考價者。
（二）其跌幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之一百一十以上，及當日收盤價須低於當日開盤參考價者。
Condition53
三、有價證券最近九十個營業日（含當日）起迄兩個營業日之收盤價漲跌百分比超過百分之一百六十，且符合下列二項條件【之一】：
（一）其漲幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之一百三十五以上，及當日收盤價須高於當日開盤參考價者。
（二）其跌幅百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅均在百分之一百三十五以上，及當日收盤價須低於當日開盤參考價者。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價漲跌百分比，不納入前項標準之計算。
二、非分離型附認股權公司債、非分離型附認股權特別股、認購（售）權證、認股權憑證不適用前項標準。
Condition54
三、有價證券最近三十個營業日（含當日）內，已依本要點第四條第一項第一款公布注意交易資訊，
且其最近六個營業日（含當日）累積之收盤價漲跌百分比達下列情事之一者，不適用前項標準：
Condition55
（一）未超過百分之二十五。
Condition56
（二）超過百分之二十五，且其漲跌百分比與全體有價證券及同類有價證券依最近六個營業日（含當日）累積之收盤價漲跌百分比計算之平均值的差幅均未達百分之二十以上。
（三）與前項各款所達標準漲跌之方向相反。

四、有價證券最近六十個營業日（含當日）內，最近一次經依本要點第六條第二項或第三項規定發布處置，其處置原因僅有前項標準情事，
且其最近六個營業日（含當日）累積之收盤價漲跌百分比達下列情事之一者，不適用前項標準：
Condition58
（一）未超過百分之十。
Condition59
（二）超過百分之十，且其漲跌百分比與全體有價證券及同類有價證券依最近六個營業日（含當日）累積之收盤價漲跌百分比計算之平均值的差幅均未達百分之五以上。
（三）與前項各款所達標準漲跌之方向相反。
五、有價證券在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價漲跌百分比時，排除此項變動因素。
六、同類有價證券未達五種者不適用前項有關類股之規定。
Condition60
七、有價證券本益比為負值或達六十倍以上者不適用前項有關類股之規定。
八、公開資訊觀測站公告有價證券當日之前一個營業日溢（折）價百分比達下列情事之一者，不適用前項標準：
（一）未超過百分之十。
（二）與前項所達標準漲（跌）之方向相反。
}
// 基本條件
Condition51=100*(C-C[29])/C[29]>100 and 100*(C-C[29])/C[29]-100*(TSEClose-TSEClose[29])/TSEClose[29]>=85 and C<>O;
Condition52=100*(C-C[59])/C[59]>130 and 100*(C-C[59])/C[59]-100*(TSEClose-TSEClose[59])/TSEClose[59]>=110 and C<>O;
Condition53=100*(C-C[89])/C[89]>160 and 100*(C-C[89])/C[89]-100*(TSEClose-TSEClose[89])/TSEClose[89]>=135 and C<>O;
// 除外條件 
Condition54=trueany(Condition50,30);
Condition55=Condition54 and 100*(C-C[5])/C[5]<=25;
Condition56=Condition54 and 100*(C-C[5])/C[5]>25 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]<20;

Condition58=100*(C-C[5])/C[5]<=10;
Condition59=Condition54 and 100*(C-C[5])/C[5]>10 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]<5;
Condition60=GetField("本益比","D")<0 or GetField("本益比","D")>=60 ;
// 條件整合
Condition100=Condition51 or Condition52 or Condition53 and (Not Condition55 or Not Condition56 or Not Condition58 or Not Condition59 or Not Condition60);

// 篩選
If Condition100 Then Begin 
AlertCount42=1;
End;

{===============================================================================================================================================================
Condition150
4.3. 第四條第一項第三款
本要點第四條第一項第三款「有價證券最近一段期間累積之收盤價漲跌百分比異常，且其當日之成交量較最近一段期間之日平均成交量異常放大者」，係指有價證券當日【同時】達下列各款情事者：
Condition101
一、最近六個營業日（含當日）累積之收盤價漲跌百分比超過百分之二十五，且其漲跌百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅，均在百分之二十以上。
Condition102
二、當日之成交量較最近六十個營業日（含當日）之日平均成交量放大為五倍以上，且其放大倍數與全體有價證券依本款規定計算之平均值相差四倍以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價漲跌百分比、日成交量，不納入前項標準之計算。
二、轉換公司債、非分離型附認股權公司債、非分離型附認股權特別股、債券換股權利證書、認購（售）權證、認股權憑證、指數股票型基金受益憑證、指數投資證券不適用前項標準。
三、有價證券在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價漲跌百分比時，排除此項變動因素。
Condition103
四、有價證券當日週轉率未達千分之一以上，或成交量未達五百交易單位以上者，不適用前項標準。
五、同類有價證券未達五種者，不適用前項有關類股之規定。
Condition104
六、有價證券本益比為負值或達六十倍以上者，不適用前項有關類股之規定。
七、公開資訊觀測站公告有價證券當日之前一個營業日溢（折）價百分比達下列情事之一者，不適用前項標準：
（一）未超過百分之十。
（二）與前項所達標準漲（跌）之方向相反。
}
// 基本條件
Condition101=100*(C-C[5])/C[5]>25 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]>=20;
Condition102=V/Average(V,60)>=5 and V/Average(V,60)>=4*TSEVolume/Average(TSEVolume,60);
// 除外條件 
Condition103=GetField("週轉率","D")<0.1 or V<500;
Condition104=GetField("本益比","D")<0 or GetField("本益比","D")>=60 ;
// 條件整合
Condition150=Condition101 and Condition102 and (Not Condition103 or Not Condition104);

// 篩選
If Condition150 Then Begin 
AlertCount43=1;
End;

{===============================================================================================================================================================
Condition200
4.4. 第四條第一項第四款
本要點第四條第一項第四款「有價證券最近一段期間累積之收盤價漲跌百分比異常，且其當日之週轉率過高者」，係指有價證券當日【同時】達下列各款情事者：
Condition151
一、最近六個營業日（含當日）累積之收盤價漲跌百分比超過百分之二十五，且其漲跌百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅，均在百分之二十以上。
Condition152
二、當日週轉率百分之十以上，且其週轉率與全體有價證券依本款規定計算之平均值的差幅在百分之五以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價漲跌百分比，不納入前項標準之計算。
二、轉換公司債、非分離型附認股權公司債、非分離型附認股權特別股、債券換股權利證書、認購（售）權證、認股權憑證、指數股票型基金受益憑證、指數投資證券不適用前項標準。
三、有價證券在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價漲跌百分比時，排除此項變動因素。
四、同類有價證券未達五種者，不適用前項有關類股之規定。
Condition153
五、有價證券本益比為負值或達六十倍以上者，不適用前項有關類股之規定。
六、公開資訊觀測站公告有價證券當日之前一個營業日溢（折）價百分比達下列情事之一者，不適用前項標準：
（一）未超過百分之十。
（二）與前項所達標準漲（跌）之方向相反。
}
// 基本條件
Condition151=100*(C-C[5])/C[5]>25 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]>=20;
Condition152=GetField("週轉率","D")>=10 and GetField("週轉率","D")-GetSymbolField("TSE.TW","週轉率","D")>=5;
// 除外條件 
Condition153=GetField("本益比","D")<0 or GetField("本益比","D")>=60 ;
// 條件整合
Condition200=Condition151 and Condition152 and (Not Condition153);

// 篩選
If Condition200 Then Begin 
AlertCount44=1;
End;

{===============================================================================================================================================================
Condition250
4.7. 第四條第一項第七款
本要點第四條第一項第七款「有價證券最近一段期間累積之收盤價漲跌百分比異常，且券資比明顯放大者」，係指有價證券當日【同時】達下列各款情事者：
Condition201
一、最近六個營業日（含當日）累積之收盤價漲跌百分比超過百分之二十五，且其漲跌百分比與全體有價證券及同類有價證券依本款規定計算之平均值的差幅，均在百分之二十以上。
Condition202
二、當日之前一個營業日之券資比百分之二十以上，且【同時】符合下列二項條件：
（一）融資使用率百分之二十五以上。
（二）融券使用率百分之十五以上。
Condition203
三、當日之前一個營業日之券資比較最近六個營業日（從當日之前一個營業日起）之最低券資比放大四倍以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價漲跌百分比，不納入前項標準之計算。
二、有價證券在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價或收盤指數漲跌百分比時，排除此項變動因素。
三、同類有價證券未達五種者，不適用前項有關類股之規定。
Condition204
四、有價證券本益比為負值或達六十倍以上者，不適用前項有關類股之規定。
Condition205
五、當日之前一個營業日券資比低於當日之前二個營業日之券資比。
六、公開資訊觀測站公告有價證券當日之前一個營業日溢（折）價百分比達下列情事之一者，不適用前項標準：
（一）未超過百分之十。
（二）與前項所達標準漲（跌）之方向相反。
}
// 基本條件
Condition201=100*(C-C[5])/C[5]>25 and 100*(C-C[5])/C[5]-100*(TSEClose-TSEClose[5])/TSEClose[5]>=20;
Condition202=GetField("券資比","D")[1]>=20 and GetField("融資使用率","D")>=25 and GetField("融券使用率","D")>=15;
Condition203=GetField("券資比","D")[1]>=4*Lowest(GetField("券資比","D")[1],6);
// 除外條件 
Condition204=GetField("本益比","D")<0 or GetField("本益比","D")>=60 ;
Condition205=GetField("券資比","D")[1]<GetField("券資比","D")[2];
// 條件整合
Condition250=Condition201 and Condition202 and Condition203 and (Not Condition204 or Not Condition205);

// 篩選
If Condition250 Then Begin 
AlertCount47=1;
End;

{===============================================================================================================================================================
Condition300
4.9. 第四條第一項第九款
本要點第四條第一項第九款「有價證券當日及最近數日之日平均成交量較最近一段期間之日平均成交量明顯放大者」，係指有價證券當日【同時】達下列各款情事者：
Condition251
一、最近六個營業日（含當日）之日平均成交量較最近六十個營業日（含當日）之日平均成交量放大為五倍以上，且其放大倍數與全體有價證券依本款規定計算之平均值相差四倍以上。
Condition252
二、當日之成交量較最近六十個營業日（含當日）之日平均成交量放大為五倍以上，且其放大倍數與全體有價證券依本款規定計算之平均值相差四倍以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之日成交量，不納入前項標準之計算。
二、轉換公司債、非分離型附認股權公司債、非分離型附認股權特別股、債券換股權利證書、認購（售）權證、認股權憑證、指數股票型基金受益憑證、指數投資證券不適用前項標準。
Condition253
三、在最近六個營業日（含當日）內，已依本要點第四條第一項第三款公布注意交易資訊之有價證券，不適用前項標準。
Condition254
四、有價證券當日週轉率未達千分之一以上，或成交量未達五百交易單位以上者，不適用前項標準。
}
// 基本條件
Condition251=Average(V,6)/Average(V,60)>=5 and Average(V,6)/Average(V,60)>=4*Average(TSEVolume,6)/Average(TSEVolume,60);
Condition252=V/Average(V,60)>=5 and V/Average(V,60)>=4*TSEVolume/Average(TSEVolume,60);
// 除外條件 
Condition253=trueany(Condition150,6);
Condition254=GetField("週轉率","D")<0.1 or V<500;
// 條件整合
Condition300=Condition251 and Condition252 and (Not Condition253 or Not Condition254);

// 篩選
If Condition300 Then Begin 
AlertCount49=1;
End;

{===============================================================================================================================================================
Condition350
4.10. 第四條第一項第十款
本要點第四條第一項第十款「有價證券最近一段期間之累積週轉率明顯過高者」，係指有價證券當日【同時】達下列各款情事者：
Condition301
一、最近六個營業日（含當日）之累積週轉率超過百分之五十，且其累積週轉率與全體有價證券依本款規定計算之平均值的差幅在百分之四十以上。
Condition302
二、當日週轉率百分之十以上，且其週轉率與全體有價證券依本款規定計算之平均值的差幅在百分之五以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之日週轉率，不納入前項標準之計算。
二、轉換公司債、非分離型附認股權公司債、非分離型附認股權特別股、債券換股權利證書、認購（售）權證、認股權憑證、指數股票型基金受益憑證、指數投資證券不適用前項標準。
Condition303
三、在最近六個營業日（含當日）內，已依本要點第四條第一項第四款公布注意交易資訊之有價證券，不適用前項標準。
Condition304
四、有價證券當日成交金額未滿新臺幣五億元以上者，不適用前項標準。
}
// 基本條件 
Condition301=Summation(GetField("週轉率","D"),6)>50 and Summation(GetField("週轉率","D"),6)-Summation(GetSymbolField("TSE.TW","週轉率","D"),6)>=40;
Condition302=GetField("週轉率","D")>=10 and GetField("週轉率","D")-GetSymbolField("TSE.TW","週轉率","D")>=5;
// 除外條件 
Condition303=trueany(Condition200,6);
Condition304=GetField("成交金額(億)","D")<5;
// 條件整合
Condition350=Condition301 and Condition302 and (Not Condition303 or Not Condition304);

// 篩選
If Condition350 Then Begin 
AlertCount410=1;
End;


{===============================================================================================================================================================
Condition400
4.11. 第四條第一項第十一款
本要點第四條第一項第十一款「有價證券最近一段期間起迄兩個營業日之收盤價價差異常者」，係指有價證券當日達下列各款情事【之一】者：
Condition351
一、有價證券最近六個營業日（含當日）起迄兩個營業日之收盤價價差達新臺幣一百元以上，且有價證券當日收盤價須為最近六個營業日（含當日）收盤價最高者。
但最近五個營業日（不含當日）無收盤價時，則當日收盤價須高於開盤參考價。
Condition352
二、有價證券最近六個營業日（含當日）起迄兩個營業日之收盤價價差達新臺幣一百元以上，且有價證券證當日收盤價須為最近六個營業日（含當日）收盤價最低者。
但最近五個營業日（不含當日）無收盤價時，則當日收盤價須低於開盤參考價。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之收盤價，不納入前項標準之計算。
二、有價證券或指數在計算前項標準期間內，如有因非交易之原因（如除權、除息等）造成價格變動者，則於計算收盤價或收盤指數時，排除此項變動因素。
Condition353
三、在最近六個營業日（含當日）內，當日之前五個營業日已依本要點第四條第一項第十一款公布注意交易資訊之有價證券，不適用前項標準。
}
// 基本條件 
Condition351=absvalue(C-C[5])>=100 and C=Highest(C,6);
Condition352=absvalue(C-C[5])>=100 and C=Lowest(C,6);
// 除外條件 
// 條件整合
Condition400=truecount(Condition351 or Condition352,6)=1;

// 篩選
If Condition400 Then Begin 
AlertCount411=1;
End;


{===============================================================================================================================================================
Condition450
4.12. 第四條第一項第十二款
本要點第四條第一項第十二款「有價證券最近一段期間之借券賣出成交量占總成交量比率明顯過高者」，係指有價證券當日之前一個營業日【同時】達下列各款情事者：
Condition401
一、最近六個營業日（從當日之前一個營業日起）之借券賣出成交量占最近六個營業日（從當日之前一個營業日起）總成交量比率在百分之十二以上。
Condition402
二、當日之前一個營業日借券賣出成交量較最近六十個營業日（從當日之前一個營業日起）之日平均借券賣出成交量放大為五倍以上。

前項除外情形如下：
一、初次上市普通股採無升降幅度限制期間之日成交量，不納入前項標準之計算。
二、指數股票型基金受益憑證不適用前項標準。
三、有價證券當日之【前一個營業日】達下列情事【之一】者，不適用前項標準：
Condition403
（一）週轉率未超過千分之三。
Condition404
（二）成交量未超過五百交易單位。
Condition405
（三）借券賣出成交量未超過一百交易單位。
}
// 基本條件 
Condition401=Summation(GetField("借券賣出張數","D")[1],6)/Summation(V[1],6)>0.12;
Condition402=GetField("借券賣出張數","D")[1]>=5*Average(GetField("借券賣出張數","D")[1],60);
// 除外條件 
Condition403=GetField("週轉率","D")[1]<=0.3;
Condition404=V[1]<=500;
Condition405=GetField("借券賣出張數","D")[1]<=100;
// 條件整合
Condition450=Condition401 and Condition402 and (Not Condition403 or Not Condition404 or Not Condition405);

// 篩選
If Condition450 Then Begin 
AlertCount412=1;
End;

{===============================================================================================================================================================
Condition500
6.1 第六條
有價證券之交易有下列情形【之一】時，本公司即發布為處置之有價證券：
Condition451
一、連續三個營業日經本公司依第四條第一項第一款發布交易資訊者。
Condition452
二、連續五個營業日或
Condition453
最近十個營業日內有六個營業日或
Condition454 
最近三十個營業日內有十二個營業日經本公司依第四條第一項第一款至第八款發布交易資訊者。
}
// 基本條件 
Condition451=Trueall(Condition50,3);
Condition452=Trueall(Condition50 or Condition100 or Condition150 or Condition200 or Condition250,3);
Condition453=Truecount(Condition50 or Condition100 or Condition150 or Condition200 or Condition250,10)>=6;
Condition454=Truecount(Condition50 or Condition100 or Condition150 or Condition200 or Condition250,30)>=12;
// 條件整合
Condition500=Condition451 or Condition452 or Condition453 or Condition454;

// 篩選
If Condition500 Then Begin 
AlertCount61=1;
End;

{===============================================================================================================================================================
Condition550
2.1 第 2 條 
本公司於每日交易時間內（下稱盤中），分析上市有價證券（不含外國債券、政府債券、普通公司債）之交易，發現其有下列情形【之一】時，即依第三條規定辦理。
Condition501
一、當日盤中成交價振幅超過百分之九，且與本公司發行量加權股價指數振幅之差幅在百分之五以上，且其成交量達三千交易單位以上者。
Condition502
二、當日盤中成交價漲跌百分比超過百分之六，且與本公司發行量加權股價指數漲跌百分比之差幅在百分之四以上，且其成交量達三千交易單位以上者。
Condition503
三、當日盤中週轉率超過百分之十，且其成交量達三千交易單位以上者。
但轉換公司債、非分離型附認股權公司債、非分離型附認股權特別股、債券換股權利證書、認購（售）權證、認股權憑證、指數股票型基金受益憑證及指數投資證券不適用之。
四、依本要點規定發布交易資訊或採取處置措施者。
五、經市場傳聞或媒體報導或經本公司電腦系統分析有異常情事並經簽報核准者。
六、其他經主管機關指定者。
有價證券升降幅度計算公式含有以標的證券或標的指數等計算因素者，以其當日盤中振幅、漲跌百分比與標的證券或標的指數之振幅、漲跌百分比
（投資組合者，取其組合標的證券或標的指數振幅、漲跌百分比之平均值）計算差幅。
第一項第一款、第二款、第三款關於「且其成交量達三千交易單位以上者」之規定，於初次上市普通股採無升降幅度限制期間之交易不適用之。
有價證券交易單位低於一千單位（股、受益權單位、存託憑證單位等，下同）者，其成交（委託）量交易單位數據標準依下列公式調整：
調整後成交（委託）量交易單位數據標準＝調整前成交（委託）量交易單
位數據標準ｘ（1000 ÷ 該有價證券交易單位）。
}
// 基本條件 
Condition501=absvalue(StockChangeRatio)>9 and absvalue(StockChangeRatio-TSEChangeRatio)>=5 and V>=3000;
Condition502=absvalue(StockChangeRatio)>6 and absvalue(StockChangeRatio-TSEChangeRatio)>=4 and V>=3000;
Condition503=GetField("週轉率","D")>10 and V>=3000;
// 條件整合
Condition550=Condition501 or Condition502 or Condition503;

// 篩選
If Condition550 Then Begin 
AlertCount21=1;
End;

首先我們先來了解一下相關的規定，一檔股票要成為處份股票，首先要多次成為注意股票，這之後如果交易所認為還是出現價量異常的情況，就會宣佈成為處份股票。

下面這個連結是交易所公佈處置股票的連結，大家可以去看一下交易所的說明，會被列為處置股票的，都是連續多日先是成為注意股票的

所以我們攻城師先模擬成為注意股票的條件，再把符合多日注意股票的個股，看看是否會符合處置股票的條件。

目前xs並沒有支援注意股票的註記，所以這麼寫也是情非得已，等到xs支援注意股票的註記，這個腳本就可以更好寫了。

從資金流向看類股的輪動

這陣子產業輪動非常的明顯，沒有買到主流股，賺了指數賠了差價，今天來跟大家分享我觀察產業輪動的方法：看細產業的資金流向。

細產業的資金流向，是拿該細產業所有成份股的成交值當分子，大盤成交值當分母，這樣算出該細產業佔大盤成交量的比重，所以當一個細產業開始有資金流入時，資金流向會呈現上昇趨勢，如果大戶開始看上這個細產業時，這細產業的資金流向就可能暴衝。

根據這個原理，我設計了一頁產業資金流向，大家可以從這個連結來下載，以下是幾個例子，近一日的LED族群資金流向有明顯回昇

半導體類的資金流向則是早在半個月前就開始轉成上升趨勢

但IC基板資金流入的點其實是在六月初，現在反而是在下降趨勢中

隨著市場資金不斷轉戰各種題材，這個頁面提供大家一個儘早上車的參考，我自己近期裡比較留意的產業，主要放在PCB，LED，磊晶廠，5G相關元件等類別

勝率Go裡的策略K線用法

因為有不少網友希望可以直接使用我們過去介紹過的高勝率交易策略，所以公司去申請了投顧執照，推出了勝率Go這個產品，其中策略K線，盤中訊號及策略訊號三個功能，就是運用過去介紹過的高勝率策略所做的服務，今天先來跟大家介紹我使用策略K線的心得。

策略K線是把投顧看好的股票，當策略也出作多訊號時，就把這訊號標示在K線上，並且把策略標示在K線的下方

以上圖為例，台積電上週五符合了海龜交易法這個策略，這個策略從2014年一月一日到現在，台積電共出現了20個訊號，其中16次獲利出場，勝率高達八成。如果想要了解這個交易策略的細節，可以把滑鼠移到策略勝率報告那個小框框，會出現“更多資訊”這四個字，按下去會看到如下圖般的策略說明

接下來跟大家報告的是，在經過了一陣子的使用之後，我發現，如果一檔股票持續有各種不同的策略陸續出現買進訊號，那麼這檔股票出現波段上漲走勢的機率就會比單一策略作多要高很多

上面的台積電就是一個很典型的例子，下面我再舉幾個例子

我的觀察是，不同的交易策略，在幾日裡，陸續出現交易訊號，代表從不同的面象，都研判這檔股票的起漲點已出現，這樣的情況下，上漲的機率可能遠比單一訊號高。

以上是我使用的心得，跟大家分享。

撰寫高勝率交易策略的五個常用方法

愈來愈多的網友開始使用XS，試著寫出高勝率的交易策略，大家各自有不同的市場觀察心得，所以也有著五花八門的作法，蠻多這行的前輩都教我們，尋找市場裡高機率不斷重覆出現的韻律，是我們制定交易策略的基本原則，這幾年我大約也寫過2000多個交易策略，來跟大家分享一些，寫出高勝率策略的入手方法。

一，大跌就是最大的利多。

我寫過不少大跌後股價變化的腳本，像是

大跌後的低檔五連陽

大跌後的糾結均線突破

我發現，大跌真的是最大的利多，平平是糾結均線突破，大跌後的勝率就是會特別的高

二，籌碼集中發散理論

在所有股市的各種投資理論中，籌碼收集與發散是我很認同的一個理論，實證上，當籌碼一直被收集，甚至就算是當沖交易，大戶買進而散戶賣出的股票，往往也是最強的，我很少看到螞蟻搬大象的劇情真的出現。

三，ROE是很神奇的因子

我寫過很多腳本，用所有普通股去跑，績效平平，但如果只跑ROE好的股票，勝率就拉高不少，投資學上學者非常用力的尋找股價上漲背後的因子，我看過一篇論文，裡頭找出了159種因子，在台股的實證操作上，真的常帶給我驚喜的是ROE這個因子。

四，跟著大股東走

XS裡有不少欄位可以窺探大股東的動向，如關鍵券商，地緣券商，千張大戶等等，我的的確確有感受到，大股東的多空態度是影響股價長線表現的很重要參考指標。畢竟最了解公司的，應該是大股東

五，剛整理完且預估量暴增的強勢股

市場有不少短線大戶是在追逐盤面上出量且表現最強的股票，特別是那些剛整理結束的，我寫過一些腳本來印證這樣的作法到底會不會賺錢？結論是，從這樣的角度出發，在選股上做一些過濾，還真的是會賺錢，這其中最重要的眉角是，最好是挑那些不管法人，實戶，甚至一般投資人都會一擁而上的股票。

以上這五個方向，是我到目前為止，寫出最多高勝率腳本的基本精神，分享給大家，祝大家都能找到夠多的好策略。

XQ量化交易平台上的型態學相關函數

型態分析應該算是股市投資者最耳熟能詳的分析方式，M頭，W底，趨勢線等名稱，大家總能朗朗上口，如何把這些大家都很熟悉的概念，用程式語法表現出來，是本章學習的重點。

所有的型態概念，通常有三個基本元素

上昇切線
下降切線
上昇或下降的角度

透過這三個元素，可以組成各種線段，而型態就是由這些線段所組成。

例如把過去一段時間的走勢分成三個線段，就可以組成如下圖所列出來的不同行情走勢

在語法上，要描敘這些線段，使用的是一個叫作Angle的函數，透過這個函數，只要輸入計算的起始日期及結束日期，就可以算出這段區間的線段上漲或下跌的角度。

它的語法如下:

計算任意二個日期的走勢角度。

回傳數值=Angle(日期1,日期2)

傳入二個參數:
– 第一個參數是日期1。
– 第二個參數是日期2，需大於日期1。

例如要計算最近四期的走勢角度，就可以像下面這麼寫

以下是Angle這個函數的腳本

從腳本中我們可以發現，angle這個值的計算有兩個步驟

第一是先算出斜率_slope

斜率的算法是以最近一期收盤價除以計算起始期的開盤價減一當分子(也就是漲跌幅)，以兩個日期的差當分母，然後乘以100。

第二是把斜率用arcTangent函數，把數值轉成角度。

由於arcTangent是利用已知直角三角形的對邊和鄰邊這兩條直角邊的比值求出其夾角大小的函數，用來算對邊與鄰邊值的角度，所以算出來的角度就是這兩個區間的線段的上漲或下跌角度值。

當回傳數值大於0時，代表趨勢向上；當回傳數值小於0時，代表趨勢向下。

回傳值的數值絕對值愈大，代表這個線段的斜率愈陡。

所以運用這樣的概念，可以用語法描述各種型態的轉折，例如要用語法描敘V型反轉，就可以這麼寫

上面這個腳本裡有用到一個函數叫lowestbar，這個函數是用來計算一個區間內的最低點落在第幾根Bar，在描述那些更複雜的型態時，往往需要標示出整個區間的

最高點
最高點所在的位置
最低點
最低點所在的位置
第N個高低點
第N個高低所在的位置
波段第N個高低點
波段第N個高低點所在的位置

為了標示出這些位置及價位，系統內建了以下的幾個函數，透過這些函數的應用，可以讓電腦回傳上述八種位置及價位，以利於後續的運算。例如下面這張圖

就需要標出上述的六個點，為了協助使用者能夠在腳本中描繪各種型態，系統支援了描述上述八種位置及數值的相關函數，這些函數分類如下：

函數的寫法，以nthhighest為例：

計算序列資料的第N個極大值
回傳數值=NthHighest(第幾個極大值,數列,期數)
傳入三個參數:
– 第一個參數是要計算極大值的序號。
– 第二個參數是數列，通常是開高低收的價格數列。
– 第三個參數是期數。

以最新一筆資料為基準點，輸入要計算的期數，然後計算過去期數的第N個極大值。

例如，要計算近五期的次高價，就可以這麼寫：

Value1=nthhighest(2,high,5);

這一系列的函數可以協助找出區間的各個高點及低點，以及它們在K棒上的相對位置，可以協助描繪使用者想要尋找的型態。

舉個例子，上面列出來的多頭繼績型態，有個上昇旗型

這個型態的特色是在整理期間還是一峰高過一峰，最後以更陡的漲勢來突破整理，要描述這樣的型態，可以運用上面所提到的nthhighest 及nthhighestbar這兩個函數，參考的腳本如下：

input:period(20,"計算區間");

value2=nthhighest(1,high[1],period);//最高價

value3=nthhighest(2,high[1],period);//第二高價

value4=nthhighest(3,high[1],period);//第三高價

value5=nthhighestbar(1,high[1],period);//最高價距今幾根bar

value6=nthhighestbar(2,high[1],period);//第二高價距今幾根bar

value7=nthhighestbar(3,high[1],period);//第三高價距今幾根bar

if value6-value5>3 and value7-value6>3

  //三個高點沒有連在一起，且是愈來愈高

and maxlist(value2,value3,value4)

<minlist(value2,value3,value4)*1.05

  //三個高點相差不到5%

and close crosses over value2

  //創新高

then ret=1;

這個腳本就可以選出像下面這張圖裡，符合腳本描述型態的股票。

其次，系統也支援幾個可以找出轉折的高點及相對位置，可以使用的函數有以下幾個：

舉Swinghigh為例，其語法如下：

回傳數值=SwingHigh(數列,期數,左肩期數,右肩期數,第幾個高點)

計算數列最近N個的轉折高點數值

傳入五個參數:
– 第一個參數是數列，通常是開高低收的價格數列。
– 第二個參數是要尋找轉折點的樣本期數。
– 第三個參數是高點左側要有幾筆較低的數值。
– 第四個參數是高點右側要有幾筆較低的數值。
– 第五個參數是第幾個高點，依圖表由右往左(時間新到舊)，1為最近一次的高點、2為第二近的高點。

若某一筆資料的左右二側數值在指定的期數內都比該筆資料低的話，則定義為轉折高點。

當無法找到對應的轉折高點時，回傳值為-1。

例如想要找出過去20天，第二個左右兩邊都各至少有三天的高點價位，就可以寫成：

value1=swinghigh(high,20,3,3,2);

透過以上這些型態的函數，可以具體的描繪各種型態，找出符合特定型態的股票。

以下是一個多次到頂而破的例子，用到的是 highest及highestbar這兩個函數

 input:HitTimes(4,"設定觸頂次數");
input:RangeRatio(1,"設定頭部區範圍寬度%");
input:Length(40,"計算期數");

if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),10)
then begin
variable: theHigh(0); 

//找到過去其間的最高點
theHigh = Highest(High[1],Length); 
value1=highestbar(high[1],length);

variable: HighLowerBound(0); 

// 設為瓶頸區間上界
HighLowerBound = theHigh *(100-RangeRatio)/100; 

variable: TouchRangeTimes(0); 

//回算在此區間中 進去瓶頸區的次數 
TouchRangeTimes = CountIF(High[1] > HighLowerBound, Length-value1);

Condition1 = TouchRangeTimes >= HitTimes;
Condition2 = close > theHigh;
condition3=close[length]*1.1<thehigh;


Ret = Condition1 and Condition2 and condition3 ;
end;

透過這些型態函數，可以試著描繪出各種不同的型態，程式交易語法的好處就在於，當您把您相信的型態，透過語法完整而清楚的描述之後，就不用每天辛苦地從1500多檔股票的線圖中尋找想要尋找的型態，電腦可以很快的在幾秒到幾分鐘之內挑出這些股票。

圖說技術指標的設計方式與背後的思維（五)

在大家常用的技術指標中，布林值算是熱門的指標，像布林值這類從統計學出發的技術指標，蠻值得我們了解背後的設計概念，可以作為我們自訂指標的設計靈感。

關於布林值這個指標的設計概念，以及像變異數，標準差，R平方這些從統計學上所衍生出來的技術指標，我先前有寫過一些文章介紹，相關連結如下

布林通道

R平方

今天要跟大家討論的是，除了把股價拿來作為統計分佈的計算標的，其實透過Getfield語法，我們也可以把其他欄位拿來試看看，今天跟大家舉個例子，我們平常看到個股的外資買賣超時，如果只看絕對值，可能不見得很有感，但如果把布林值這種常態分配的概念放進去，就可以觀察目前的數字在統計學上，是不是已進十分罕見，如果罕見，往往就可能是一個新方向的開始，基於這樣的想法，我寫了一個腳本如下

input: Length(20, "天數"), UpperBand(2, "上"), LowerBand(2, "下"), EMALength(3, "EMA");
variable: up(0), down(0), mid(0), bbandwidth(0), ema(0);
value1=GetField("外資買賣超張數");
up = bollingerband(value1, Length, UpperBand);
down = bollingerband(value1, Length, -1 * LowerBand);
Plot1(value1, "外資買超張數");
Plot2(up, "上限");
plot3(down,"下限");

把這個自訂指標畫成圖，下圖是台積電近期的對照圖

從上面那張圖，我們會發現，空轉多時，容易看到外資買超突破或貼近布林值上限，多轉空時，則是多次跌破布林值下限。

再多看幾張圖

有些數據，看絕對值無感，把它透過統計學作點變化，就會比較有感覺

總市值低於一定標準

有網友在問說能不能知道那些股票的總市值已經低於流動資產，我寫了一個選股腳本來找出這些股票。不過要跟大家提醒的是，從過去回測的數字來看，這種價值型投資方法，在市場大跌時，股價未必能抗跌，只是在多頭市場，確實有不錯的表現，所以大家可以透過這個選股腳本去找出被低估的股票，但進場點還是得等不確定因素結束，然後也不是折價愈大愈好，還是要考慮公司的未來前景及獲利能力。

我寫的腳本如下

value1=GetField("總市值(億)","D");//億元
value2=GetField("流動資產","Q");//百萬
value3=GetField("負債總額","Q");//百萬
value4=GetField("普通股股本","Q");//億元
if value4<>0 then 
value5=((value2-value3)/100-value1)/(value4);
if value5>0 then ret=1;
outputfield(1,value1,0,"總市值億元");
outputfield(2,value2/100,0,"流動資產億元");
outputfield(3,value3/100,0,"負債總額億元");
outputfield(4,value4,0,"股本億元");
outputfield(5,value5*10,2,"每股折價");

以今天的收盤價來跑，符合條件的股票如下

如果拿這腳本去回測到去年底的過去三年，回測報告如下

看得出來是可以比指數好一些，但如果能再搭配其他籌碼或價量的篩選條件應該會更好。

另外就是大盤不好的時候，其實沒有看到很強的抗跌能力

這點是大家需要特別留意的

圖說技術指標的設計方式與背後的思維（四)

談完趨勢，來談談離趨勢太遠時該怎麼辦？如果我們接受股價是有其趨勢，那麼偏離趨勢太遠，就應該要回到趨勢上來，除非是整個趨勢都要改變了，由這樣的概念所出發的技術指標有兩種，一種是乖離型指標，另一種是震盪型指標。這兩種都有隱含者物極必反的思維。

一，乖離率

乖離率的概念簡單說，就是目前的價格離平均值有多遠，XS裡有一個bias的函數就是用來計算乖離率，它的腳本如下

SetBarMode(1);

// Bias function (for 乖離率相關指標)
//
input: length(numericsimple);

value1 = Average(close, length);
Bias = (close - value1) * 100 / value1;

從程式碼來看，bias就是價格減去平均值當分子再除以平均值，乖離值在零的上下游走，離太遠就是偏離平均值太遠

二，KD值

除了偏離均線算是乖離，另外一種概念叫震盪，它的概念是人們有時太過樂觀，有時又太過悲觀，所以造成股價會上下波動，形成一種像鐘擺一樣的來回震盪走勢，這個概念裡最有名的指標是KD指標，它的計算方式是去找出特定區間內，收盤價與最低價的距離佔區間最高價與最低價間距離的比例，它的計算公式如下，在XS中是把它寫成一個叫Stochastic的函數，函數的腳本如下

input:
length(numericsimple), rsvt(numericsimple), kt(numericsimple),
rsv(numericref), k(numericref), d(numericref);

variable:
maxHigh(0), minLow(0);

maxHigh = Highest(high, length);
//找出波段最高點
minLow = Lowest(low, length);
//找出波段最低點
if maxHigh <> minLow then
rsv = 100 * (close - minLow) / (maxHigh - minLow)
else
rsv = 50;
//定議RSV是收盤價減去波段最低點除以最高點到最低點間的距離
if currentbar = 1 then
begin
k = 50;
d = 50;
end
else
begin
k = (k[1] * (rsvt - 1) + rsv) / rsvt;
//K值是平滑RSV值
d = (d[1] * (kt - 1) + k) / kt;
//D值是K值的平滑值 
end;

stochastic = 1;

一般rsvt常用的是3，也就是平滑的權重是1/3，區間是9，所以如果要寫出9K在低檔與9D黃金交叉的腳本，就可以運用這個stochastic的函數撰寫如下

input: Length(9), RSVt(3), Kt(3);
variable: rsv(0), k(0), _d(0);

SetTotalBar(maxlist(Length,6) * 3);

SetInputName(1, "天數");
SetInputName(2, "RSVt權數");
SetInputName(3, "Kt權數");

Stochastic(Length, RSVt, Kt, rsv, k, _d);

Ret = k crosses above _d;

K值及D值如鐘擺般來回擺動，有著物極必返的概念，是震盪指標的代表

以上是物極必反的概念下所衍生的技術指標，我們到現在討論了開高低收相對位置，成交量，趨勢理論及物極必返理論所衍生出來的一些技術指標，大家可以發現，一個技術指標的發明，總是歷經了如下圖的四個階段

我有很多的交易策略，都是透過這樣的方式，找到合用的技術指標，然後在搭配一些選股條件所組合而成，之後會再跟大家繼續介紹一些技術指標的產生過程，幫助大家找出自己滿意的自訂指標。

期指當沖交易領先指標的設定方法

連續兩篇都在介紹由權值股的表現，來總合成一個期指多空方向的領先指標，為什麼國際金融情勢地動山搖，而我一直聚焦在介紹期指當沖的領先指標呢? 原因是我也不知道隔天醒來市場會往上噴還是往下掉，但盤中至少這些外在的變數可以直接從盤面的反映而得知，所以我才會聚焦在介紹期指當沖的領先指標上。

繼前兩篇製定指標的方法之後，今天跟大家介紹利用兩個陣列來輸入領先指標成份股及其在計數器上的權重，然後算出加權後的領先指標，以下是程式樣本

給不同成份股不同的權值

array:T50[50](0),W50[50](0),S50[50](0);
t50[1]=GetSymbolField("1101.tw","close");
t50[2]=GetSymbolField("1102.tw","close");
t50[3]=GetSymbolField("1216.tw","close");
t50[4]=GetSymbolField("1301.tw","close");
t50[5]=GetSymbolField("1303.tw","close");
t50[6]=GetSymbolField("1326.tw","close");
t50[7]=GetSymbolField("1402.tw","close");
t50[8]=GetSymbolField("2002.tw","close");
t50[9]=GetSymbolField("2105.tw","close");
t50[10]=GetSymbolField("2227.tw","close");
t50[11]=GetSymbolField("2301.tw","close");
t50[12]=GetSymbolField("2303.tw","close");
t50[13]=GetSymbolField("2308.tw","close");
t50[14]=GetSymbolField("2317.tw","close");
t50[15]=GetSymbolField("2327.tw","close"); 
t50[16]=GetSymbolField("2330.tw","close");
t50[17]=GetSymbolField("2357.tw","close");
t50[18]=GetSymbolField("2382.tw","close");
t50[19]=GetSymbolField("2395.tw","close");
t50[20]=GetSymbolField("2408.tw","close");
t50[21]=GetSymbolField("2412.tw","close");
t50[22]=GetSymbolField("2454.tw","close");
t50[23]=GetSymbolField("2474.tw","close");
t50[24]=GetSymbolField("2633.tw","close");
t50[25]=GetSymbolField("2801.tw","close");
t50[26]=GetSymbolField("2823.tw","close");
t50[27]=GetSymbolField("2880.tw","close");
t50[28]=GetSymbolField("2881.tw","close");
t50[29]=GetSymbolField("2882.tw","close");
t50[30]=GetSymbolField("2883.tw","close");
t50[31]=GetSymbolField("2884.tw","close");
t50[32]=GetSymbolField("2885.tw","close");
t50[33]=GetSymbolField("2886.tw","close");
t50[34]=GetSymbolField("2887.tw","close");
t50[35]=GetSymbolField("2888.tw","close");
t50[36]=GetSymbolField("2890.tw","close");
t50[37]=GetSymbolField("2891.tw","close");
t50[38]=GetSymbolField("2892.tw","close");
t50[39]=GetSymbolField("2912.tw","close");
t50[40]=GetSymbolField("3008.tw","close");
t50[41]=GetSymbolField("3045.tw","close");
t50[42]=GetSymbolField("3711.tw","close");
t50[43]=GetSymbolField("4904.tw","close");
t50[44]=GetSymbolField("4938.tw","close");
t50[45]=GetSymbolField("5871.tw","close");
t50[46]=GetSymbolField("5876.tw","close");
t50[47]=GetSymbolField("5880.tw","close");
t50[48]=GetSymbolField("6505.tw","close");
t50[49]=GetSymbolField("9904.tw","close");
t50[50]=GetSymbolField("9910.tw","close");

W50[1]=1;
W50[2]=1;
W50[3]=1;
W50[4]=1;
W50[5]=1;
W50[6]=1;
W50[7]=1;
W50[8]=1;
W50[9]=1;
W50[10]=1;
W50[11]=1;
W50[12]=1;
W50[13]=1;
W50[14]=2;
W50[15]=1;
W50[16]=3;
W50[17]=1;
W50[18]=1;
W50[19]=1;
W50[20]=1;
W50[21]=1;
W50[22]=1;
W50[23]=1;
W50[24]=1;
W50[25]=1;
W50[26]=1;
W50[27]=1;
W50[28]=1;
W50[29]=1;
W50[30]=1;
W50[31]=1;
W50[32]=1;
W50[33]=1;
W50[34]=1;
W50[35]=1;
W50[36]=1;
W50[37]=1;
W50[38]=1;
W50[39]=1;
W50[40]=1;
W50[41]=1;
W50[42]=1;
W50[43]=1;
W50[44]=1;
W50[45]=1;
W50[46]=1;
W50[47]=1;
W50[48]=1;
W50[49]=1;
W50[50]=1;
variable:count(0),i(0);
count=0;
for i=1 to 50
begin
if t50[i]> t50[i][1]
then count=count+W50[i];
end;
value1=average(count,10);
plot1(value1);

這個腳本是用第二個陣列來輸入權重，大家可以自己嚐試看看不同的權重是否各具備領先的效果。

下面是我做的加權領先指標跟加權指數一分鐘線的對照圖

請跟前面兩個指標一起對照著看，看看是否可以掌握加權指數盤中的轉折點

期指盤中領先指標的另一個寫法

昨天跟大家介紹在盤中透過權值股的股價變化來預測期指的走向，當時我有提到可以透過調整成份股，調整計數標準及調整權重等三個方法來打造期指的領先指標，今天來跟大家介紹的是透過調整計數標準的方法。對於以當沖期指為操作方法的朋友，我真的非常建議各位學會這些方法，以權值股的股價表現來預測期指未來走向，是我個人覺得非常值得研究及開發程式的領域，因為從實戰上來看，這在有行情的時候，真的是一個不錯的參考依據。

上一篇是來計算有多少檔權值股站在10分鐘均線之上，這一篇則是介紹改成計算有多少檔分鐘線是上漲的，然後把這個數字算出十期的移動平均，這樣可以看出權值股上漲下跌的主流趨勢。

這個腳本如下

array:T50[50](0);
t50[1]=GetSymbolField("5876.tw","close");
t50[2]=GetSymbolField("2317.tw","close");
t50[3]=GetSymbolField("2412.tw","close");
t50[4]=GetSymbolField("1301.tw","close");
t50[5]=GetSymbolField("1303.tw","close");
t50[6]=GetSymbolField("2454.tw","close");
t50[7]=GetSymbolField("1326.tw","close");
t50[8]=GetSymbolField("2308.tw","close");
t50[9]=GetSymbolField("2882.tw","close");
t50[10]=GetSymbolField("2881.tw","close");
t50[11]=GetSymbolField("2891.tw","close");
t50[12]=GetSymbolField("2002.tw","close");
t50[13]=GetSymbolField("1216.tw","close");
t50[14]=GetSymbolField("3008.tw","close");
t50[15]=GetSymbolField("2886.tw","close");
t50[16]=GetSymbolField("3711.tw","close");
t50[17]=GetSymbolField("2357.tw","close");
t50[18]=GetSymbolField("2474.tw","close");
t50[19]=GetSymbolField("3045.tw","close");
t50[20]=GetSymbolField("6505.tw","close");
t50[21]=GetSymbolField("2303.tw","close");
t50[22]=GetSymbolField("2382.tw","close");
t50[23]=GetSymbolField("2207.tw","close");
t50[24]=GetSymbolField("2892.tw","close");
t50[25]=GetSymbolField("4938.tw","close");
t50[26]=GetSymbolField("2884.tw","close");
t50[27]=GetSymbolField("2912.tw","close");
t50[28]=GetSymbolField("2885.tw","close");
t50[29]=GetSymbolField("2883.tw","close");
t50[30]=GetSymbolField("2105.tw","close");
t50[31]=GetSymbolField("2880.tw","close");
t50[32]=GetSymbolField("2330.tw","close");
t50[33]=GetSymbolField("4904.tw","close");
t50[34]=GetSymbolField("5880.tw","close");
t50[35]=GetSymbolField("2823.tw","close");
t50[36]=GetSymbolField("9904.tw","close");
t50[37]=GetSymbolField("1402.tw","close");
t50[38]=GetSymbolField("1101.tw","close");
t50[39]=GetSymbolField("2887.tw","close");
t50[40]=GetSymbolField("2890.tw","close");
t50[41]=GetSymbolField("2801.tw","close");
t50[42]=GetSymbolField("2633.tw","close");
t50[43]=GetSymbolField("5871.tw","close");
t50[44]=GetSymbolField("2301.tw","close");
t50[45]=GetSymbolField("2395.tw","close");
t50[46]=GetSymbolField("2354.tw","close");
t50[47]=GetSymbolField("9904.tw","close");
t50[48]=GetSymbolField("1102.tw","close");
t50[49]=GetSymbolField("2408.tw","close");
t50[50]=GetSymbolField("2227.tw","close"); 
variable:count(0),i(0);
count=0;
for i=1 to 50
begin
if t50[i]> t50[i][1]
then count=count+1;
end;
value1=average(count,10);
plot1(value1);

用這個指標跟加權指數的對照圖如下

各位可以發現，指數小跌，而下跌的權值股愈來愈多時，後市下跌的機率就變大，相反的，指數不大動，但上漲的權值股家數愈來愈多，後市看漲的機率就變大。

再跟大家嘮叨一次，人的肉眼無法一次盯住50檔或更多的個股，但期指的表現是由成份股的股價表現所組合而成的，我們可以讓電腦一次幫我們盯住所有成份股的表現，然後形成一個總合性的數據，把這個數據變成一個指標，盯住幾個指標，絕對是我們用肉眼可以做的到的，如果你有志於把期指盤中操作當成一種謀生方式，這個方法絕對值得您學起來。