Author Archives: 發財橘子

Chaikin Volatility　這個指標是在描述價格的波動程度。

公式 ：

1.先計算n日的 Range = High – Low 的指數型移動平均

REMAt = REMAt-1 + 2/(n+1) * ( Rt – REMAt-1)

2.計算n日移動平均的變動率：

Chainkin’s Volatility = (REMAt – REMAt-n) / REMAt-n

描述價格的波動程度的狀況有二種，一種是認為當股價向上時的波動程度將隨之上升，此種描述是認為價格上升時經常伴隨著成交量放大， 這表示此過程將吸引更多的市場參與者加入，而更多人的參與交易隱含著波動程度放大。另一種狀況則是認為觀察短期的價格走勢， 則波動的訊雜幹擾會較長期來得大。

對應的腳本

// Chaikin Volatility 指標
//
input: Length(10), LengthROC(12);
variable: _chaikin(0);

SetInputName(1, "天數一");
SetInputName(2, "天數二");

Value1 = XAverage(High - Low, Length);

if CurrentBar >= LengthROC And Value1[LengthROC] <> 0 then
 _chaikin = 100 * (Value1 - Value1[LengthROC]) / Value1[LengthROC]
else
 _chaikin = 0;
 
Plot1(_chaikin, "Chaikin");

參考的圖形

在技術分析領域，Money Flow Index（MFI，資金流量指標） 常被稱為「價量結合的 RSI」。

與 RSI 僅考慮價格漲跌不同，MFI 將成交量 (Volume) 納入計算邏輯。其核心假設是：如果股價上漲且成交量放大，代表資金流入強勁；若價格上漲但成交量萎縮，則動能可能虛假。

MFI 的應用有如下幾個原則：

1. 超買與超賣 (Extreme Overheating):

   • 當 MFI > 80：代表資金過度擁擠，需留意獲利了結壓力。若達到 90 以上，則是極度過熱。

   • 當 MFI < 20：代表恐慌性拋售，資金流失見底。

2. 背離訊號 (The Divergence) —— 最強大的領先特徵:

   • 看跌背離： 股價創下新高，但 MFI 卻走低。這代表股價上漲缺乏資金後援，趨勢即將反轉。

   • 看漲背離： 股價創新低，但 MFI 底部墊高。代表聰明錢正在低檔默默吸貨（Accumulation）。

3. 趨勢確認:

   • MFI 突破 50 分界線：代表資金流入占優勢，多頭趨勢確立。

MFI的計算方法如下

對應的腳本

Input: Length(6);
variable: tp(0), tv(0), utv(0), dtv(0), pmf(0), nmf(0), mfivalue(0);

SetInputName(1, "天數");

tp = TypicalPrice;
tv = tp * Volume;

if tp > tp[1] then
 begin
 utv = tv;
 dtv = 0;
 end
else
 begin
 utv = 0;
 dtv = tv;
 end;

pmf = Average(utv, MinList(CurrentBar, length));
nmf = Average(dtv, MinList(CurrentBar, length));


if CurrentBar < Length or (pmf + nmf) = 0 then
 mfivalue = 50
else 
 mfivalue = 100 * pmf /(pmf + nmf);

Plot1(mfivalue, "MFI");

拿這個指標來對照大盤

Market Facilitation Index (BW MFI) 市場便利指標是由 Dr. Bill Williams所發明的

這個指標必須搭配成交量來一起看 :

＋交易量/＋MFI 綠燈(Green)

－交易量/－MFI 衰退(Fade)

－交易量/＋MFI 偽裝(Fake)

＋交易量/－MFI 蟄伏(Squat)

市場便利指標運用時會與成交量一起使用 : 市場便利指標增加，交易量增加 (Green)。

這一點表明 :

1. 進入市場的交易人員的數量增加。（交易量增加）
2. 新的交易人員會隨著柱圖的發展趨勢入市。（例如，移動的開始和速度的加快）

市場便利指標的回落和交易量的下降 (Fade)，表明市場的交易人對該市場不在感到有任何的興趣。

市場便利指標的增加，但交易量下降 (Fake)。最有可能的就是，市場並不受到來自客戶交易量的支援，價格隨著“底樓”交易人員的遊資而變化（經濟人和交易人）

市場便利指標的下跌，但是交易量的增加 (Squat)。存在牛力和熊力之間的鬥爭。主要特徵為大量的買進和大量的賣出。 但是價格沒有重大的變化，因為兩股勢力比較相當。競爭的其中一方（買家或賣家）將會最終贏得這次鬥爭的勝利。 通常，柱形的停滯讓你知道是否這個柱形決定了市場趨勢的連續性，或這個柱形終止了市場趨勢。Bill Williams 稱之為“Squat”。

腳本的寫法

{
指標說明
Market Facilitation Index
}

if volume <> 0 then
 value1=(high-low)/volume;
if value1>value1[1] and volume>volume[1] then begin
 plot1(volume,"綠燈");
 noplot(2);
 noplot(3);
 noplot(4);
end;
if value1>value1[1] and volume<=volume[1] then begin
 plot2(volume,"偽裝");
 noplot(1);
 noplot(3);
 noplot(4);
end;
if value1<=value1[1] and volume>volume[1] then begin
 plot3(volume,"蟄伏");
 noplot(1);
 noplot(2);
 noplot(4);
end;
if value1<=value1[1] and volume<=volume[1] then begin
 plot4(volume,"衰退");
 noplot(1);
 noplot(2);
 noplot(3);
end;

參考的圖形

EMV指標的原文是Ease Of Movement，按原文的意思是「輕鬆移動」指標，這個指標是由阿木思ARMS所發明， 他取這個名字應該是指隨著指標值突破關鍵點後，股價會「輕鬆」的上漲或下跌吧。

這個指標的計算方法如下

1.把當日最高最低價的平均值減去前一日的最高最低價平均值

2.把這個值乘上當日最高價減去當日最低價

3.然後再除以成交量

4.最後再把上述的值乘上10000，然後取平均值

腳本

Input: Length(14);
variable: _emv(0), factor(10000), avg(0);

SetInputName(1, "天數");

if Volume = 0 then
 _emv = 0
else
 _emv = factor * (((High + Low) / 2 - (High[1] + Low[1]) / 2) * (High - Low)) / Volume;

Plot1(_emv, "EMV");


If CurrentBar >= Length Then
 avg = Average(_emv, Length)
else
 avg = _emv; 

Plot2(avg, "EMVA");

參考圖形

這個指標的計算步驟如下

1.加總一段時間的上漲值

2.加總一段時間的下跌值

3.把加總的上漲值減去加總的下跌值除以兩者的總和

腳本

Input:length(10); setinputname(1, "天期");

variable: SU(0),SD(0); 

if close >= close[1] then 
 SU = CLOSE - CLOSE[1] 
else 
 SU = 0; 

if close < close[1] then 
 SD = CLOSE[1] - CLOSE 
else 
 SD = 0; 

value1 = summation(SU,length); 
value2 = summation(SD,length); 
value3 = (value1-value2)/(value1+value2)*100; 
plot1(value3, "CMO");

參考圖形

日內動量指標的概念如下

1.當紅K棒時，把收盤價比開盤價高的部份視為多頭動能

2.當黑K棒時，把開盤價比收盤價高的部份視為空頭動能

3.計算過去一段時間的多頭動能及空頭動能

4.日內動量指標的算法是以多頭動能除以多頭動能+空頭動能

對應的腳本如下

input:length(10); setinputname(1, "天期");
 
variable:up(0),dn(0),upi(0),dni(0),imi(0); 

if close > open then 
 up = close-open 
else 
 up = 0; 

if close < open then 
 dn = open-close 
else 
 dn = 0; 

upi = summation(up,length); 
dni = summation(dn,length); 
if upi+dni = 0 then imi = 0 else imi = upi/(upi+dni)*100; 

plot1(imi, "IMI");

參考的圖形

加速指標的作法有幾個步驟

1.計算一段期間裡，上漲天數的平均上漲幅度

2.計算一段時間裡，下跌天數的平均下跌幅度

3.拿平均上漲幅度減去平均下跌幅度

4.取上述值的九日平均線

腳本

variable:aspeed(0),dspeed(0),a1(0),d1(0),p1(0),ap1(0);
if close>close[1]
then
aspeed=(close-close[1])/close*100
else
aspeed=0;
if close<close[1]
then
dspeed=(close[1]-close)/close*100
else
dspeed=0;

a1=average(aspeed,5);
d1=average(dspeed,5);


p1=a1-d1;
ap1=average(p1,9);

plot1(p1,"加速度");
plot2(ap1,"移動平均");

參考的圖形

STARC (Stoller 平均波幅通道) 顯示圍繞一般移動平均由三條線建立的通道。這三條線是 ：

1. 有 n–期間的簡單移動平均 (SMA)。
2. 一條較高的曲線，來自 n 期間的 SMA 加上 m 期間的平均真實波幅 (ATR) 乘上常數 K。
3. 一條較低的曲線，來自 n 期間的 SMA 減去 m 期間的 ATR 乘上常數 K。

1. 類似於布林通道 (Bollinger Bands)，斯塔克帶在穩定的市場中會緊縮，並在波動的市場中放鬆。不過，與布林通道以收盤價為基礎不同， 斯塔克帶的計算依據是平均真實波幅 (ATR)，因此對市場波動率提供更深入的快照。
2. 當價格曲線穿透布林通道時，這可能代表價格持續變更，相較下斯塔克帶傾向於定義一般價格行動的上下限 。因此， 部分交易者在進入市場之前使用斯塔克帶來決定風險水準

指標的腳本如下

input : length(5); setinputname(1, "天期");
input : atrlength(15); setinputname(2, "ATR天期");
input : k(1.35); setinputname(3, "通道常數");
 
variable : hband(0),lband(0); 
 
hband = average(close,length)+average(truerange,atrlength)*k; 
lband = average(close,length)-average(truerange,atrlength)*k; 
 
plot1(hband, "通道上限"); 
plot2(lband, "通道下限");

參考的圖如下圖

力度指標的思考邏輯是

1.把當天收盤價減去前一日收盤價的值乘以成交量當作當日的上漲下跌力度

2.分別計算短期與長期的上漲下跌力度的移動平均

3.畫出短期與長期力度的差

對應的腳本如下

input:length(10),length1(30);
variable:fis(0),fil(0);
fis=average(volume*(close-close[1]),length);
fil=average(volume*(close-close[1]),length1);
plot1(fis);
plot2(fil);
plot3(fis-fil);

參考的圖形如下

1、以長週期Force Index 判斷長期趨勢，若長週期Force Index 在 0 軸以下，則趨勢是持續向下，若遇短週期Force Index 向上穿越0 軸 ，則為空頭信號。

2、以長週期Force Index 判斷長期趨勢，若長週期Force Index 在 0 軸以上，則趨勢是持續向上，若遇短週期Force Index 向下穿越0 軸 ，則為多頭信號。

3、Force Index 也不易觀察出發散狀態，但若出現發散( 頭背離或底背離 )，亦是很好的趨勢反轉信號。

這個指標的作法是以最新收盤價減去N日前的收盤價取絕對值當分子，以區間最高價減去區間最低價當分母，然後乘以100，取百分比值。

這個指標如果絕對值愈高，要嘛是分母很小，也就是區間最高價跟最低價相去不遠，這自然是盤整盤，要嘛是分子很小，那代表收盤價差距不大，也是盤整盤盤無誤，但這個指標最悶的地方在於，如果收盤價變動很小但最高最低價變動也很大時，數字可能很小，但實際上可能是尖頭反轉後的大漲。

如果是在一個原有趨勢裡，這個數字開始從高點往下走，的確是一個從趨勢走向盤整的訊號。

我把這指標改良了一下，用在加權指數上

input:period(10,"計算區間");

value1=(close-close[period-1])/(highest(high,period)-lowest(low,period))*100;

value2=absvalue(value1)-30;

value3=average(value2,3);

plot1(value3,"市場波動指標");

用它畫成的圖如下

從這張圖可以看出，

1.當這個指標從50以上下滑時，代表一個趨勢的休息

2.這指標踫到尖頭反轉會失真