Author Archives: 發財橘子

“月線，週線，日線要同時看，月線看大方向，週線看波段，日線看進場點” 在民國79年，那個一天沒事刷個兩三百點的時候，市場老手總是如此地耳提面命的提醒著我，雖然這些年市場老手大多告老還鄉，但”日週月”線要同時看，這句話我總是記在心裡。

所以當XS提供了幾個跨頻率的技術指標函數時，我也就試著想要寫出用日週月線不同頻率不同指標的交易策略，以下是我試著寫的一個樣本

我思考過程如下圖

因為XS有提供了幾個跨頻率時來運用的技術指標函數，所以這個腳本就可以寫的很簡短

condition1=false;
condition2=false;
condition3=false;

input: Length(5, "計算期數");
input: RSVt(3, "RSVt權數");
input: Kt(3, "Kt權數");
input: LOWBound(30, "低檔區");

variable: rsv1(0), k1(0), _d1(0);

xf_Stochastic("M", Length, RSVt, Kt, rsv1, k1, _d1);

condition1= K1>_D1;
 //月線KD轉強

xf_macd("W",close,6,12,4,value1,value2,value3);
condition2=value2>0;
//週線DIF轉正

if condition1 and condition2
and Momentum(Close, 10) Crosses Above 0
and GetSymbolField("tse.tw","收盤價")>
average(GetSymbolField("tse.tw","收盤價"),10)

then ret=1;

在這個腳本中，我用到了xf_rsi，xf_macd這兩個跨頻率的常用技術指標函數，在XS中都已經成了系統函數，各位在IDE中的函數區都可以查得到它們的計算公式，並且可以直接拿來使用

我拿這腳本去跑最近半年的回測，回測報告如下

以上大約是跨頻率的寫法，上述的腳本只是個語法的示範，各位可以自己挑選不同的日週月線指標組合出專屬的交易策略。

隨著程式交易日漸引起大家的注意，小弟也開始從十年寒窗無人問，變成朋友詢問策略寫法的對象，最新被問到一個交易策略: “找出那些日線KD向上的股票中，60分鐘線盤整後創新高的”。

我整理了朋友的思考方式，把這個策略的想法歸納如下圖

他的思考方向是如果個股KD 日線呈多頭排列，代表最近是多頭在主導，60分鐘線如果盤整一陣子，代表近期處於多頭在新佔領的地盤休養生息，休息夠了，一旦噴出，代表另一波的多頭走勢即將展開。

我根據這個思維，寫了以下的腳本，

//盤整後噴出
input: Periods(15,"計算期數");
input: Ratio(3,"近期波動幅度%");
input: TXT1("僅適用60分鐘","使用限制");
var:rsv1(0),k1(0),d1(0);
xf_stochastic("D",9, 3, 3, rsv1, k1, d1);
condition1 = false;

if (highest(high[1],Periods-1) - lowest(low[1],Periods-1))/close[1] <= ratio*0.01 
then condition1=true//近期波動在?%以內
else return;

if condition1 and high = highest(high, Periods)
and GetSymbolField("tse.tw","收盤價","D")
>average(GetSymbolField("tse.tw","收盤價","D"),10)
and volume >=average(volume,20)*1.3
and k1>d1
and k1>50
and k1<80

then ret=1;

這個腳本有用到我之前有介紹過的兩個自訂函數，

現在已經成為XScript編輯器中的系統函數囉！

直接輸入函數呼叫即可，不需要在自訂函數腳本。

在此稍微介紹一下在盤後噴出腳本中，使用到這兩個函數的原因為，

一個是”xf_getvalue”，這是用來作跨頻率的資料對齊用的，

另一個是”xf_stochastic”，這個函數是用來計算跨頻率的KD值的，它的用法是

xf_stochastic(“頻率”,天期,3,3,rsv,K,D)

需要這麼處理的原因在於，我們在這裡跑的是60分鐘線，如果直接用KD的函數去跑，是跑不出日KD的正確數字的，因為60分鐘線的計算基礎下，前一根不會是前一天，所以需要先做資料對齊的處理，算出在60分鐘線之下，前第N根的數字才是日線要拿的值。

我回測一年60分鐘線之後的報告如下圖

這樣的回測結果確實有比單純用60分鐘線去跑的時候勝率高出一些。

這當中有不少參數，停損停利的條件，以及應用的股票(我用的是有量的中小型股)可以調整，請各位自行找出最適合您自己的參數及應用的商品

跨頻率的腳本在撰寫時，如果有用到指標，都必須使用指定頻率的指標函數，不能直接引用系統提供的原有函數，希望XS可以儘早提供常用指標如RSI，MACD等等在跨頻率使用時的函數。

有幾個我一向敬重的市場老手，他們的成名絕技都是在多頭市場大量追進領先市場創很長時間以來新高的股票，我想試著把這樣的精神，改寫成交易策略，以下是我的心路歷程。

在認識這些市場老手之前，我對”領先市場創長期以來新高”這樣的操作策略並不陌生，原因在於我師父介紹我研究美國成長股大師William J. O’Neil，以及他的CANSLIM法則，師父認為，台灣是中小型成長股的溫床，所以歐尼爾的操作手法比巴菲特及彼得林區。

CANSLIM的法則，用台灣的選股用語，大略如下:

C：單季營收年增率≧18%。

A：五年營收複合成長率≧15%且每年皆為正成長。

N：股價創最近１年最高價。

S：中小型股

L：一年股價相對強弱度(RPS)≧80。

I：投信基金持有家數≧10或外資持股比例≧5%。

M：市場趨勢是否為多頭？

簡單講，CANSLIM法則就是在大盤多頭時，挑選股價比大盤強勢的，法人有在佈局的中小型成長股，然後在股價創近一年新高時進場

這是我第一次接觸到比大盤強且股價創長期以來新高的交易策略

後來我因為工作的關係，開始接觸到一些在操作上頗為成功的人士，大家在個性上，專業上或有不同，但其中有幾位，不約而同的，都具有兩個共同特徵

1.很會看盤，對盤很敏感

2.總是在大盤多頭時，大量買進領先大盤創長期以來新高的股票

我曾經問過他們為何這麼操作，得到的答案一般有兩個

1.股價領先基本面，股價創長期來新高代表基本面出現新的機會

2.上檔的賣壓會比較輕，比較好拉。

後來我自己也試著用新台幣印證這樣的手法，雖然有賺有賠，但賺的時候比較大段，賠的時候還好虧的不多。

現在有了XS，我想試著實證看看，這樣的操作手法是不是真的有效? 而要怎麼操作才最有效?

首先我先把多頭市場時股價領先大盤創歷史新高(且法人買進)的概念寫成以下的腳本

condition1=false;
condition2=false;
condition3=false;
condition4=false;

if GetSymbolField("tse.tw","收盤價")
>average(GetSymbolField("tse.tw","收盤價"),20)
then condition1=true;//市場處於多頭
value1=barslast(close=highest(close,100));
if close=highest(close,100) and value1[1]>60
then condition2=true;//股價創近來新高

if summation(GetField("法人買賣超張數"),10)>500
then condition3=true;//法人支持

if summation(GetField("強弱指標","D"),100)>0
then condition4=true;//股價比大盤強
 
if condition1 and condition2 and condition3
and condition4
and volume>1000


then ret=1;

回測時，我分成兩種出場方式，第一種是買進後持有10天，回測報告如下

我是用有量的中小型股共195檔去回測，這樣的策略雖然勝率只有五成多一點，但多頭市場會穩定獲利，空頭市場只有在反彈時因為加權指數突破20日均線而有些強勢股票會出進場訊號，然後盤不好時個股也會跟著拉回而被停損掉。

由於一開始的腳本我挑的是創60天來新高的股票，所以可能強度不足以抵擋大盤的空頭氣氛 ，所以我把60天改成100天，我的想法是股價都能創100日來新高，就算盤不好，短期應該也會有所表現，從以下的測試報告看來，確實是如此

上面這個回測我是設五天出場，算是短多的概念，但如果不設出場日期呢?

從回測的結果來看，勝率不變，總報酬率更高

我有試著把200天改成300天，結果交易次數，勝率及總報酬率都比200天差

所以結論就是

1.在多頭市場時挑股價領先大盤創200天來新高的股票是可以值得留意的

2.這種股票抱到賺一成才走比抱五天就走好

3.如果能更精準的掌握大盤的多空波段，這個策略的勝率會更高

英國脫歐搞得全球股市大跌，短線上，什麼訊號才是止跌訊號，應該是大家比較關心的課題，以前老營業員有個口訣，開低殺低後若站回開盤價之上，可以搶短，我想今天就用實證回測的數據，來跟大家探討，這樣的口訣，到底對不對? 可以應用在什麼樣的股票? 可以應用在什麼樣的情況?

首先當然是先把口訣寫成一個腳本

input:ratio(10,"近十日最小下跌幅度");
if open*1.025<close[1]//開盤重挫
and close>open //收盤比開盤高
and close*(1+ratio/100)<close[9]
//近十日跌幅超過N%
and low*1.01<open
//開低後又殺低
then ret=1;

我用的是日線，首先我先前十天的下跌幅度是訂在10%，持有最大期數訂為兩天，然後我用有量的中小型股票去跑，過去三年的回測報告如下:

我們可以發現，這樣的設定在大盤急挫的時候，還是會虧錢，於是，我就把過去十天的下跌幅度放大到15%，20%，25%，以下是他們分別的回測報告

過去十天跌幅超過15%的股票勝率提高到55%

當近十日跌幅超過兩成時，勝率進一步提昇到59.6%

如果把十日跌幅設定在25%，勝率更超過六成，達到63%

不過如果把跌幅再往上拉，勝率反而就下滑了，這樣的現象顯示，對於有量的中小型股而言，隨著大盤的利空而下跌，跌到有一天，開低下殺後，如果能回到開盤價之上且站穩到收盤，隔天有六成以上的機率，還有高點可以獲利了結。

我也試著把這個腳本用權值股去跑，結果我發現效果並不好

顯示賺的時候小賺，賠的時候是大賠，代表權值股逆勢持續拉昇的力道是比較不夠的。

值此大盤危疑之際，這個策略的實證數字告訴我們，在操作上，要搶急跌後的短線，有三個原則

1.要有量的中小型股

2.近期要跌的夠慘

3.開低走低後若能站回開盤價且站好站穩

那就有六成的機率明天有比今天收盤價高的價位可以賣。

昨天有網友希望我寫外盤量相關的交易策略，我這個標準差魔人第一時間想到的就是用bbnad，試寫了一下，效果還可以，敬呈批閱。

我的思考邏輯是

1.拿外盤量這個欄位來計算(因為用getfield語法，這欄位只support日線以上，所以用日線)

2.計算外盤量佔總量的比重

3.因為一天的暴量有可能是一日行情，所以外盤量比重取三日移動平均

4.拿外盤量比重三日平均算bband

5.如果bbandwidth從底部翻揚，代表從平凡要轉向絢爛

6.如果外般量比重三日平均突破bband上限，代表這個轉向是往多頭轉

根據上述的邏輯，我寫了以下的指標，

var:bv(0),bva(0);
if volume<>0 then 
bv=GetField("外盤量")/volume*100;
bva=average(bv,3);

input:length(20);
variable:up1(0),down1(0),mid1(0),bbandwidth(0);
up1 = bollingerband(bva, Length, 1);
down1 = bollingerband(bva, Length, -1 );
mid1 = (up1 + down1) / 2;
bbandwidth = 100 * (up1 - down1) / mid1;
plot1(up1);
plot2(down1);
plot3(bva);
plot4(bbandwidth);

我用郭董最近講的很豪邁的2317鴻海來作例子

各位可以發現，在郭董說話的前一陣子，外盤買進佔成交量的比重就出現我上面說到的多頭訊號

1.bbandwidth 向上翻揚

2.外盤量三日均線突破bband上限

我就把這個指標改寫成交易策略如下:

var:bv(0),bva(0);
if volume<>0 then 
bv=GetField("外盤量")/volume*100;
bva=average(bv,3);

input:length(20);
variable:up1(0),down1(0),mid1(0),bbandwidth(0);
up1 = bollingerband(bva, Length, 1);
down1 = bollingerband(bva, Length, -1 );
mid1 = (up1 + down1) / 2;
bbandwidth = 100 * (up1 - down1) / mid1;
if bbandwidth cross over 20
and bva cross over up1
then ret=1;

拿這策略拿有量的中小型股去回測半年，一年，兩年及三年，回測報告分別如下:

當然這個策略還可以有進一步優化的空間，但初步的結果，應該算是一個可以拿來好好運用的方法。

連著介紹了基金投資，波段操作的一些腳本，結果被同事笑說不食人間煙火，他們說大家既不會選股也看不懂國際財經情勢，最好能介紹那些可以每天當沖的交易策略，只要能賺多賠少，回家前平倉無掛念，這樣才是王道。

為了滿足同事們的需求，接下來我盡量多介紹一些當沖的交易策略，首先要跟大家介紹的當沖策略，它的成形必須具備幾個條件

1.大盤多頭。加權指數5日均線大於20日均線。

2.開高。 開盤價要比昨收價高出2.5%以上。

3.不拉回。開盤後超過一定時間最低價不低於最高價的1.5%

4.創新高。 開高不跌後一旦再創新高就買進。

從分時圖來看，就是類似下面的這張圖

要滿足上述四個條件，我寫的腳本如下:

if barfreq <>"Min" or barinterval<> 1
then raiseruntimeerror("歹勢，本腳本只適用於1分鐘線");

var:count(0);
count=count+1;
if date<>date[1]
then count=1;
 
if GetField("開盤價","D")> GetField("收盤價","D")[1]*1.025
and count>5
and lowest(low[1],count-1)*1.015>highest(high[1],count-1)

and close =highest(high,count)
then ret=1;

這個腳本是用1分鐘線及日線的跨頻率寫成的，其中最重要的概念就是1分鐘線開高後要維持一陣子，我自己實驗的結果，開高後橫盤10分鐘以上再創新高，其勝率比橫盤5分鐘的勝率高

這是最近的多頭走勢裡，橫盤五分鐘以上創新高的回測報告，

如果改成橫盤10分鐘以上，回測的數據如下:

交易次數只比五分鐘的少了一點，在最近一個月裡也是有35次交易的機會，勝率是57.14%，總報酬是17.2%，以當沖策略來看，這樣的數據應該算是很不錯了。

如果把盤整的時間拉長到超過20分鐘，在過去一個月有25次的交易機會，其中16次可以順利獲利了結，勝率是64%，總報酬達19.84%

這個策略的迷人之處在於，如果我們把同樣的邏輯用在空頭策略，我們可以寫出下面的放空腳本

if barfreq <>"Min" or barinterval<> 1
then raiseruntimeerror("歹勢，本腳本只適用於1分鐘線");

var:count(0);
count=count+1;
if date<>date[1]
then count=1;
 
if GetField("開盤價","D")*1.025< GetField("收盤價","D")[1] 
and count>10
and lowest(low[1],count-1)*1.015>highest(high[1],count-1)

and close =lowest(low,count)
then ret=1;

這個腳本近一個月的回測報告如下

意思是雖然最近一個月指數是多頭，但用這個策略放空依然是work的

所以我們就可以試著在盤中兩頭都作，這樣不管大盤是拉尾盤還是殺尾盤我們都不用害怕。

以上是第一個當沖的策略腳本，我們下次見

定存股怎麼操作比較好? 我的建議是buy and hold!!

why?   有數字為證

首先我們先來定義什麼是定存股，我設了四個條件

1.年營收要大於十億元。有一定的經營規模比較不會受到單一客戶或特殊事件的影響。

2.連續五年營收每年就算衰退也不會超過5%。代表本業穩固

3.連績五年每年EPS超過兩元。

4.毛利率沒有掉的很兇。

其中第四項用條列式挑不出來，所以我寫成腳本如下

value1=GetField("營業毛利率","Q");
input:ratio(10,"毛利率單季衰退幅度上限");
input:period(10,"計算的期間，單位是季");

if trueall(value1>value1[1]*(1-ratio/100),period)
then ret=1;

台股中符合這四項的股票共有83檔

如果在三年前買進這八十三檔，然後不除權息，其中63檔賺錢，20檔賠錢，平均報酬率是42.63%。

同時期加權指數是漲了8.05%

當然這種買下去就一直抱的操作方式不見得大家會接受，所以我也試著用波段的方式來操作，波段操作有三種方法，一種是大盤週線突破月線時買定存股，另一種則是不管大盤，個股週線突破月線時進場，最後一種則是大盤週線大於月線且個股週線突破月線時進場

第一種的回測報告如下:

這個回測報告是以進場後持有70天為計算基礎

第二種的回測報告如下

第三種的回測報告如下:

我們從這三種不同的回測報告可以發現，如果我們把定存股拿來作市場時機操作，在大盤多翻空時出場，在大盤空翻多時進場，確實可以降低系統風險，但不會讓報酬率比buy and hold的操作方式高到那裡去，但交易次數會多上很多。

如果我們把定存股再作篩選，只留下那些護城河很高的股票(如下圖)，

那麼不管用上面的那一種方法，風險會降低，但報酬率及每一筆的平均報酬不會更好，勝率也沒有比用83檔時高。

總的來說，

1.定存股如果條件寬鬆一點，且用buy and hold，長期下來，勝率最高，平均報酬率也最高，但在空頭市場跌起來也夠嚇人。

2.如果把條件定嚴一點，然後用buy and hold，長期下來，勝率OK，風險最低，總報酬也夠 迷人。

3.Play market timing時，在大盤空翻多時才進場，可以降低風險，但報酬率會拉低。

以上大約是我把定存股拿來回測時觀察到的現象，或許未來我如果有找到適合定存股的交易策略時，再來跟大家報告

每次都用有量的中小型股當投資標的，生性保守的朋友說能不能介一些適合大型股的交易策略，最好是進出次數不要太多的。我試了幾種方法，發現大股票在多頭市場出現大碗底型態時，績效不錯，推荐給大家。

所謂的大碗底，就是類似像下面這種型態的股票

上圖在紅色箭頭處附近呈現了一個碗狀的底部區。

為了尋找這類型的股票，我寫了一個腳本如下:

value1=lowestbar(low,100);
value2=lowest(low,100);
value3=highestbar(high,100);
value4=highest(high,100);
 
if value4>value2*1.2
and value3-value1>15

then begin
if value1>15
and value2*1.05>close[1]
and average(volume[1],15)<5000
and close>close[1]*1.02
and volume>average(volume[1],15)*1.2
and GetSymbolField("tse.tw","收盤價")>
average(GetSymbolField("tse.tw","收盤價"),20)


then ret=1;
end;

我用這個腳本去跑大型股，回測報告如下:

兩年的時間總交易次數是43次，其中23次賺錢，但賺錢時賺10%，虧錢時虧5%，手氣最差的時候是連續虧了17.56%，意思是在權值股及中型100成份股中，如果出現這樣的碗型底，站在買方是值得一試的交易

不過如果拿去跑小型股，出來的數字就不優了。

之所以這個腳本比較適合大型股，原因在於大型股的籌碼比較凌亂，需要比較長的時間來整理及換手，所以比較容易出現較長時間的落底打底過程。

以前老師父教我們用週線抓波段，用日線抓進場日期，用60分鐘線抓交易時機，他們總是要我們週線日線及60分鐘線要同時看，所以我們看盤的螢幕就愈來愈大，愈來愈多，做為後生小輩，師父的話都有聽，但坦白說，知其然，不知其所以然，後來讀到一本書，Alexander Elder的著作: “Trading for a living”，這是一本同時使用不同頻率來制定交易策略的著作，我試著參照書裡的思考邏輯，寫出對應的交易策略，回測的效果還不錯，跟大家分享這個策略，各位不妨以此為基礎，進一步調整成勝率更高的私房策略。

在這本書裡，Alexander 提出了一個觀念: 叫作三重濾網交易系統(Triple Screen Trading System)，它的概念是把股價波動的趨勢分成三種，一是主趨勢，二是中期趨勢，三是短期趨勢，他用Tide(潮汐)，波浪(Wave)與小漣漪(Ripple)三種海浪的變化來代表這三種不同的趨勢，顧名思義，潮汐是長線的主要趨勢，漲潮時，海水會愈來愈逼近海岸，退潮時則海水會離海岸愈來愈遠。在漲潮退潮的過程中，海浪則是一波波打向岸邊，不斷地往前衝然後後退，漣漪則是海浪踫到不同地形地物時所激起的浪花，雖然漂亮而惹人注目，但對於大方向無關緊要。

Alexander的三重濾網交易系統的概念就是

1.掌握主要趨勢。(週線)

2.在短期超買超賣後尋找進場時機(日線)

3.從股價的波動中確認進場點(盤中)

這樣的觀念，等於在一個交易系統中，同時使用了週線，日線及盤中洗價(例如60分鐘線)這樣的概念，這是一個跨三種頻率的交易策略，這樣的策略該怎麼建構呢?

首先是挑選週，日及60分鐘所用的指標及觸發條件

第一重看長線，可以用趨勢型的指標，所以我挑選MA移動平均線

第二重是要找在長線上昇趨勢中的回檔相對低點，所以我選擇動能指標MTM

第三重則是用突破型交易策略，當60分鐘線創20小時來新高。

這三者合在一起，就可以找出在對的趨勢裡，短期整理後又重新往趨勢前進的股票。

根據上述的邏輯，對應的腳本如下:

//週線多頭排列
if GetField("收盤價","W")
>=average(GetField("收盤價","W"),4)
and 
average(GetField("收盤價","W"),4)
>=average(getfield("收盤價","w"),15)
and 
//日線動能小於0
GetField("收盤價","d")-GetField("收盤價","d")[10]
<0
then begin
//60分鐘線創20小時來新高
if close=highest(high,20)
then ret=1;
end;

用這個腳本去作六個月期及三年期回測，跑有量的中小型股，回測報告如下圖

其實我也試著把大型拿來用這個策略跑過，雖然總報酬率還是有300多%，但勝率只有39%，效果還是遠不如有量的中小型股票好

在寫這種跨頻率腳本時，要特別留意資料對齊的問題，所以非基準頻率的欄位，最好不要透過宣告變數來使用。直接用引號[x]來代表前x期的該欄位數據，才能精準的取得前x期的數據。

跨頻率的交易策略我覺得確實值得一試，推薦給大家。