Author Archives: 發財橘子

今天跟大家介紹一個很阿殺利的指標，就是江湖人稱動量指標的MTM
MTM的算法很爽快，就是今天收盤價減n日前的收盤價，一行搞定。

我們用xs語法來把MTM寫成一個函數

input: price(numericseries), length(numericsimple);
 Momentum = price - price[length];

指標就這麼簡單

這個很簡單的算術算出來的指標，它代表的意義是什麼呢? 如果股價每天都漲1塊錢，MTM會是怎麼呈現? 答案是在0以上走平，每天都跌一元呢? MTM會在0以下，也走平，不漲不跌呢?每天價格都一樣， MTM當然會等於0 所以我們可以把MTM的不同形態整理成一個表格如下: MTM走勢 意義 在0附近走平 股價不漲不跌 在0以上走平 股價每天漲，價差一樣，或是上漲的速度跟n日前一樣 在0以下走平 股價每天跌，價差一樣，或是下跌的速度跟n日前一樣 在0以上呈上升趨勢 股價以比原先更陡的方式上漲，或是股價止跌回升 在0以下呈下降趨勢 股價以比原先更快的速度下跌，或是股價作頭下跌 在0以上呈下降趨勢 跟n日前比起來漲速變緩 在0以下呈上升趨勢 跟n日前比起來跌速變緩

MACD的英文原名為 Moving Average Convergnece & Divergence，也就是收斂發散移動平均線的意思，所以顧名思義它是移動平均線的一種。這個指標在技術分析各指標當中，算是極普遍又有名的一個。以下是MACD的計算步驟，附表1即為MACD的計算範例：

1.      計算出真實成本：

　Pt=Ct ´ 1/2 + Ht ´ ¼ + Lt  ´ ¼    其中 Ct為收盤價， Ht為最高價， Lt為最低價

2.      計算兩條平滑平均線 12EMA與26EMA

Et =  Et-1  +  α  ´  (  Pt  –  Et-1  )

其中 Et為當日平滑平均值， Et-1為前一日平滑平均值，  Pt為當日真實成本，         

α= 2 / ( 1+ MA)  ； MA = 平均天數 (即=12或26 )

3. 計算正負差線

DIF = 12EMA – 26EMA

4. 計算MACD線(或稱EDA線)

   將DIF線取九天EMA平均值即得

5.柱線 = DIF線–MACD線

一般說來，MACD指標可以說是一個非常優秀的指標，也正因為如此，所以它才會那麼廣受歡迎。

MACD的函數

SetBarMode(1);

// MACD function
// Input: Price序列, FastLength, SlowLength, MACDLength
// Output: DifValue, MACDValue, OscValue
// 
Input: Price(numericseries), FastLength(numericsimple), SlowLength(numericsimple), MACDLength(numericsimple);
Input: DifValue(numericref), MACDValue(numericref), OscValue(numericref);

DifValue = XAverage(price, FastLength) - XAverage(price, SlowLength);
MACDValue = XAverage(DifValue, MACDLength) ;
OscValue = DifValue - MACDValue;

指標腳本

// XQ: MACD指標
//
input: FastLength(12), SlowLength(26), MACDLength(9);
variable: price(0);

SetInputName(1, "DIF短天數");
SetInputName(2, "DIF長天數");
SetInputName(3, "MACD天數");

price = WeightedClose();

Value1 = XAverage(price, FastLength) - XAverage(price, SlowLength);
Value2 = XAverage(Value1, MACDLength) ;
Value3 = Value1 - Value2 ;

// 前面區段資料變動較大, 先不繪出
//
if CurrentBar <= SlowLength then
begin
 Value1 = 0;
 Value2 = 0;
 Value3 = 0;
end;

Plot1(Value1, "DIF");
Plot2(Value2, "MACD");
Plot3(Value3, "Osc");

參考的圖

MAO指標的原文是Moving Average Oscillator，稱為移動平均線擺盪指標。它的計算方式非常簡單，將兩條不同天期的簡單移動平均線相減即得，注意前面的MA1值需小於後面的MA2值。

MAO ＝  MA1 － MA2

通常我們很少直接稱這個指標為MAO指標，而是稱為它為「MA1減MA2乖離指標」，特別注意這個指標並非乖離率，很多人誤稱它為乖離率，我們都知道乖離率必須要除以一個成本(分母)，但這公式沒有，所以它顯然不是乖離率。

腳本

// XQ: MA-Osc
//
input: Length1(5), Length2(10);

SetInputName(1, "天數一");
SetInputName(2, "天數二");

value1 = Average(close, Length1);
value2 = Average(close, Length2);
value3 = (value1 - value2);

Plot1(value3, "MA-Osc");

參考圖

除了利用MAO指標線與零軸的交叉點來作為買賣點的確認之外，我們也要注意該指標值在零軸以上或以下的「反轉點」，它會比跟零軸形成的交叉點更早出現，就在股價開始轉折時就讓我們抓到，而不必等漲了或跌了一段才出現的黃金交叉或死亡交叉。特別注意如果反轉點是呈現尖銳的形狀而不是平緩的圖頭狀時，則該買賣訊號的確認會更準確。

最後要補充說明的是，這個指標除了上述的特殊性之外，還有一個重要性。因為它是MACD指標的簡易版，如果將這兩條均線採用EMA式的平滑平均來計算的話，那麼兩者相減之後的MAO指標，其實就是MACD指標中的DIF線，兩者是一模一樣，毫無區別的。所以我們可以說從均線架構的理論，到MAO指標，以迄MACD指標，是「吾道一以貫之」的。

HMA的精神是在計算移動平均時，給予後面的幾根比較高的權重

腳本

inputs:Length(20) ; 
vars:MA(0),HMA(0);

MA=2*Xaverage(close,IntPortion(Length*0.5))-xaverage(close,Length);

HMA=xAverage(MA,IntPortion(SquareRoot(Length)));

Plot1(HMA,"HMA") ;

參考的圖

指數移動平均（英語：exponential moving average，EMA或EXMA）是以指數式遞減加權的移動平均。各數值的加權影響力隨時間而指數式遞減，越近期的數據加權影響力越重，但較舊的數據也給予一定的加權值。

在XS中把這個移動平均寫成一個叫XAverage的函數，腳本如下

SetBarMode(2);

input:thePrice(numericseries); //"價格序列"
input:Length(Numeric); //"計算期間"

variable: Factor(0);

if length + 1 = 0 then Factor = 1 else Factor = 2 / (Length + 1);

if CurrentBar = 1 then
 XAverage = thePrice
else
 XAverage = XAverage[1] + Factor * (thePrice - XAverage[1]);

先前有被問到有沒有很簡單的一種指標，見紅就買，見綠就賣，剛好昨天被老朋友問到如果一直盯著台積電，但又不想一直抱著，想要來回操作，有沒有什麼簡單的方法？ 今天就來跟大家介紹這樣的指標。

這個指標的基本原理還蠻單純的，如果股價高於13日的加權移動平均線就進場，跌破13日的加權移動平均線就出場。

但如果要更掌握住一檔個股的多空真實動向，不能光用收盤價來作為多空的標準，既然最高價代表當天多頭最佳的戰果，我們就可以用最高價減去加權移動平均線當作多頭力道與均線間的差額，同理最低價是空頭的最大力道，用最低價減去加權移動平均線代表空頭與均線間的差額，這樣就可以算出兩個指標

一個是Elder多頭力道指標，另一個則是Elder空頭力道指標

計算方法

Elder多頭力道指標= 日高 – n區間EMA

Elder空頭力道指標 = 日低 – n區間EMA

畫成指標的腳本如下

// Elder 多頭力道指標

// input: Length(13);

SetInputName(1, “天數”);

Value1 = High – XAverage(Close, Length); Plot1(Value1, “多頭”);

另一個腳本

//Elder 空頭力道指標
//
input: Length(13);

SetInputName(1, "天數");

Value1 = Low - XAverage(Close, Length);

Plot1(Value1, "空頭");

我畫出來的台積電參考圖如下

透過這樣視覺化的表現，可以更掌握台積電的波段買賣點，保守一點可以在多頭力道指標與空頭力道指標都翻紅後才進場，在空力道指標已多日翻黑後就要開始提高警覺了。

基本上大股票用這個方法效果不差。

今天要介紹一個海龜交易法很有名的指標:唐奇安通道。

這是由著名的海龜交易員Richard Donchian所發明,是一個極簡的突破策略:當價格突破通道上緣就買進做多,跌破通道下緣就賣出部位。

可以用以下的腳本畫出指標圖:

input:Period(13);
plot1(Highest(H[1], period),"通道上緣");
plot2(Lowest(L[1], period),"通道下緣" );
plot3((Highest(H, period)+Lowest(L, period))/2,"通道中線");

警示則可以寫成

input:Period(13); 
if H = Highest(H, period) then ret =1;//作多 
if L = Lowest(L,period) then ret=1;//作空

當然這樣的期數調整會視情況而定,每一檔商品可能最佳的結果也都不一樣,不過通常每個交易員都會有一個習慣的參數, 可能是月線或季線加減。 我們先看一下加上買賣點指標畫在圖上的情況,腳本加上以下的部份

Dupper = Highest(H[1], period);
DLower = Lowest(L[1], period); 
if C > Dupper then begin plot4(C*1.01 ,"作多");
 plot5(C*1.02);
 plot6(C*1.03);
 plot7(C*1.04);
 plot8(C*1.05);
 plot9(C*1.06); 
plot10(C*1.07);
 end; 
if C < DLower then begin plot11(C*0.99 ,"作空");
 plot12(C*0.98);
 plot13(C*0.97);
 plot14(C*0.96);
 plot15(C*0.95);
 plot16(C*0.94);
 plot17(C*0.93);
 end;

例如以下的例子

如果我們從2747可以看到明顯的多空分壘,當股價的波動具有足夠的趨勢性時,這樣的指標就能夠發揮最大的效用! 這幾年來簡單的突破系統由於採取極短線賺取利差的人大幅增加, 而導致假突破等”騙線”的情況越來越多,海龜交易也適應性的產生許多變形,但總結的目標就是要減少雜訊, 判斷出商品的走勢穩定性,這是在交易中相當關鍵的獲利點!

DPO指標的原文是 Detrended Price Oscillator，直譯為「非趨勢價格擺盪」指標，所謂的Detrend就是「去除掉趨勢」之意，顧名思義，也就是說這個指標可以將一個股價變動的時間數列值，袪除掉其長線的趨勢方向，而只留下短線價格的波動。這個指標設計的目的似乎與大多數的指標相反，一般的指標都是想要留下趨勢的變動，而袪除掉其短期波動的雜訊。

然而，這個指標要用什麼樣的方法，去除掉長期的趨勢呢？其實它用的方法一點也不新奇，就只是「短線乖離」的觀念而已。首先，對股價取一個固定期間的簡單平均線，將這條線畫在股價圖上，就如附圖１中K線上的藍色線即是。然後我們假想，如果這條籃色的線是一條可以彎曲或拉直的橡皮筋，而股價Ｋ線是固定附著在這條橡皮筋上的東西。現在我們要將這條橡皮筋以水平方向向左右兩方拉直，那麼Ｋ線的形狀就會跟著改變，這時你就會看到股價的「趨勢」不見了，只剩下依附在這條橡皮筋直線上的「短期乖離波動」。我們「將橡皮筋拉直」的這個觀念可以適用在任何採用移動平均線乖離的指標上。

不過，DPO指標又稍為加工了一下，因為光只是採用某一定期間的平均線，還難以突顯短期波動的「震盪幅度」，所以再將這條平均線向右方（附表１中是向下方）移動，而移動的距離以平均天數除以２加１來計算，所以當我們取６日平均值時，右移的距離則是６／２＋１等於４，如果平均天數取７則7／2＝3  餘1，餘數不論再加１，同樣是右移４天。

腳本

input: Length(10);
variable: dpo(0);

SetInputName(1, "天數");

dpo = Close - Average(Close, Length)[(Length /2) + 1];

Plot1(dpo, "DPO"); 

參考圖形

CCI指標的原文是 Commodity Channel Index，直譯的話就是「商品通道指標」。這個指標是由Donald R. Lamber所發明的。

這個指標的計算過程如下：

１.    先計算出典型價格：

TP t ＝ ( 最高價t ＋ 最低價t ＋ 收盤價t  ) ／３

２.    求算典型價格的簡單平均值：

MA t ＝(  TPt  +  TPt-1  + ．．． +  TP t-n+1 ) ／ ｎ

３.    MA t 與TPt 離差絕對值的ｎ日加總：

MD t ＝(｜MAt－TPt｜＋｜MAt-1－TPt-1 ｜＋．．．．＋｜MAt-n+1－TPt-n+1｜)／ｎ

４.    CCI公式：

CCI t ＝ ( TP t－MA t ) ／ (  0.015 * MD t )

這個CCI公式的設計，當典型價格等於其平均值時，CCI值會等於零。所以這個公式的原始設計比較像是在使用乖離率的觀念，因為只有當最後股價在極短期內作劇烈的向上或向下運動時，CCI值才會出現突然向上或向下大幅擺盪的極端值。這個公式的發明者為了將CCI指標值限定在一定的範圍內波動，所以特別將分母部份乘上0.015的參數值。

腳本

// XQ: CCI指標
//
input: Length1(14), Length2(28), Length3(42);

SetInputName(1, "天數一");
SetInputName(2, "天數二");
SetInputName(3, "天數三");

Plot1(CommodityChannel(Length1), "CCI1");
Plot2(CommodityChannel(Length2), "CCI2");
Plot3(CommodityChannel(Length3), "CCI3");

參考圖形

input: Length(14);
variable: pdi_value(0), ndi_value(0), adx_value(0);

SetInputName(1, "天數");

DirectionMovement(Length, pdi_value, ndi_value, adx_value);

// 初始區波動較大, 先不繪出
//
if CurrentBar < Length then
 begin
 pdi_value = 0;
 ndi_value = 0;
 adx_value = 0;
 end;
 
Plot1(pdi_value, "+DI");
Plot2(ndi_value, "-DI");
Plot3(adx_value, "ADX");

參考圖形