Author Archives: 發財橘子

前天跟大家分享了盤中大戶即時買賣超的警示腳本，然後在文中提到說現在盤中是無法畫出指標的，這句話敝公司的天才工程師們很不服氣，抗議說分時圖是畫不出來沒有錯，但分鐘K是畫的出來的（以為我不知道哦，我只是寫不出來而己)，結果其中一位天才就直接把它寫出來了，今天就來跟大家分享這個分鐘K版的即時大戶散戶買賣超指標

先跟大家分享這個指標腳本

input:
bos(true,"類別",inputkind:=dict(["大戶",true],["散戶",false]),quickedit:=true),
p(100,"大戶門檻(萬元)");
variable:i(0),tv(0),tp1(0),tp(0);

i=0;
if date<>date[1]
then begin
value1=0;
value2=0;
end;
if V>0
then begin
while GetField("時間","Tick")[i]>=time and GetFieldDate("成交量","Tick")[i]=date
i+=1;
while i>0
begin
i-=1;
tv=GetField("成交量","Tick")[i];
tp=GetField("收盤價","Tick")[i];
tp1=GetField("收盤價","Tick")[i+1];
condition1=0.1*tv*tp>=p;
if tp>tp1 
then begin
condition2=true;
condition3=false;
end;
if tp<tp1
then begin
condition2=false;
condition3=true;
end;
if condition1 
then begin
if condition2 then value1+=tv;
if condition3 then value1-=tv;
end
else begin
if condition2 then value2+=tv;
if condition3 then value2-=tv;
end;
end;
end;

if bos then value3=value1 else value3=value2;


if value3>=0 then plot1(value3,"大戶買賣超");
if value3<0 then plot2(value3,"大戶買賣超");
if not bos
then begin
setplotlabel(1,"散戶買賣超");
setplotlabel(2,"散戶買賣超");
end;

這個指標腳本在計算上請在技術分析設定的第一個視窗底下，作如下圖的設定，不然會算很久線都出不來

這個指標在一分鐘K頻率下，畫出來的圖如下

也可以用五分鐘K

其實只要是分鐘K都能用

在應用上，可以挑那些大戶持續買超但散戶是賣超的公司

但要小心大漲後，散戶買但大戶賣超的股票

以上是在分鐘K底下所呈現的大戶及散戶買賣超指標

公司高手如雲，我應該負責許願就好，各位有什麼想寫寫不出來的，不要客氣，儘管提出來，這些人對於我說寫不出來的，都非常有意願想化不可能為可能，大家儘管提。

由於預估量對當沖操作者很重要，一直有使用者來信詢問我們系統內建預估量的計算方法，也有不少熱心的使用者建議了一些演算方式。我們目前系統內建的演算法是依過往每分鐘成交量分佈比重，然後從當天的累計量去估算預估量，這樣的作法大家意見不大，但對於要拿多少天的歷史資料去估算成交量分佈情況，大家的意見差很多，我們公司的高手高高手，索性公開預估量的計算腳本，並且把成交量分佈比重究竟要拿多少天的歷史資料去估算，設成參數讓使用者自行來設計，這樣一來，大家就可以很容易的透過調整參數的方式，找到自己認為最貼近事實的估計量

這個估計量的腳本如果作成指標，其腳本如下

//
// 參數: 統計天期(N)
// 繪製: 當日估計成交量
//
// 支援任何頻率(分鐘/日)
//
// 計算方式: 依照過去N日, 每日1分鐘累計成交均量(統計天期平均), 算出每分鐘累計成交量的分佈比例, 
// 然後依照目前的累計日成交量以及分佈比例, 推算當日收盤估計成交量
//

input: length(5, "統計天數");

variable: BARPERDAY(270); // 1分鐘bar每一天270筆

array: arr_minvolume[](0); // (過去N日)每日每分鐘累計: 共length * 270筆
array: arr_minvolume_percent[270](0); // (平均)每分鐘累計成交量比例: 共270筆
array: arr_avg_minvolume[270](0); // (平均)每分鐘累計成交量: 共270筆

variable: _i(0), _j(0), _k(0);
variable: _totaldays(0);
variable: _lastdate(0);

Array_SetMaxIndex(arr_minvolume, length * 270);

{
print(text(
"currentbar=", numtostr(currentbar, 0), 
",date=", numtostr(date, 0), 
",time=", numtostr(time, 0),
",lastdate=", numtostr(_lastdate, 0),
",totaldays=", numtostr(_totaldays, 0)
));
}

if _lastdate = 0 then begin
// 跳過第一個不滿一天的資料
if barfreq = "Min" and time = 090000 then
_lastdate = date
else begin
// 日線的話則從20190101才開始算
if date >= 20190101 then
_lastdate = date;
end; 
end;

if _lastdate <> 0 and date <> _lastdate then begin
_lastdate = date;
_totaldays = _totaldays + 1;
if _totaldays >= length then begin
// 計算過去N天的成交量分佈
//
// 因為我可能跑在不同頻率上, 所以要先算出過去N日'1分鐘'資料的起點跟終點
//
variable: _start(0), _end(0), _startdate(0), _accvolume(0);

_end = 1;
while getfield("time", "1")[_end] <> 132900 begin
_end = _end + 1;
end;

_start = _end + BARPERDAY * length - 1;

// _start = 統計日期第一日第一筆1分鐘資料的位置
// _end = 統計日期最後一日最後一筆1分鐘資料的位置
//

// arr_minvolume[]: 儲存過去N天, 每一分鐘的日累積成交量
// arr_minvolume[1] = 09:00, 
// arr_minvolume[2] = 09:01
// arr_minvolume[271] = 第二天09:00
// ..
_startdate = getfield("date", "1")[_start];
_accvolume = 0;
for _i = _start downto _end begin
if _startdate <> getfield("date", "1")[_i] then begin
// 換日
_accvolume = 0;
_startdate = getfield("date", "1")[_i];
end;
_accvolume += getfield("volume", "1")[_i];
arr_minvolume[_start - _i + 1] = _accvolume; // 當日累積volume
end;

// arr_avg_minvolume[]: 每一分鐘的日平均累積成交量
//
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = 0;
for _i = 1 to length begin
arr_avg_minvolume[_j] += arr_minvolume[_j + (_i - 1) * BARPERDAY];
end; 
end;
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = arr_avg_minvolume[_j] / length;
end;

// arr_minvolume_percent[]: 每一分鐘的日平均累積成交量%
//
for _j = 1 to BARPERDAY begin
arr_minvolume_percent[_j] = arr_avg_minvolume[_j] / arr_avg_minvolume[BARPERDAY];
end;

{
print(text(
"main-date=", numtostr(date, 0), ",",
"main-time=", numtostr(time, 0), ",",
"start=", numtostr(_start, 0), ",",
"end=", numtostr(_end, 0), ",",
"startdate=", numtostr(getfield("date", "1")[_start], 0), ",", numtostr(getfield("time", "1")[_start], 0), ",",
"enddate=", numtostr(getfield("date", "1")[_end], 0), ",", numtostr(getfield("time", "1")[_end], 0), ","
));

for _i = 1 to 270 begin
print(text(
numtostr(_i, 0), "=", 
numtostr(arr_minvolume_percent[_i] * 100, 2))); 
end; 
}
end;
end;

if _totaldays >= length then begin
// 如果已經有分佈資料了, 則計算估計成交量
//
variable: _estvolume(0);
variable: _timeindex(0);
variable: _time(0), _v(0);

// 算出目前時間應該是1~270的哪一筆
// 分鐘線的話就用bar的時間
// 日線的話, 如果是歷史日線, 就用收盤時間估算, 如果是最後一天(盤中日線), 用目前時間估算
//
if barfreq = "Min" then
_time = time
else begin
if date < currentdate then
_time = 132900
else 
_time = currenttime;
end;
_timeindex = floor(timediff(_time, 090000, "M")) + 1;
_timeindex = minlist(_timeindex, 270);
_timeindex = maxlist(1, _timeindex);

// 預估量 = 累計到目前的日成交量 / 這個時間點之前所佔的日成交量%
//
_v = GetField("volume", "D");
if arr_minvolume_percent[_timeindex] > 0 then
_estvolume = _v / arr_minvolume_percent[_timeindex]
else
_estvolume = 0;

plot1(_estvolume, "預估量");
end;

我也試著把這個預估量的腳本寫成函數

input: length(numericsimple);

variable: BARPERDAY(270); // 1分鐘bar每一天270筆

array: arr_minvolume[](0); // (過去N日)每日每分鐘累計: 共length * 270筆
array: arr_minvolume_percent[270](0); // (平均)每分鐘累計成交量比例: 共270筆
array: arr_avg_minvolume[270](0); // (平均)每分鐘累計成交量: 共270筆

variable: _i(0), _j(0), _k(0);
variable: _totaldays(0);
variable: _lastdate(0);

Array_SetMaxIndex(arr_minvolume, length * 270);

{
print(text(
"currentbar=", numtostr(currentbar, 0), 
",date=", numtostr(date, 0), 
",time=", numtostr(time, 0),
",lastdate=", numtostr(_lastdate, 0),
",totaldays=", numtostr(_totaldays, 0)
));
}

if _lastdate = 0 then begin
// 跳過第一個不滿一天的資料
if barfreq = "Min" and time = 090000 then
_lastdate = date
else begin
// 日線的話則從20190101才開始算
if date >= 20190101 then
_lastdate = date;
end; 
end;

if _lastdate <> 0 and date <> _lastdate then begin
_lastdate = date;
_totaldays = _totaldays + 1;
if _totaldays >= length then begin
// 計算過去N天的成交量分佈
//
// 因為我可能跑在不同頻率上, 所以要先算出過去N日'1分鐘'資料的起點跟終點
//
variable: _start(0), _end(0), _startdate(0), _accvolume(0);

_end = 1;
while getfield("time", "1")[_end] <> 132900 begin
_end = _end + 1;
end;

_start = _end + BARPERDAY * length - 1;

// _start = 統計日期第一日第一筆1分鐘資料的位置
// _end = 統計日期最後一日最後一筆1分鐘資料的位置
//

// arr_minvolume[]: 儲存過去N天, 每一分鐘的日累積成交量
// arr_minvolume[1] = 09:00, 
// arr_minvolume[2] = 09:01
// arr_minvolume[271] = 第二天09:00
// ..
_startdate = getfield("date", "1")[_start];
_accvolume = 0;
for _i = _start downto _end begin
if _startdate <> getfield("date", "1")[_i] then begin
// 換日
_accvolume = 0;
_startdate = getfield("date", "1")[_i];
end;
_accvolume += getfield("volume", "1")[_i];
arr_minvolume[_start - _i + 1] = _accvolume; // 當日累積volume
end;

// arr_avg_minvolume[]: 每一分鐘的日平均累積成交量
//
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = 0;
for _i = 1 to length begin
arr_avg_minvolume[_j] += arr_minvolume[_j + (_i - 1) * BARPERDAY];
end; 
end;
for _j = 1 to BARPERDAY begin
arr_avg_minvolume[_j] = arr_avg_minvolume[_j] / length;
end;

// arr_minvolume_percent[]: 每一分鐘的日平均累積成交量%
//
for _j = 1 to BARPERDAY begin
arr_minvolume_percent[_j] = arr_avg_minvolume[_j] / arr_avg_minvolume[BARPERDAY];
end;

{
print(text(
"main-date=", numtostr(date, 0), ",",
"main-time=", numtostr(time, 0), ",",
"start=", numtostr(_start, 0), ",",
"end=", numtostr(_end, 0), ",",
"startdate=", numtostr(getfield("date", "1")[_start], 0), ",", numtostr(getfield("time", "1")[_start], 0), ",",
"enddate=", numtostr(getfield("date", "1")[_end], 0), ",", numtostr(getfield("time", "1")[_end], 0), ","
));

for _i = 1 to 270 begin
print(text(
numtostr(_i, 0), "=", 
numtostr(arr_minvolume_percent[_i] * 100, 2))); 
end; 
}
end;
end;

if _totaldays >= length then begin
// 如果已經有分佈資料了, 則計算估計成交量
//
variable: _estvolume(0);
variable: _timeindex(0);
variable: _time(0), _v(0);

// 算出目前時間應該是1~270的哪一筆
// 分鐘線的話就用bar的時間
// 日線的話, 如果是歷史日線, 就用收盤時間估算, 如果是最後一天(盤中日線), 用目前時間估算
//
if barfreq = "Min" then
_time = time
else begin
if date < currentdate then
_time = 132900
else 
_time = currenttime;
end;
_timeindex = floor(timediff(_time, 090000, "M")) + 1;
_timeindex = minlist(_timeindex, 270);
_timeindex = maxlist(1, _timeindex);

// 預估量 = 累計到目前的日成交量 / 這個時間點之前所佔的日成交量%
//
_v = GetField("volume", "D");
if arr_minvolume_percent[_timeindex] > 0 then
_estvolume = _v / arr_minvolume_percent[_timeindex]
else
_estvolume = 0;
destvolume=_estvolume;
end;

利用這個Destvolume的函數，我們就可以寫出預估量比五日均量增加N%的警示腳本

input:day(10,"預估量估算期間");
input:period(20,"均量計算期間");
input:ratio(80," 暴量比例");
if destvolume(day) crosses over average(volume,period)*(1+ratio/100)
and close>close[1]*1.01
then ret=1;

至於預估量的成交量分配要用過往幾天的值來估算，我個人偏向於不要太長，因為太長要計算的時間很久，而且跟目前的交易實況可能會有落差。

以上是預估量的計算腳本大公開

有不同想法的朋友也可以再提出來

大家的目標都是想要把預估量計算的愈來愈貼近實際量

上次跟大家分享的選股常用語法大匯總，得到不少使用者的迴響，也提了一些希望可以加上去的常用語法，這些語法有價量型的，有技術指標類的，籌碼類的也不少，我今天就先跟大家分享價量類的。

大家希望加進去的價量類的腳本，我整理了一下，我寫得出來的，一共有21個，名稱如下圖

這些腳本的下載連結

下載後在選股中心點選匯入後即可以把這些腳本匯進來

這些腳本都是使用者覺得很常用到的，例如想要找出近幾日從最低點上漲超過一定幅度的股票時，就可以用N日自低檔上漲M%這個腳本

至於詳細的使用介面，在上一篇時有介紹，請參考

接下來會再陸續把關於籌碼面，技術指標類等等的使用者建議加上的常用腳本分享給大家

容我再整理一下

在美股隊長操作秘笈這本書裡，有提到一個概念：指數見底時，率先上漲及創新高的類股，往往就是下一波的強勢族群。目前在XQ全球贏家美股版中，有提供道瓊中產業指數，我運用這組報價組合，配合書上介紹的相對強勢概念，設了一個類股輪動的觀察頁面。

這個頁面的樣式如下：

頁面的下載點如下

連結

RS的腳本如下

input:preiod(20,"RS移動平均線計算期別");
value1=GetSymbolField("GSPC.FS","收盤價","W");
variable:rss(0);
variable:rssav(0);

if value1<>0 then rss=CLOSE/value1;
rssav=average(rss,10);
plot1(rss,"美股RS指標");
plot2(rssav,"移動平均");

這裡用的比較商品是用S&P500指數。

目前道瓊中產業指數裡約有184個不同的行業指數，其中跟台灣比較有產業連動的，包括輪胎，汽車零件，半導體，服裝零售業，傢俱，海運，化工，科技硬體與設備，基本原料，航太與國防，鞋業，電腦硬體，紙業，消費電子等產業。

有興趣的朋友可以下載這一頁來監控美股產業的輪動

人人都是巴菲特專案

前兩天跟大家介紹了相對強勢指標RS，今天我想跟大家介紹這個指標在尋找強勢類股的應用上。

首先來復習一下RS的計算公式： A商品收盤價/B商品收盤價。

如果要看類股指數的相對強勢，那就是用類股指數/加權指數

根據這樣的公式，寫出對應的指標腳本如下

input:preiod(20,"RS移動平均線計算期別");
value1=GetSymbolField("TSE.TW","收盤價","D");
variable:rss(0);
variable:rssav(0);

if value1<>0 then rss=CLOSE/value1;
rssav=average(rss,10);
plot1(rss,"RS指標");
plot2(rssav,"移動平均");

用這個腳本，可以設計出像下面這樣的頁面，在盤中可以找到當天轉強的類股，然後馬上看看這類股的相對強度目前處於什麼位置。

這一頁的載點，要記得必須有產業模組的權限才能使用

我們來看看今天很強的幾個類股

我們會發現，當 RS指標突破均線且開始拉大與均線的差距，且成交量也同步放大時，這個產業往往後市有可能成為新的主流類股。

我根據這樣邏輯，也挑了幾類剛冒出來沒有多久的類股給大家參考。

以上是RS在產業輪動上的應用

最近市場比較悶，有點山雨欲來風滿樓的氛圍，加上摩根史坦利有看壞全球股市，連帶的開始有些投資人開始偏向空方，美國ETF市場中，有大量的反向型ETF，適合在看壞某特定市場時用來交易，今天就來跟大家介紹我自己會留意的一些反向型ETF

在挑反向型ETF上，主要考量的不外乎交易成本，流動性及指數追蹤能力等這幾項

我常觀察的反向型ETF如下

這個頁面的下載位置如連結

如上圖裡，目前看壞美國股市，債市，看壞美元，都有反向型的ETF

另外，看壞日本，歐洲，中國，俄羅斯及巴西等地股市，也有對應的ETF

乃至於看壞原油及黃金，也有對應的ETF

在這一頁裡，我有把基金規模，折溢價率及總管理費也列了出來，反向型的ETF，管理費通常會高一點，所以大家才說作反向型ETF最好是主跌段再出手，其中一個就是擔心管理費成本高，不適合持久消耗戰。

這邊我沒有放VIX反向，原因是這商品一般投資人不是很能理解，加上一不小心會虧到吐血，所以我就不放了。

此外，我個人的作法通常是覺得要跌了先小玩放空一倍的，確定主跌段了再換成兩倍的，三倍的我是沒有作過，我是膽小鬼。

有了反向型ETF，當我們確定那一個市場的趨勢明確時，多空都有投資的管道。

最後容我工商服務一下，請來參加人人都是巴菲特專案，只要在指定券商開戶下美股，即可享受XQ操盤高手美股即時報價的免費服務。

昨天跟大家介紹如何運用中信亮點APP來選股，文中有提到這個APP內建了不少常用的選股條件，那如果您想要用的條件 不是常用的，是您獨自創獲的見解呢？ 正常來說，可能需要在XQ操盤高手的選股平台裡寫程式，但正所謂英雄所見略同，我既然已經寫了不少選股條件，可能有一些就是您想要寫出來的，所以我就把這些寫過的分享出來，讓大家可以直接匯入後拿來用就行了。

這次分享的常用的選股條件有如下表，我整理了一下大約有58個

這是這些腳本的下載點

請下載後到選股中心匯入即可使用

怎麼用呢？

下面是一個示意圖

未來我一段時間會整理一批新的常用選股腳本，讓大家可以匯入來使用，各位如果覺得有什麼選股條件想要用程式寫出來的，也可以來許願，我是魯肉腳，但我臉皮厚，寫不出來的我會去廬我們的歹命工程師

網友來信問到相對強度的計算方法及應用，這個方法其實單純，就是兩個商品相除後的時間序列，市場常用來研判兩檔不同股票間的消長，像是股債的相對強弱度，有時是用來留意資金流向的變化，有時則是用來了解兩家同業的市場認同度消長。今天我就來跟大家介紹這個簡單但實用的指標。

相對強度的計算方式很單純，就是把商品A的收盤價除以商品B的收盤價，在XS的語法上，可以寫去指標如下

input:symbol1("","主商品代碼");
input:symbol2("","比較商品代碼");
value1=GetSymbolField(symbol1,"收盤價","D");
value2=GetSymbolField(symbol2,"收盤價","D");
var:rss(0);
var:rssav(0);

if value2<>0 then rss=value1/value2;
plot1(rss,"RS相對強度指標");

有了這個指標，只要輸入兩個不同的商品，就可以算出兩者的相對強度，以OTC指數對應加權指數的相對強度指標為例，設定的畫面如下

然後就會出現像下面這樣的圖

我自己最常用這個指標來計算otc與加權指數的相對強度，因為我有觀察到，大盤空頭市場的末期，otc往往會比大股票要先止跌甚至有表現，像是以下幾張圖都可以看到有類似的情況

這個最常被應用來看兩檔同行業股票間的強弱消長

例如下面這張圖是統一超商的股價與全家的相對強度

從上面這張圖可以明顯感覺到，在2018年8月之前，統一超的人氣是高於全家，但在那之後，情勢就有了很大的改變。

以上是相對強度的概念，在應用上，未來還有一些值得跟大家介紹的，我會另為再跟大家說明。