Author Archives: 發財橘子

以前市場有個很有名的開盤八法，其中有一個說法是，如果開盤起算的五分鐘K 線，連續三根都收紅，那麼當天收高的機率就比較高，我寫了腳本想要印證這樣的說法是否正確，結果發現，最近漲的不兇，但這兩日走勢比大盤強，今天開盤前十五分鐘又維持連續三根五分鐘K都收紅，那麼作多贏的機率確實比較大。

我試了不少的方向，最後的發現是，符合以下條件下的開盤三紅K，會有比較高的勝率

1.大盤多頭

2.前兩個交易日走勢比加權指數強

3.近十日漲幅沒有大兇

4.開盤前三根五分鐘K都收紅

5.開盤前三根五分鐘K的平均成交量明顯比先前放大

我寫的腳本如下

if GetSymbolField("tse.tw","收盤價","D")
>average(GetSymbolField("tse.tw","收盤價","D"),10)
//多頭市場
and GetSymbolField("tse.tw","收盤價","D")
/ GetSymbolField("tse.tw","收盤價","D")[2]+0.01
<GetField("收盤價","D")/GetField("收盤價","D")[2]
//前兩日比大盤明顯走強
and GetField("收盤價","D")[1]
<GetField("收盤價","D")[10]*1.07
//近十日沒有漲的太兇
then begin

if barfreq<> "Min"and barinterval<> 5
then raiseruntimeerror("本腳本只限五分鐘線");
if time=091500
and trueall(close>close[1],3)
//開盤三根五分鐘線都是紅棒
and average(volume,3)>average(volume,20)*1.3
//開盤的量能明顯增加
then ret=1;
end;

回測設定我是用有量的中小型股，停損停利都設7%

回測報告如下:

勝率接近六成，不過大盤走大空頭時，用這個策略還是大多以停損出場，這策略比較適合在大多頭市場中使用。

如果擔心這個策略輸的時候輸的很慘，另一個方法是把它當成當沖策略，我用進場後的第51根K棒出場來回測，回測報告如下:

勝率雖然比較低，但還是有55%，但最大連續虧損及最大區間虧損就都回到合理的範圍了。

最後，我在檢視回測中出現虧損的個股股價走勢，我發現那種前一天下跌的股票，今天出現紅三K的時候，尾盤收高的機會較大，所以我在腳本中加上一個條件

and GetField("收盤價","D")[1]<GetField("收盤價","D")[2]

加上這個條件後的回測報告如下

加上這條件後的勝率達到68%，更難能可貴的是，最大連續虧損及最大區間虧損只有 7%。

早先公司在開發XS這套軟體的時候，常有朋友勸我說，台灣會寫程式又會做交易的人很有限，你們花這麼多資源做這產品，能賣幾個人呢? 當時我其實心裡也是毛毛的，怕做出曲高和寡的產品，這陣子我用了這項服務之後，我發現，它讓我可以在有任何的Trading idea時，都可以寫成程式去回測，再根據回測的結果不斷的修正程式，最後理解到一個Trading idea在什麼情況下，會work，什麼情況下，聽聽就好，這種拿所有個股的交易及財報資料來作運算，找出在什麼情況下，有較大機率股價會上漲或下跌，其實是大數據分析的一種實踐。

在有這種體會之後，其實我就比較篤定了。因為，這真的可以幫到我。

每次當自己看好的股票股價翻紅時，我們總面臨了天人交戰: “追還是不追”，追嘛怕追到盤整的高點，不追怕這是大漲的起點。今天我想介紹一個策略，這個策略是把一定區間內的上漲跟下跌絕對值分別計算並算出加權平均，當兩者比例非常懸殊時，代表區間內多方很明確地佔了上風，這是一個判定股價是翻明確翻多的交易策略，從回測的數據來看，這個策略還蠻值得大家參考的。

我先把上面說的邏輯寫成一個指標腳本

input:length(10); 
variable: sumUp(0), sumDown(0), up(0), down(0),RS(0);
if CurrentBar = 1 then
begin
sumUp = Average(maxlist(close - close[1], 0), length); 
sumDown = Average(maxlist(close[1] - close, 0), length); 
end
else
begin
up = maxlist(close - close[1], 0);
down = maxlist(close[1] - close, 0);
 
sumUp = sumUp[1] + (up - sumUp[1]) / length;
sumDown = sumDown[1] + (down - sumDown[1]) / length;
end;
if sumdown<>0
then rs=sumup/sumdown;
plot1(rs);

根據這個腳本畫出來的指標如下

各位可以發現，當RS超過4的時候，代表多頭的漲勢非常明確

我把這個指標改寫成策略腳本

if getsymbolfield("tse.tw","收盤價")

>average(getsymbolfield("tse.tw","收盤價"),10)

then begin







input:length(10);

variable: sumUp(0), sumDown(0), up(0), down(0),RS(0);

if CurrentBar = 1 then

begin

sumUp = Average(maxlist(close - close[1], 0), length);

sumDown = Average(maxlist(close[1] - close, 0), length);

end

else

begin

up = maxlist(close - close[1], 0);

down = maxlist(close[1] - close, 0);




sumUp = sumUp[1] + (up - sumUp[1]) / length;

sumDown = sumDown[1] + (down - sumDown[1]) / length;

end;

if sumdown<>0

then rs=sumup/sumdown;

if rs cross over 4

and close>close[1]*1.02

//最近一日漲幅超過2%

and close<close[5]*1.05

//最近五日漲幅小於5%

then ret=1;




end;

回測時我用有量的中小型股，由於我設的計算區間是10天，所以我出場設定是進場後10天

回測報告如下

從回測報告顯示，這個策略在過去三年共出現279個交易訊號，有173次獲利，勝率達到62%。

如果各位希望風險低一點，可以把區間拉長，這樣勝率雖然較低，但風險也會降低不少。

股票的價格，絕大多數的時候，是隨著大盤的多空氣氛，隨著產業的展望，順勢波動，隨波逐流，但就像潮汐一樣，退潮之後總是會轉為漲潮，所以我們可以找出那些現在股價距離平均水準還有一段距離，但開始轉強的公司，期待這些公司是正在從退潮要轉成漲潮。

這樣的公司，需要符合兩個條件

1.總市值不到600日平均的七成

2.收盤價創十日最高價

根據這兩個條件，我的對應腳本如下

settotalbar(700);
if getsymbolfield("tse.tw","收盤價")
> average(getsymbolfield("tse.tw","收盤價"),10)
then begin
value4=GetField("總市值");
value5=average(value4,600);
if value4[1]<value5[1]*0.7
and close=highest(close,10)
then ret=1;
end;

回測設定我用的是過去每年EPS都超過兩元的股票，出場點是設為進場後10天出場

回測報告如下:

勝率約57%，造成虧損的時點，主要是在大盤走長期空頭走勢的時段

如果把這個腳本用有量的中小型股來跑，回測報告如下

勝率甚至超過6成

這樣的策略，它的核心精神有三個

1.在多頭市場之下

2.總市值離三年來的平均值有不小的距離

3.股價正在轉強

符合這三個條件的股票，就極可能符合這個交易策略。

其次，我們在腳本上試的是目前總市值不到長期平均值七成的股票，如果現在股價是不到長期平均值五成時，勝率其實更高

回測數字為證，勝率都快接近七成了。

“低價股如果股價創了近一個月新高且離底部不遠，往往有短線作多的空間”，這段話是以操作低價股創造了不錯蹟效的一位法人跟我說過的話。

他的邏輯是，股價低於15元的股票，基本上就是股票市場上的魯蛇，這種股票通常不會有啥表現，但如果股價可以站上一個月來新高點且距離一個月來的低點不遠，技術面通常線型不會太差，基本面則可能有些不一樣，如果跟長期的高點股價還有點距離的話，那麼短線作多的勝率應該就不低。

要符合上述條件的股票，應該要有以下的特徵

1.股價低於15元。

2.今日最高價創20日以來新高

3.今日收盤價距離20日以來的低點不到7%

4.股價距離40日以來的高點還至少有一成以上的空間

我根據上述的特徵寫的腳本如下:

if GetSymbolField("tse.tw","收盤價")
 > average(GetSymbolField("tse.tw","收盤價"),10)
then begin
 
 if close<15
 and H = highest(H,20)
 and close<lowest(low,20)*1.07
 and highest(h,40)>close*1.1
 then 
 ret=1;
 
end;

回測設定  我是用所有的股票下去跑三年，停損點設5%，停利點設7%

回測報告如下:

從回測報告來看，這些低PB的低價股，一旦站上一個月來的高點，還真的是一個短線可以作多的訊號。

然後我發現，這個策略不旦可以作短，其實作波段也很好用，以下是我把出場點改成進場後二十天

雖然勝率略降了一點，但總報酬率高出許多，且連續虧損也比短線操作要小，顯示這個策略會抓到那些長線回升的低價股。

這個策略的語法很簡單，但勝率卻出奇的高，算是市場經驗轉化成交易策略的一個成功的例子。

糾結均線代表的是短中長期持股者的成本都接近一致，一旦突破，賣壓很輕，同樣的道理，一旦跌破，代表短中長期的持股者大家都同時被套牢，這種情況會造成，股價一旦反彈，馬上就會面臨極大的賣壓，所以跌破糾結均線，是可信度極高的波段空頭策略，特別是對那些長期不大賺錢的大型股，更是如此。

跌破糾結均線的腳本，跟突破糾結均線的腳本差不多

if GetSymbolField("tse.tw","收盤價")
<average(GetSymbolField("tse.tw","收盤價"),10)
then begin

input: shortlength(5); setinputname(1,"短期均線期數");
input: midlength(10); setinputname(2,"中期均線期數");
input: Longlength(20); setinputname(3,"長期均線期數");
input: Percent(5); setinputname(4,"均線糾結區間%");
input: XLen(20); setinputname(5,"均線糾結期數");

input: Volpercent(25); setinputname(6,"放量幅度%");//帶量突破的量是超過最長期的均量多少%
variable: shortaverage(0);
variable: midaverage(0);
variable: Longaverage(0);
variable: AvgHLp(0),AvgH(0),AvgL(0);

shortaverage = average(close,shortlength);
midaverage = average(close,midlength);
Longaverage = average(close,Longlength);
 
 
AvgH = maxlist(shortaverage,midaverage,Longaverage);
AvgL = minlist(shortaverage,midaverage,Longaverage);

if AvgL > 0 then AvgHLp = 100*AvgH/AvgL -100;

condition1 = trueAll(AvgHLp < Percent,XLen);
condition2 = V > average(V[1],XLen)*(1+Volpercent/100) ;
condition3 = average(Volume[1], 5) >= 2000;
condition4 = C < AvgL *(0.98) and L < lowest(L[1],XLen);

ret = condition1 and condition2 and condition3 and condition4;
end;

不過在回測設定時，我用的是不大賺錢的大型股，出場是進場後二十天後

回測報告如下

我們可以看得出來，這是一個勝率超過六成的波段作空策略

突破糾結均線一般被視為一個重要的買進訊號，因為這代表不管短中長期的持股者，都處於剛剛賺錢的狀態，所以解套的賣壓很輕，獲利了結的賣壓也不大，只要買盤持續，後市向上的機率比較高，為了印證這樣的市場印象，我寫了一個對應的腳本，但不是所有的股票，突破糾結均線後作多都是一個績效良好的交易策略，實證上發現，唯有高ROE的股票，如果出現糾結均線突破時，才有有較高的勝率。

對於糾結均線突破，我寫的腳本如下

if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),10)
then begin


input: shortlength(5); setinputname(1,"短期均線期數");
input: midlength(10); setinputname(2,"中期均線期數");
input: Longlength(20); setinputname(3,"長期均線期數");
input: Percent(5); setinputname(4,"均線糾結區間%");
input: XLen(10); setinputname(5,"均線糾結期數");

input: Volpercent(25); setinputname(6,"放量幅度%");//帶量突破的量是超過最長期的均量多少%
variable: shortaverage(0);
variable: midaverage(0);
variable: Longaverage(0);
variable: AvgHLp(0),AvgH(0),AvgL(0);

shortaverage = average(close,shortlength);
midaverage = average(close,midlength);
Longaverage = average(close,Longlength);
 
AvgH = maxlist(shortaverage,midaverage,Longaverage);
AvgL = minlist(shortaverage,midaverage,Longaverage);

if AvgL > 0 then AvgHLp = 100*AvgH/AvgL -100;

condition1 = trueAll(AvgHLp < Percent,XLen);
condition2 = V > average(V[1],XLen)*(1+Volpercent/100) ;
condition3 = C > AvgH *(1.02) and H > highest(H[1],XLen);
condition4 = average(volume[1], 5) >= 1000; 

ret = condition1 and condition2 and condition3 and condition4;

end;

回測設定  我用的是高ROE的股票，停損停利都設10%

回測報告如下

勝率很高，虧錢的時段都是在大空頭市場中，所以如果在多頭市場高ROE的股票出現這種情況， 還真的是一個不錯的買進訊號。

我試著用所有的股票去跑，用有量的中小型股去跑，勝率都不如高ROE的股票高，顯示這個交易策略對績優股比較有用。

這陣子介紹了不少從繼續型態發展出來的策略，當中的多頭策略，可以協助我們找到那些在長期多頭走勢中休息後準備再出發的股票，當中的空頭策略，則常能讓我們對手中持股要留要砍，下定決心。

在這諸多繼續型態當中，平台整理是一個很常發生的型態，平台整理之後，可能往上，但也可能往下，在一段跌勢之後，一旦跌破整理區，股價繼績下跌的機率很高。

跟平盤整理後突破一樣，平盤整理後跌破有四個要件

1.整理型態前30天跌幅超過1成。

2.整理期間最高點與最低點之間差不到7%

3.整理期間最高點與第四高點間差不到2%

4.整理期間最低點與第四低點間差不到2%

把這四點畫成圖形，就像下面這張圖

我寫的腳本如下

if GetSymbolField("tse.tw","收盤價")
<average(GetSymbolField("tse.tw","收盤價"),10)
then begin

input:Period(15, "平台區間");
input:ratio(7, "整理幅度(%)");
input:ratio1(2,"各高點(低點)間的差異幅度");
var:h1(0),h2(0),L1(0),L2(0);
h1=nthhighest(1,high[1],period);
h2=nthhighest(4,high[1],period);
l1=nthlowest(1,low[1],period);
l2=nthlowest(4,low[1],period);

if (h1-l1)/l1<=ratio/100
and (h1-h2)/h2<=ratio1/100
and (l2-l1)/l1<=ratio1/100
and close cross below l1
and close[period+30]>l1*1.1
then ret=1;
end;

回測設定我用的是不大賺錢的中大型股，出場設定是十天。

回測報告如下

回測報告顯示，在172次的交易機會裡，有111次獲利出場，61次虧損，勝率蠻高的。

而它的連續虧損情況，相較於連續獲利情況，小了很多，顯示這是一個賺的時候大賺，賠的時候小賠的策略

先前介紹了多次到頂而破等等從繼續型態所衍生出來的交易策略，那如果沒有出現一底高過一底，也沒有出現高點連續很接近的情況，而是屬於不規則的橫向整理，該怎麼面對呢?

我試著寫了一個腳本來模擬各種情況，我發現當不規則的整理型態，如果符合以下的特徵，會是不錯的短多策略

1.整理型態前30天漲幅超過1成。

2.整理期間最高點與最低點之間差不到7%

3.整理期間最高點與第四高點間差不到2%

4.整理期間最低點與第四低點間差不到2%

如果符合以上四點，一旦股價突破區間最高點，繼續向上的機率頗高。

我把這樣的整理型態畫成一張圖如下

對應的腳本如下

 if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),10)
then begin
 
input:Period(15, "平台區間");
input:ratio(7, "整理幅度(%)");
input:ratio1(2,"各高點(低點)間的差異幅度");
var:h1(0),h2(0),L1(0),L2(0);
h1=nthhighest(1,high[1],period);
h2=nthhighest(4,high[1],period);
l1=nthlowest(1,low[1],period);
l2=nthlowest(4,low[1],period);

if (h1-l1)/l1<=ratio/100
and (h1-h2)/h2<=ratio1/100
and (l2-l1)/l1<=ratio1/100
and close cross over h1
and close[period+30]*1.1<h1
and volume> average(volume,period)
then ret=1;
end;

回測設定我用的是有量的中小型股，停損停利我都設成10%

以下是回測報告

從回測報告上來看，過去三年一共有198個交易的機會，其中113個可以獲利出場，勝率是57%，從淨值的變化圖來看，這個策略在空頭市場比較容易出現連續虧損的情況，比較適合大多頭市場。

若是多次到頂而破是一個不錯的短多策略，那麼多次到底跌破理論上應該也會是一個不錯的短空交易策略，就像下圖一樣，這種型態代表的是一個強力支撐區的被跌破，我從過去三年的數據中發現，如果在頂部區探了四次底之後，第五次正式跌破後短空，勝率會超過六成。

這個短空策 略的腳本寫法跟多次到頂而破很像

input:HitTimes(4); setinputname(1,"設定觸底次數");
input:RangeRatio(1); setinputname(2,"設定底部區範圍寬度%");
input:Length(20); setinputname(3,"計算期數");

 if GetSymbolField("tse.tw","收盤價")
<average(GetSymbolField("tse.tw","收盤價"),10)
then begin
variable: theLow(0); 

//找到過去期間的最低點
theLow = lowest(low[1],Length); 

variable: LowUpperBound(0); 

// 設為瓶頸區間上界
LowUpperBound = theLow *(100+RangeRatio)/100; 

variable: TouchRangeTimes(0);
//期間中進入瓶頸區間的低點次數,每根K棒要歸0
TouchRangeTimes = CountIF(Low[1] < LowUpperBound, Length);
 
Condition1 = TouchRangeTimes >= HitTimes;
Condition2 = close < theLow;
Condition3 = Average(Volume, 5) >= 1000;

Ret = Condition1 And Condition2 And Condition3;
end;
 

因為是作空，所以我執行的股票是有不大賺錢的大型股，停損停利都是設5%

回測報告如下:

過去三年有818次的交易機會，其中513次是賺錢出場，從多次到頂而突破跟多次到頂而跌破兩個交易策略來看，這種多頭空頭最後防線被棄守後，獲勝方乘勝追擊的機率是很高的。

多次到頂而破，也是繼續型態的一種，它的概念在於股價突破了一個多次上攻都被打回來的鐵板區(請見下方附圖)，我們可以假設原本這裡是多頭多次進攻都無功而返的空頭重要防線，正常的情況下，一鼓作氣，再而衰，三而竭，如果反而能夠一舉攻破，代表有新生的買盤介入，或是代表原本的賣壓縮手或被消化殆盡。 這樣的情況如果出現，往往是一趟波段多頭行情的開始。

以下的腳本，就是在描述上圖的情況

input:HitTimes(4,"設定觸頂次數");
input:RangeRatio(1,"設定頭部區範圍寬度%");
input:Length(40,"計算期數");

if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),10)
then begin
variable: theHigh(0); 

//找到過去其間的最高點
theHigh = Highest(High[1],Length); 
value1=highestbar(high[1],length);

variable: HighLowerBound(0); 

// 設為瓶頸區間上界
HighLowerBound = theHigh *(100-RangeRatio)/100; 

variable: TouchRangeTimes(0); 

//回算在此區間中 進去瓶頸區的次數 
TouchRangeTimes = CountIF(High[1] > HighLowerBound, Length-value1);
 
Condition1 = TouchRangeTimes >= HitTimes;
Condition2 = close > theHigh;
condition3=close[length]*1.1<thehigh;


Ret = Condition1 and Condition2 and condition3 ;
end;

回測設定我用的是有量的中小型股，停利停損都設為5%

回測報告如下:

從回測報告上可以看得出，過去三年，這樣的交易機會高達2001次，勝率高達六成以上，顯示這是一個很值得作參考的交易策略