Author Archives: 發財橘子

價值型投資都是價位到了就buy and hold，往往股票買了之後就要擺好久，如果想要資金運用的更有效率，最好是漲勢要開始發動時再進場。今天來跟大家介紹的，就是這樣的策略。

首先，先來設計符合價值型投資的標準

這裡用的標準是，企業價值必須低於稅前息前折舊前盈餘的四倍

企業價值是市場認定這家企業扣除現金與借款之外的評價

稅前息前折舊前淨利則是這業務本身可以帶來的獲利

前者是後者的四倍，代表純粹談這家公司的運營情況，四年可以回本

腳本如下

value1=GetField("總市值","D");//單位億
value2=GetField("負債總額","Q");//單位百萬
value3=GetField("現金及約當現金","Q");//單位百萬
value4=GetField("短期投資","Q");//單位百萬
value5=GetField("稅前息前折舊前淨利","Q");//單位百萬

var: pricingm1(0);
input: bl(4,"上限值");
if value5>0 then begin
pricingm1=(value1*100+value2-value3-value4)
/summation(value5,4);

if pricingm1<bl and pricingm1>1
then ret=1;
outputfield(1,pricingm1,1,"EV/EBITDA");
outputfield(2,value1*100+value2-value3-value4,0,"EV");
outputfield(3,value5,0,"EBITDA");
outputfield(4,value1,0,"總市值");
outputfield(5,value2,0,"負債總額");
outputfield(6,value3,0,"現金");
outputfield(7,value4,0,"短期投資");
end;

再來就是加上進場時機的條件，我用的是近一日投信買超張數超過成交量的一成。價值型股票如果連講究資金運用效率的投信都進場，往往代表近期可能會受市場青睞

最後再加上過去四年EPS都超過一元的過濾條件

整體選股策略如下圖

用這個選股策略去回測所有股票，停損停利都設為7%，過去七年的回測報告如下圖

這個策略的勝率雖然不算特別高，但總報酬還不錯，屬於多頭市場有表現，空頭市場守得住的策略，更難能可貴的是，交易次數還不少，代表策略還有進一步優化的空間，有興趣的朋友可以試看看。

透過回測，我們發現，長期盤整後的個股，當其技術指標如MACD及DMI等出現買進訊號時，勝率特別高，同樣的現象，也發生在KD這個指標上。

我的同仁發現，如果具備以下條件的個股，在短線上，上漲的機率頗高：

一、連續5日成交量>500

二、日KD黃金交叉且週KD黃金交叉

三、日K值和D值向上+週K值和D值向上且K值>50

四、144日最高與最低之幅度<10%

同仁寫的腳本如下：

 
Input:SPeriod(5),MPeriod(8),LPeriod(55),LLPeriod(144); 
Input:SMALen(13); 
Input:Length(9),RSVt(3),Kt(3);
Var:_rsv(0),k(0),_d(0);
Var:rsvW(0),kW(0),_dW(0);
// 計算 
Stochastic(Length, RSVt, Kt, _rsv, k, _d); 
xf_Stochastic("W",Length, RSVt, Kt, rsvW, kW, _dW); 
// 條件 
Condition1=trueall(V>500,SPeriod);
//1. 連續5日成交量>500 
Condition2=k Cross Over _d and kW Cross Over _dW;
//2. 日KD黃金交叉且週KD黃金交叉
Condition3=k>k[1] and _d>_d[1] and kW>kW[1] 
and _dW>_dW[1] and k>50;
//3. 日K值和D值向上+週K值和D值向上且K值>50
Condition4=absvalue(100*(Lowest(L,LLPeriod)
-Highest(H,LLPeriod))/Highest(H,LLPeriod))<10;
//4. 144日最高與最低之幅度<10% 
Condition99=Condition1 and Condition2 and Condition3
and Condition4 ; 
// 篩選 
IF Condition99 Then Ret=1;

把這個腳本拿去回測過去七年的所有普通股，停損停利都設為7%，回測報告如下圖：

要完全符合這些條件的股票不多，只有102次交易機會，但勝率蠻高的。如果要有更多的交易次數，可以把144天這個參數往下調，不過這樣勝率及總報酬率就沒有那麼高了，需要藉由其他條件來優化它。

另一個方式是只看日KD不看週KD，也是一個作法。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

江湖上有個傳說： 如果一檔股票投信原本沒有持股，現在開始積極的買進，這檔股票就很值得留意。

我同事為了印證這個傳說，寫了一個選股策略去回測。

回測的結果發現，這樣的傳說是有它的道理，值得大家繼續發展成一個可以實戰的交易策略。

我同事寫的腳本如下：

input: v1(2000); setinputname(1, "投信估計持股上限(張)");
input: v2(300); setinputname(2, "近一日買賣超(張)");

value1=GetField("投信持股","D");
value2=GetField("投信買賣超","D");

if value1 < v1 and value2 > v2
then ret=1;

SetOutputName1("投信買賣超(張)");
OutputField1(value2);

這個腳本的意思是投信估計持股不到2000張，但最近一個交易日買進超過600張，加上收盤價低於80元的選股條件，組合成的選股策略如下：

拿這個選股策略去回測過去七年，停損停利都設為7%，回測報告如下圖：

勝率不算高，但總報酬很可觀，且交易次數超過500次，顯示這是一個積少勝為大勝的交易策略，個人非常喜歡這個策略，有興趣的朋友可以據而再優化成自己的私房秘技。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

MACD黃金交叉是大家耳熟能詳的指標訊號，我們優秀的同事發現，如果MACD黃金交叉是發生在長期盤整之後，勝率特別的高。

他寫了一個腳本，當MACD黃金交叉伴隨著：

一、過去五個交易日成交量都超過500張

二、OSC愈來愈大

三、過去144天上下震盪幅度不到10%

以下是他寫的腳本：

// 定義 
Input:SPeriod(5),LLPeriod(144); 
Input:FastLength(12),SlowLength(26),MACDLength(9); 
Var:difValue(0),macdValue(0),oscValue(0); 
// 計算 
MACD(weightedclose(), FastLength, SlowLength, MACDLength, difValue, macdValue, oscValue); 
// 條件 
Condition1=trueall(V>500,SPeriod);
//1. 連續5日成交量>500 
Condition2=oscValue>0 
and oscValue[1]<0
and oscValue[1]>oscValue[2] 
and oscValue[0]>-oscValue[1];
//2. MACD黃金交叉且OSC愈來愈大 
Condition3=absvalue(100*(Lowest(L,LLPeriod)-Highest(H,LLPeriod))
/Highest(H,LLPeriod))<10;
//3. 144日最高與最低之幅度<10% 
Condition99=Condition1 and Condition2 and Condition3 ;
// 篩選 
IF Condition99 Then Ret=1;

用這腳本去回測過去七年所有股票，停損停利都設為7%，回測報告如下：

這策略有很高的勝率，缺點就是出現的交易訊號不多，七年才出現78次，建議大家可以把144天的天期拉的近一點，例如60天或80天，這樣出來的訊號會比較多，當然勝率會降低，這時候就可以用其他的過濾條件來優化它。

例如我用80天，再加上法人買超100張，回測的結果如下：

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

我師父最常說的一句話是反常必有妖，在正常情況下，當每股的本業獲利創這幾年新高時，股價應該要有所反應，但如果這樣的公司，其股價跟淨值沒有離多遠，而且散戶還在出場，可能是這檔股票太冷，被市場遺忘了，不然就是大盤太差，泥沙俱下，如果在這樣的情況下，股價開始出量上漲，往往代表市場開始要還這公司的股價一個公道了。

我根據這樣的思維，寫了以下的選股策略：

其中用到的暴量起漲的腳本，程式碼如下：

input: Length(20); setinputname(1,"計算期數");
input: VLength(10); setinputname(2,"均量期數");
input: volpercent(50); setinputname(3,"爆量增幅%");
input: Rate(5); setinputname(4,"離低點幅度%");

settotalbar(3);
setbarback(maxlist(Length,VLength));

if Close > Close[1] and
Volume >= average(volume,VLength) *(1+ volpercent/100) and
Close <= lowest(close,Length) * (1+Rate/100)
then ret=1;

這個選股策略過去七年，停損停利都設7%的回測報告如下圖：

這是一個禁得起市場考驗的交易策略，有興趣的朋友可以研究看看。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

在最新一個月的營收公佈期，我會用最近三個月的月營收及最新一季的營業利益率，計算出單季的本業獲利，然後假設未來一年的本業獲利皆如最近這一季，據以計算出全年本業的獲利及EPS，再以這樣的EPS搭配當下的股價，計算出目前的本益比，如果本益比非常低，例如低於6倍，那麼如果這家公司的月營收不是曇花一現，那麼目前的股價就是明顯被低估。

基於這樣的想法，我寫了一個腳本如下：

value1=GetField("月營收","M")
+GetField("月營收","M")[1]+GetField("月營收","M")[2];//億
outputfield(1,value1,1,"近三月營收合計(億)");
value2=GetField("營業利益率","Q");
outputfield(2,value2,1,"營業利益率");
value3=value1*4*value2/100;
//用最近三個月的營收乘以最近一季營業利益率來估算全年本業獲利
value4=GetField("最新股本");//億
variable:FEPS(0);
FEPS=value3/value4*10;
//用這樣估算的本業獲利來算預估的EPS
outputfield(3,FEPS,2,"預估本業EPS");
if feps<>0 
then value5=close/feps;
outputfield(4,value5,"預估本益比");
input:pe(6,"預估本益比上限");
if value5<pe and value5>0
then ret=1;
outputfield(5,value4,0,"股本億元");

當然這樣計算的方式，如果碰到景氣在最高峰的個股，像是之前的航運股、鋼鐵股，就有可能被誤導，所以我加了一個關鍵券商買超的條件，組合成以下的選股策略：

過去七年，停損停利設為7%，回測報告如下圖：

這是一個一直有穩定表現，且交易次數還不少的短線策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

股價是股利的幾倍，算是合理價位？

如果一家公司，每年都配四元股利，跌到多少錢以下可以買？

是60元？ 還是40元？  60跟40差很多，我們透過【XQ量化平台】來找答案。

一個交易策略，基本上就是觀察、假設、撰寫腳本、回測、調整這五個步驟。

我觀察到，看股利不能看一年，股利有上有下，用最近一年的股利來計算合理股價，在公司表現好時容易高估，在公司景氣谷底期容易低估，所以最好用近幾年平均股利來作計算的標準。

其次，股價反映的是未來，一家獲利穩定的公司，股價跌到一定的價位，如果法人買超，代表這家公司的未來，法人買是肯定的。

我把這兩個觀察整合在一起，假設股價跌到股利的15倍且法人買超，是個好的進場時機，然後寫成了以下的腳本：

value1=(GetField("股利合計","Y")+GetField("股利合計","Y")[1]
+GetField("股利合計","Y")[2]+GetField("股利合計","Y")[3]
+GetField("股利合計","Y")[4])/5;
if close<value1*15
and getField("投信買賣超", "D")>200
and getField("外資買賣超", "D")>500
then ret=1;

這腳本取過去五年的平均股利作為評價的基礎，在股價跌破股利15倍且外資單日買超大於500張，投信買超大於200張後進場，回測報告如下：

這是一個有一定勝率，有夠多交易訊號，長期報酬率穩定向上的交易策略，有興趣的朋友可以再調整參數或加入其他過濾條件來優化這個策略。

===

● XQ【盤後量化選股模組】($1,000) 六大功能，購買就送【台股進階(原價$300)+小道瓊行情(延遲)】➤https://utm.to/48q5pr

● 首次訂閱享7天鑑賞期，首次購買輸入官方優惠碼「@XQ8899」，首月可折抵模組費用$100！

我們很常用總市值與年營收的比例，來作為企業估值的標準，例如一家公司如果一年營業額30億，那麼總市值如果遠低於30億時，我們會覺得這檔股票的股價可能被低估了，企業價值營收比是一個在這樣概念下被進一步發展出來的估值數據。

企業價值的公式是總市值+負債總額-(流動資產-應收帳款）

這數字是扣除負債及流動資產的可立即變現部份，更清楚的呈現市場對一家公司運營本身的估值，用這個數字去除以年營收，就是所謂的企業價值營收比，我把這樣的概念寫成腳本，去尋找企業價值不到營收1/5的公司

value1=getField("總市值(億)", "D");//億
value2=getField("負債總額", "Q");//百萬
value3=getField("流動資產", "Q");//百萬
value4=getField("應收帳款及票據", "Q");//百萬
value5=getField("營業收入淨額", "Y");//百萬
value6=(value1*100+value2-(value3-value4))/value5;
input:ratio(0.2,"比例上限");
if value6<ratio
and value6>0
then ret=1;
outputfield(1,value6,1,"企業價值營收比");
outputfield(2,value1,0,"總市值單位億元");
outputfield(3,value1*100+value2-(value3-value4),0,"企業價值單位百萬");
outputfield(4,value5,0,"年營收");

如果只用這個腳本去回測，停損停利設為7%，回測報告如下

長期都可以打敗大盤。

如果這樣的公司連續2日法人都買超一定張數，可能代表法人也覺得目前的估值太低了，開始進場買進

這樣可能會形成一個合適的選股策略，所以我寫了一個選股策略如下

拿這個策略去回測，回測報告如下圖

這樣的勝率及MDD，算是在可以接受的範圍

但是符合條件的交易次數太少了

所以我把連2日法人買超500張改成佔成交量10%以上，回測結果如下圖

總交易次數變多了，勝率也略高一點，但總報酬沒有比較好，MDD也變大