先前介紹我撰寫當沖腳本的流程，今天接著來跟大家介紹一些我自己最常卡關的地方，以及公司高手們的寫法範本，讓大家可以做個參考，介紹卡關的部份之前，先列出我研究過去的分時圖之後，整理的一些想要寫成腳本的敘述

1. 開盤下跌後馬上站上平盤且急拉後只回檔一兩檔即再創新高
2. 10點之後帶量突破先前的箱型盤整區，且拉回幅度不大後再創新高
3. 預估量爆增且大戶買盤成交比例很高
4. 10點之後創當日新高，也創波段新高
5. 開高後大盤下跌仍不跌且10點後創新高
6. 開盤前三分鐘有一分鐘K拉超過2%
7. 開高後長時間沒有拉回，12後創新高
8. 開盤後緩步攻堅，一底高過一底，一峰高過一峰
9. 開盤即暴量跳空突破前幾日盤整以來的高點且未拉回
10. 開高拉回後迅速創新高
11. 開盤五分鐘K棒連三紅
12. 日線盤整結束，當日開高後，底部一路愈墊愈高
13. 急拉後回檔然後再急拉創高
14. 開高後多次探底後回升
15. 開高後不拉回嚐試回補之前日線的跳空下跌
16. 開盤急拉漲勢結束後現在拉回整理幅度為漲幅的1/3
17. 沒量的股票突然暴大量急拉
18. 當天已衝過前一日的高點
19. 上攻走勢很陡之後拉回整理長期未破底
20. 開高後拉回整理後突破當日高點
21. 大跌後，開高直接跳空突破前一天高點且拉回未踫觸到前一天高點
22. 開盤大跌，但超過10分鐘沒有再破底且一直創當日新高
23. 開盤大跌但09：30之前就站回平盤
24. 早盤有急拉，雖然之後有明顯的拉回，但接下來底部愈墊愈高
25. 外盤量遠超過正水準

我在想要描述這些情況時，最常卡關的有以下的狀況，我請了公司同仁寫了範本給我參考，以下是這些範本的說明

卡關一： 在同一天裡有個值要一直累計該怎麼寫？

例如想要累計今天大買單或大賣單的成交金額或張數，想要累計外盤成交的筆數之類的，這是我們在寫極短線腳本時會常用到的，但卻不知道怎麼寫，後來我請了同事給了我一個範本，他寫的是今天大單買進超過N次的腳本

input: atVolume(100,"大單門檻");
input: LaTime(10,"大單筆數");
input:TXT("須逐筆洗價","使用限制");
settotalbar(3);
variable: intrabarpersist Xtime(0);
//計數器
variable: intrabarpersist Volumestamp(0);
Volumestamp =q_DailyVolume;
if Date> date[1] or 
Volumestamp = Volumestamp[1]
then Xtime =0; //開盤那根要歸0次數
if q_tickvolume > atVolume
//單筆tick成交量超過大單門檻
and GetQuote("BidAskFlag")=1
//外盤成交
then Xtime+=1; 
//量夠大就加1次
if Xtime > LaTime 
and close>close[1]*1.01
then 
begin
ret=1; 
Xtime=0;
end;

這個腳本可以在當個股外盤成交超過100張的次數超過10次時即發出警示訊號，這個腳本的眉角有幾個

1.宣告一個intrabarpersist的變數

關於intrabarpersist的意義及寫法，請參考這個網頁

使用這個語法，在同一根K線裡，逐筆的每個TICK帶來的新變化都會更新該K棒裡的特定宣告變數值，這麼一來，當根K棒裡每個TICK的數據都可以被累計。

2.開盤時計數器歸零的寫作技巧

variable: intrabarpersist Volumestamp(0);
Volumestamp =q_DailyVolume;
if Date> date[1] or 
Volumestamp = Volumestamp[1]
then Xtime =0; //開盤那根要歸0次數

這一段的意思是當日量沒有再增加或日期不等於前一筆的日期時，就代表是隔一日的第一筆，這時候計數器就要歸零

3.計數器的寫法

Xtime+=1這樣的寫法，其實是Xtime=Xtime+1的快速寫法，也就是符合前面if的條件時，就加1的意思。這個寫作技巧在計算分數或次數常會用到。

結合這三個撰寫的技巧，就可以在日線的計算的基礎下去累計每個tick的相關數據。

卡關二：計算開盤到現在一共是多少根bar

我們常會寫一些腳本是屬於那種要從第N根1分鐘線開始作計算的腳本，例如開盤八法是去計算前三根五分鐘線的漲跌情況，我的同事寫了一個開盤前三根都是紅K棒的腳本給我

if barfreq <> "Min" or Barinterval <>1 then RaiseRuntimeError("請設定頻率為1分鐘");
variable:BarNumberOfToday(0);
if Date <> Date[1] then
BarNumberOfToday=1
else
BarNumberOfToday+=1;{記錄今天的Bar數}
if barnumberoftoday=3 then begin
//今天第三根1分鐘K，也就是開盤第三分鐘
if trueall(close>=close[1],3)
//連三根K棒都是紅棒
and volume>average(volume[1],3)*2
//成交量是過去三根量平均量的兩倍以上
and close=highd(0)
//收最高
then ret=1;
end;

這個腳本主要是透過計數器，去計算現在是分鐘K的第幾根，可以用在不同頻率的分鐘K

另外這個腳本也示範了策略指定頻率時要怎麼寫

卡關三：從那一根開始算起，以及第一根要往前引用多少根

我在寫極短線腳本時，經常用到1分鐘線，這時候常會想要確定要拿多少跟K棒來算，以及每一根K棒是計算的第幾根，還有第一根如果要計算像十根移動平均時，必須再往前多拿九根來算，這些到底在腳本上要怎麼設，我常弄的迷迷糊糊，後來我同事就寫了一個範本給我

input:Length(100,"計算期數");
input:Ratio(0.5,"突破幅度%");
input:RRatio(1.5,"盤整區間幅度%");
input:TXT1("僅適用5分鐘線","使用限制");

settotalbar(3);
setbarback(Length);

if barfreq<> "Min" or barinterval <> 5 then return;

variable: RangeHigh(0);
variable: RangeLow(0);
RangeHigh=highest(close[1],length);
RangeLow=lowest(close[1],length);

if RangeHigh[1] < RangeLow[1] * (1+ RRatio/100) then begin
if Close crosses over RangeHigh*(1+Ratio/100)
and volume>average(volume,length)*1.5
then ret=1;
end;

這個腳本用到兩個內建函數，一個是用來設定資料讀取範圍的settotalbar，以及設定最大引用範圍的setbarback。這兩個函數的意義，可以參考這一頁

在這個腳本裡，為了要表達糾結均線，所以要拿過去100根的5分鐘K來計算，所以必須把setbarback設為100，但要觀察現在的K棒有沒有突破這糾結的均線，只要看最近幾筆，所以settotalbar設的很短。

透過這兩個函數，我們就可以框定這個腳本要從最近一根之前的第幾根bar開始計算起，然後要往前引用多少根的資料，把每根bar標示號碼之後，就可以用currentbar這個函數來表達現在要的是第幾根，例如以下的腳本是去計算加權平均值，這時候第一根必須引用收盤價作為加權平均值，所以腳本可以如下面這麼寫

if CurrentBar = 1 then
    XAverage = Close
else
    XAverage = XAverage[1] + Factor * (Close - XAverage[1])

透過Currentbar這個函數，就可以宣告要從第幾根bar開始計算，透過這三個函數，我們就可以很清楚知道要計算的這個時間序列，會從那裡開始被計算，要標定任何一根的特定數據，都可以用currentbar=n來處理，這樣我們就可以楚理這個時間序列裡的每個數據而不會對錯位置。

卡關四：設定某特定時點作為結算點

我在寫極短線腳本時，會希望設定一些特定時間的關卡點，例如09：15或是10點，是午飯時間如12：00之類的，我們同事寫了一個範本給我

input: timeline(100000); setinputname(1,"時間切算點");
input:TXT1("限用分鐘線"); setinputname(2,"使用限制");
input:TXT2("高點自開盤起算"); setinputname(3,"使用說明");
settotalbar(3);
if barfreq<> "Min" then return;
variable:RangeHigh(0);
if date <> date[1] then RangeHigh = 0;
if Time < timeline then RangeHigh = maxlist(RangeHigh,high)
else if time >= timeline and RangeHigh > 0 and Close > RangeHigh*1.005 then ret=1 ;

這個範本的概念是在10點以後，如果突破10點之前的高點就出訊號

這是用Time這個回傳值與設定一個 timeline這樣的參數來設定計算的時間區段，我用這個範本就知道怎麼處理時間的問題了

卡關五：如何在分鐘線裡引用日線的價量資料

我們在透過分鐘線描述當天走勢時，常常會想要考慮到日線對應的價量關係，例如今天盤中一分鐘線突破前一根日線高點之類的想法，這時候會希望可以在分鐘線的腳本中，引用日線的價量資料，這時候就需要用到一些語法上的小技巧，茲舉例如下

input: volumeRatio(0.1, "分鐘量暴量比例");
input: changeRatio(3, "最近3日最大上漲幅度");
input: averageVolume(1000, "5日均量");

variable:KBarOfDay(0), BreakHigh(false);

KBarOfDay+=1;
if date<>date[1] then begin
KBarOfDay=1; 
BreakHigh = false;
end; 

condition1 = KBarOfDay = 6;
//一分鐘線每天的第六根

condition2 = Countif(High > High[1] and Close > Close[1] ,5) >=3;
//近五根裡至少三根最高價比前一根高且收盤比前一根高

if KBarOfDay = 1
and close > getfield("close", "d")[1] 
//一分鐘線第一根的最新價格高於前一日的收盤價
then BreakHigh = true;
//開高

value1 = average(GetField("Volume", "D")[1], 5);
//用getfield語法來取得過去五天成交量再作移動平均
//五日均量

condition3 = value1 > averageVolume;
//五日均量大於某張數

value2 = rateofchange(GetField("Close", "D")[1], 3);
condition4 = AbsValue(value2) < changeRatio;
//前三日漲帳幅小於一定標準

condition5 = summation(volume, 5) > value1 * volumeRatio;
//前五根一分鐘線成交量的合計大於五日均量某個比例

if condition1 and condition2 and condition3
and Condition4 and Condition5 
and BreakHigh
then ret=1;

這個腳本裡跑的是一分鐘線，主敘述是近幾天整理格局的股票，開盤跳空上漲且五分鐘內到少三次創新高，且成交量增加，這裡必須用日線來描敘跳高，計算五日均線，以及描敘過去幾點基本上屬於盤整格局，這些都是需要用到日線，這個樣本透過 getfield語法，在1分鐘線裡，大量的使用日線的收盤價及成交量來協助運算。

卡關六：如何撰寫突破盤中整理時高點的腳本？

我在描繪分時圖盤整後突破高點時，不知道要怎麼寫才合適？ 同事給了我一個範本如下

input:HitTimes(3,"設定觸頂次數");
input:RangeRatio(1,"設定頭部區範圍寬度%");
input:Length(20,"計算期數");

settotalbar(Length + 3);

variable: theHigh(0);
theHigh = Highest(High[1],Length); 
//找到過去其間的最高點
variable: HighLowerBound(0); 
HighLowerBound = theHigh *(100-RangeRatio)/100;
// 設為瓶頸區間上界
variable: TouchRangeTimes(0); 

//回算在此區間中 進去瓶頸區的次數 
TouchRangeTimes = CountIF(High[1] > HighLowerBound, Length);

if TouchRangeTimes >= HitTimes and close > theHigh then ret=1;

這個腳本是用來描繪在分鐘線下底下，一段時間以來，多次股價有上攻到高點附近但都拉回，最後則順利站上新高點的腳本，這個腳本的做法是先把高點標示出來，然後畫出一塊高原區，只要股價有進到高原區就算一次上攻，然後如果先前有進攻三次以上，就算是多次上攻。

以上是我在撰寫分鐘線腳本時所踫到的一些卡關的地方，以及語法上對應的寫法樣本，祝大家都能順利寫出自己的想法。

我先前寫過不少大跌後抄底的腳本，這次武漢肺炎所帶來的急跌，朋友們最想知道的就是跌下來要買那一檔？ 我想整理這些腳本，找出其中勝率較高的，來跟大家介紹。

一，大跌後的主力回頭收集

這個腳本的想法是如果股價這二十天到三十天有一定的跌幅，但在這段時間內，分公司賣出家數愈來愈多，分公司買進家數愈來愈少，代表有特定買盤趁著大跌在默默吸納籌碼。

我寫的腳本如下

input:period(20);
value1=GetField("分公司賣出家數")[1];
value2=GetField("分公司買進家數")[1];

if linearregslope(value1,period)>0
//賣出的家數愈來愈多
and linearregslope(value2,period)<0
//買進的家數愈來愈少
and
close*1.05<close[period]
//過去一段時間股價在跌
and close*1.25<close[30]

then ret=1;

二，大跌後的低檔五連陽

這個策略是去尋找長期下跌，近期跌勢加遽，但最近五天收盤都大於開盤的股票

對應的腳本如下

 if trueall(close>open,5) 
and close*1.4<close[90]
and close*1.2<close[20]
then ret=1;

三，大跌後的價量背離

這個策略是去尋找大跌且近期急跌後，近十個交易日價量背離的股票

input:period(10);
input:times(5);
if close[1]*1.4<close[90]
and close*1.2<close[30]
and countif(c>c[1]xor v>v[1],period)
>=times
and close=highest(close,period)
then ret=1;

四，大跌後的長黑後長紅

這個腳本是去尋找那些大跌之後，加速趕底後，出現長紅的股票

if close*1.4<close[90]
and close*1.2<close[20]
then begin
if close[1]*1.05<close[2]
and close>1.05*close[1]
then ret=1;
end;

五，大跌後出現長下影線

這是去尋找大跌後，近三天出現至少一根長下影線的股票

input: Percent(1.5,"下影線佔股價絕對百分比");
settotalbar(5);
condition1 = (minlist(open,close)-Low) > absvalue(open-close)*3; 
//下影線的長度是實體的三倍以上
condition2 = minlist(open, close) > low* (100 + Percent)/100;
if countif( condition1 and condition2, 5)>=1
and close[20]> close*1.25
and close[90]>close*1.4
then ret=1;

六，大跌後的急拉

這個腳本是去尋找大跌且股價很久沒有上漲超過6%的股票

value1=barslast(close>=close[1]*1.06);
if value1[1]>50
//超過50天沒有單日上漲超過6%
and value1=0
//今天上漲超過6%
and average(volume,100)>500
and volume>1000
and close[1]*1.25<close[50]
//過去50天跌幅超過25%
then ret=1;

七，大跌後的第一次突破月線

這個腳本是股價大跌後，去尋找股價離低點沒有很遠，且股價近期以來第一次突破月線的標的

input:period(90,"計算區間");

value1=highest(high,period);
value2=lowest(low,period);
if value2*1.3<value1
and close<value2*1.07
and barslast(close cross over average(close,22))=0
and barslast(close cross over average(close,22))[1]>30

then ret=1;

以上這七個策略的勝率都接近六成，大家也可以根據這些樣本， 發展出自己的大跌後對應策略，祝大家在驚濤中都能乘風而行。

推荐碼@XQ8899

XQ全球贏家下載連結

XQ超人氣加值模組介紹

XQ手機版支援下單

XQ量化交易平台學習地圖

統一證券開戶連結

群益金鼎證券開戶連結

華南永昌開戶連結

XS提供了一些籌碼相關的欄位，我運用這些欄位，寫過不少交易策略，今天就來跟大家分享一個最近寫的指標 。

之前有跟大家聊過關鍵券商，地緣券商，官股券商及前十大綜合券商總公司的意義，這些都是屬於長線的力量，再搭配外資，投信及非套利的自營商買賣超，應該可以代表一檔股票長線的買賣力道，我把這些力量加總起來，組合成一個長線客買賣超張數指標，以下是這個指標的腳本

value1=GetField("關鍵券商買賣超張數","D");
value2=GetField("地緣券商買賣超張數","D");
value3=GetField("外資買賣超張數");
value4=GetField("投信買賣超張數");
value5=GetField("自營商自行買賣買賣超");
value6=GetField("官股券商買賣超張數","D");
value7=GetField("綜合前十大券商買賣超張數","D");
value8=value1+value2+value3+value4+value5+value6+value7;
plot1(value8,"長線客買賣超張數");

我把這個指標拿來跟K線圖對照，我發現，這個指標對於中小型電子股有不錯的參考意義，以下是幾個例子

我把這個腳本改成選股腳本，找出當日長線買盤佔成交量一成以上的股票

我所寫的腳本如下

value1=GetField("關鍵券商買賣超張數","D");
value2=GetField("地緣券商買賣超張數","D");
value3=GetField("外資買賣超","D");
value4=GetField("投信買賣超","D");
value5=GetField("自營商自行買賣買賣超","D");
value6=GetField("官股券商買賣超張數","D");
value7=GetField("綜合前十大券商買賣超張數","D");
value8=value1+value2+value3+value4+value5+value6+value7;
input:ratio(10,"長線買盤佔百分比");
if volume<>0 then value9=value8/volume*100;
if value9>=ratio and volume>2000
then ret=1;
outputfield(1,value9,2,"長線買盤佔比");

以昨天的數據來跑，這個比例最高的的股票如下

謹供大家參考。

今天來跟大家介紹一個很典型的成長股交易策略，這個策略的概念是當最新一季的營業利益，毛利率及營業利益率都創近幾年來的新高，且技術面出現暴量起漲時就進場買進。大家別小看這個很老生常談的想法，實際回測下來，這個策略過去五來的勝率快逼近75%，是屬於四戰三勝的夢幻型交易策略。

選股策略

警示策略

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

這裡用的策略是大家應該已經看過很多遍的暴量剛起漲

回測報告

二年的回測報告

五年的回測報告

這個策略的交易次數不多，平均一年大約11-12次，一個月差不多一次，但表現比台灣50還好，年報酬在15-20之間，這代表當基本面出現明顯的好轉，且技術面也的確看到市場競逐的跡證，就很值得我們留意了。

這是一個基本面與技術面合作的例子，跟大家分享。

[ xqlite/]

前兩天跟大家介紹我使用XS的方法，透過這樣的決策架構，我每天作功課的時間，就會聚焦在高勝率策略的開發，所以會漸漸的累積出一些勝率還不錯的交易策略，今天來跟大家介紹一個長期勝率蠻高（有七成)，這兩年績效穩定的交易策略，這個策略是透過選股平台挑出股價距離合理價位很遠的股票，然後當這股票出現暴量起漲時進場。

這個策略的選股腳本如下

variable: idx(0), t(0);
input:r1(3, "假設未來十年營業利益年成長率");
input:r2(2, "未來十年平均年利率");
input:r3(100, "未來獲利折現合計淨值與市價比");

// 計算未來10年的營業利益折現值

value1=GetField("營業利益","Y"); //單位:百萬
value2=GetField("最新股本"); //單位:億
value3=GetField("每股淨值(元)","y");

value11 = maxlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);
value12 = minlist(GetField("營業利益","Y"),GetField("營業利益","Y")[1],GetField("營業利益","Y")[2],GetField("營業利益","Y")[3],GetField("營業利益","Y")[4]);

if trueall(value1>0,5) and (value11-value12)/value11<0.5 then begin
t = 0;
for idx =1 to 10 begin
t = t + value1 * power(1+r1/100,idx)/power(1+r2/100,idx);
end;

// t=百萬,value2=億,換成每股
value5 = t / value2 / 100;
value6=close/(value3+value5);

if value6<r3/100
then ret=1;
end;

outputfield(1, value5, 2, "估算每股營業利益");
outputfield(2, value6, 1, "市價/淨值比", order := -1);

這個選股腳本是先找出過去五年本業都獲利且五年裡的最高獲利與最低獲利的差異沒有很大，然後拿最新的營業利益當計算基礎 ，假設未來十年每年獲利都成長3%，然後用2%的利率當折現值，這樣計算出股票的合理價位，再跟市價去比，找出目前價值被低估的股票。

搭配的盤中洗價腳本如下

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

這個組合出來的策略在過去兩年的回測報告如下

這個策略的概念我用過很多次~ 價值被低估的股票開始絕地大反攻。差別只是評價方式的差別及對於絕地大反攻的價量定義。

這樣概念所寫出來的策略，我有不少勝率都不錯，所以把這樣的概念推荐給大家，祝大家找到績效比這個腳本更好的相關策略

為了滿足單筆基金投資者的需求，Moneydj有做了一個策略雷達的功能，透過一些策略腳本，去尋找未來可能最有漲升潛力的基金類別，今天就來跟大家介紹這項服務。

這個服務是在Moneydj自主理財這個功能裡頭，

點選自主理財之後，會看到下面這個畫面

最上方那一排第二個就是策略雷達，點選後，再左欄選勝率超過60%，會看到如下頁的畫面

這一頁就會列出近十日那些市場，有那些高勝率的策略出現買進訊號

以上圖為例，能源，特別是全球乾淨能源，在十天前，同一天有三個勝率超過六成的策略都出現買進訊號，下圖是從十天前到現在的全球乾淨能源ETF的淨值走勢

這個例子跟大家說的是，透過基金策略雷達，我們可以找到高勝率策略，近十天裡出現買進訊號的股票

如果不止一個高勝率策略出現買進訊號，那後市看漲的機率就更高了

這個功能是免費的，提供給單筆基金投資人作參考。

我寫過很多交易策略，有兩大類型勝率比較突出，一類是最低估的股票開始出量，另一類就是好公司暴量起漲，什麼是好公司呢？ 我寫過一些不同的衡量標準，今天來跟大家介紹的是其中一種標準，這種標準搭配暴量起漲的腳本，出現的交易次數雖然不多，但勝率還可以。

一，選股標準

我用的選股標準條件還蠻多的

這裡我主要是去找那些各種因子都符合的個股

二，進場腳本

這裡用的還是常用的暴量起漲的腳本

 Input: day(60,"日期區間");
Input: ratioLimit(14, "區間最大漲幅%");

Condition1 = H=highest(H,day);
//今日最高創區間最高價

Condition2 = V=highest(v,day);
//今日成交量創區間最大量

Condition3 = highest(H,day) < lowest(L,day)*(1 + ratioLimit*0.01);
//今日最高價距離區間最低價漲幅尚不大

if Condition1 And Condition2 And Condition3
then ret=1;

兩個搭配下來，回測報告如下

這裡用的停損停利都設為7%

兩年裡只有十一次的交易次數

對這種策略制定方向有興趣的朋友，可以自行修改選股及觸發腳本，但基本概念： 好公司+價量表現突出，是制定高勝率策略的一個不錯方向。