Author Archives: 發財橘子

我的前老板錢太多沒處放，台幣利率又低，讓我挑幾檔可以拿來每年分點股利又能保本的股票來投資，他要的報酬率不高，年報酬五%就可以接受。為了達成任務，我把1000多檔股票用一些條件濾了一遍，最後給了他一些名單。在這過程中我發現，市場上不少的存股概念，好像太複雜了，我認為，挑定存股就是三原則:獲利穩定，配息穩定，會填息。然後就是等每年股票市場大跌後，開始分批買進。

這幾年，可能是台幣利率太低的關係，定存股的概念愈來愈受重視，我看到這類相關文章的時候，發現很多的觀念，例如要看ROE，ROA，要看自由現金流量等等的，這些都超過一般人的能力範圍，當然多學一點不是壞事，但怕的是學太多沒有聚焦反而無法挑到對股票。

我這次在挑定存股的過程，試了一些方法，最後回頭仔細比對後，我覺得以下的幾個重點才是直指核心，最能挑出安心定存股的

1.長期穩定股利，且獲利每年都達到一定水準

2.長期營運不曾有大衰退

3.董監事持股超過一定水準

所以我先寫一個腳本來找出過去五年每年現金股利最少兩元，而且最近四季稅後淨利超過兩億元台幣的公司。

以下是這個腳本的內容

input:p1(2,"現金股利下限");
input:period(5,"符合條件的連續年數");
condition1=false;

value1=GetField("現金股利","Y");
if trueall(value1>=p1,period) or trueall(value1[1]>=p1,period)
then condition1=true;

value2=GetField("本期稅後淨利","Q");//單位:百萬
value3=summation(value2,4);

if value3>200
then condition2=true;

if condition1 and condition2
then ret=1;

符合這個腳本條件的股票有140檔，名單如下:

接下來再從這140檔當中，濾掉那些過去幾年曾經有較大衰退的公司，所以我在上面提到的那個腳本中，再加上下面的濾網:

condition3=false;

value4=GetField("營業利益成長率","Y");
if countif(value4<-15,period)=0
then condition3=true;

if condition1 and condition2 and condition3
then ret=1;

這個濾網的意思就是濾掉那些過去幾年曾經有任何一年獲利衰退超過15%以上的公司，加上這個濾網，我們濾到只剩63檔股票。

接下來我再設了一個濾網: 董監事持股比例超過15%。加了這個條件之後，符合的股票再被濾掉 23檔，剩39檔，名單如下:

最後我再設一道濾網，濾掉那些短期業績明顯在衰退的，我設的條件是濾掉那些近半年月營收年增率平均衰退超過5%的。經過這個過濾的方式後，再濾掉八家，剩31家，名單如下:

這三十一檔就是在大盤大跌後，我覺得可以加入定存股名單的股票，當然這個名單在每個月月營收公佈後，都需要用最後一個濾網再重跑一次。

過去一年，加權指數跌了13%，這31檔股票有19檔的年報酬率是維持在零以上，表現比加權指數差的只有川湖，天仁，景碩，聯強及美利達這四檔，可見這樣的投資組合至少是會打敗大盤的。

綜合以上的說明，我的存股法條件就是以下三條

第一條是用XS腳本寫的，第二條及第三條都是透過系統內建的條件式，只是調整參數而已。

以上就是我的存股法SOP，邏輯單純: 每年都會配息，業績長期不衰退，董監持股不低，最近半年業績沒有大衰退。

想知道今年以來，漲幅大的是什麼類型的股票，順手寫了一個區間漲跌幅的自訂函數，也就野人獻曝，順便跟大家分享寫自訂函數腳本時，要留意的事。每年年初我極愛看漲多的股票是那些，因為以前我師傅說可以從這些股票看出今年的選股方向。從這些股票來看，感覺今年是中小型股個股表現的格局。

先來介紹一下計算區間漲跌幅的自訂函數，我寫的腳本如下:

 input:price(numericsimple);
 input:startday(numericsimple);
 input:endday(numericsimple);
 value1=getbaroffset(startday);
 value2=getbaroffset(endday);
 {if value1>value2
 then raiseruntimeerror("起始日期不能晚於結束日期");}

 value3=(price[value2]/price[value1])-1 ;
 rangechange=value3*100;

順便跟大家提幾個撰寫自訂函數腳本時，要稍加留意之處
1.自訂函數的名稱一定要是英文的。
2.在用input設定參數時，參數名稱後面括號後不能直接打預設值，而是要寫預設的資料格式，目前XS支援的資料格式分成三種，Numeric數值，String字串，邏輯值TrueFalse。細分是否傳值或傳址， 是否為陣列、序列、或是簡單型態，宣告的名稱如下:

3.最後一定要記得描述該自訂函數名稱的演算方式。例如在這個例子中一定要記得寫

rangechange=value3*100;

有了這個函數，要寫區間漲跌幅的選股腳本就容易多了:

input:startday(20150702,"區間起始日");
input:endday(20151002,"區間結束日");
input:ratio(10,"最低漲幅");

value1=rangechange(close,startday,endday);
if value1>=ratio
then ret=1;
 
value2=GetField("最新股本");
value3=GetField("月營收年增率","M");
value4=GetField("股價淨值比","D");
outputfield(1,value1,1,"區間漲跌幅");
outputfield(2,value2,0,"股本(億)");
outputfield(3,value3,1,"月營收年增率");
outputfield(4,value4,1,"股價淨值比");

這個腳本的outputfield的部份，為了觀察方便，可以像上面的寫法一樣，多加幾欄。

根據這個選股腳本，從今年一月三日到昨天，漲幅超過三成的股票如下:

一共35檔股票，從這些檔位中可以發現

1.股本除了中鴻144億之外，全部都在40億以下，30億以上的也只有鎧勝及揚智兩家。

2.接近三分之二的股票月營收年增率有兩位數成長

3.其中一半股價淨值比在二以下。

有了區間漲跌幅這個自訂函數，以及outputfield這個輸出特定資料欄位的語法，我們可以很快的挑出特定區間漲幅或跌幅超過一定比例的股票，並且以我們希望呈現的欄位，加以排序。這對我們在作功課時，有不少的幫助。

今年開紅盤以來 ，漲幅超過兩成的股票共有42檔，其中31檔股價在 50元以下，32檔最近一個月的月營收年增率是成長的，29檔本益比在20以下，其中有一部份是虧錢的公司，這些數字顯示，這一波的領頭羊是那些低PB且營運具轉機的個股，我稱之為價值型轉機股，今天來跟大家介紹一些這方面的選股腳本。

當我想知道現在是什麼類型的股票在帶頭上漲時，我會用底下的腳本去跑選股:

input:startdate(20160203);
input:ratio(15,"漲幅下限");
value1=getbaroffset(startdate);
if close[value1]<>0
then value2=(close-close[value1])/close[value1]*100;
if value2>ratio
then ret=1;
outputfield(1,value2,1,"區間漲跌幅");
outputfield(2,GetField("股價淨值比","D"),2,"股價淨值比");
outputfield(3,GetField("月營收年增率","M"),2,"月營收年增率");
outputfield(4,GetField("本益比","D"),1,"本益比");

這個腳本跑出來的股票，我透過股價，股價淨值比，月營收年增率及本益比四個面象，去判斷現在是流行成長股，價值型股，低價股/高價股，還是低本益比股。

從封關到昨天收盤為止，透過這個腳本選出來的，漲幅超過兩成的股票中，PB較低的股票如下:

我們會發現，這當中不少股票，最近一個月的月營收年增率有著明顯的成長。

這種股票，我幫它取了一個名字: “價值型轉機股”。

這種股票有兩個特徵:

1.股價跌到其市值低於其真實價值

2.營運最壞的時候過去了。

後者比較容易判斷，只要看月營收的數字即可，前者比較麻煩，什麼叫作真實價值呢? 有的股票適合用股價淨值比來衡量，有的適合用本益比來衡量，於是，我乾脆寫了一個腳本，把各種衡量價值型股票的常見方法全部寫出來，然後個股只要符合其中一個條件我就把它挑出來，然後再把這一整群的個股搭配營收是否成長的選股條件，這樣就可以找出所謂的”價值型轉機股”。

我寫的腳本共有六個:

一，本益比小於 15 倍 股價淨值比小於 2 倍 殖利率大於 3%

{本益比小於 15 倍 股價淨值比小於 2 倍 殖利率大於 3%}
if GetField("本益比","D") < 15 and
 GetField("股價淨值比","D") <2 and
 GetField("殖利率","D") > 3 and
 GetField("營收成長率","Q") >0 
  then ret=1;

這個腳本是最基本的篩選條件

二，用月營收推估的低本益比股

value1=GetField("月營收","M");//單位:億元
value2=GetField("月營收月增率","M");
value3=GetField("月營收年增率","M");
value4=GetField("營業利益率","Q");
value5=GetField("最新股本");//單位:億元
condition1=false;
condition2=false;
input:peraito(12);
setinputname(1,"預估本益比上限");
if value5<>0
then
value6=(value1*value4*12)/(value5*10);//單月營收推估的本業EPS
if value6<>0
then 
value7=close/value6;

if value7<peraito and value7>0

then ret=1;

這個腳本是用單月營收去推算來自本益的盈餘，然後再用這個盈餘去計算本益比

三，每股的流動資產遠大於股價

input:percent(20);
 setinputname(1,"每股易變現資產與股價間的落差比");
 value1=GetField("現金及約當現金","Q");//百萬;
 value2=GetField("短期投資","Q");//百萬
 value3=GetField("應收帳款及票據","Q");//百萬
 value4=GetField("長期投資","Q");//百萬
 value5=GetField("負債總額","Q");//百萬
 value6=GetField("最新股本");//單位: 億
 value7=(value1+value2+value3+value4-value5)/(value6*10);
 if value7>close*(1+percent/100)
 then ret=1;

這個腳本是找出那些每股可以快速變現的價值高於每股股價

四，流動性資產減負債超過市值N成

input:ratio(80,"佔總市值百分比%");
if (GetField("流動資產","Q")-GetField("負債總額","Q"))/100>GetField("總市值","D")*ratio/100
then ret=1;

這個腳本找出那些股價已經很接近淨流動性資產的股票

五，高現金總市值比的公司

//現金總市值比高的公司 
value1=GetField("現金及約當現金","Q");//單位百萬
value2=GetField("短期投資","Q");//單位百萬
value3=(value1+value2)/100;//單位億之現金及短期投資合計金額
value4=GetField("總市值","D");//單位:億
if value4<>0
then value5=value3/value4;//現金總市值比;
if value5>0.7 and value3>3 //現金總市值比大於0.7且現金及短投合計超過3億
then ret=1;

這個腳本是找出那些有大量閒置現金，但股價低的公司

六，高自由現金流量總市值比

input:ratio(50);
 setinputname(1,"近四季自由現金流總合佔總市值最低比率單位:%");
if (GetField("來自營運之現金流量","Q")+GetField("來自營運之現金流量","Q")[1]+
 GetField("來自營運之現金流量","Q")[2]+GetField("來自營運之現金流量","Q")[3]-
 GetField("資本支出金額","Q")-GetField("資本支出金額","Q")[1]
 -GetField("資本支出金額","Q")[2]-GetField("資本支出金額","Q")[3])
 >GetField("總市值","D")*100*ratio/100
 then ret=1;

這個腳本可以用來尋找那些有創造出高自由現金流量但股價低估的公司

我把這六項腳本全部放到一個選股法中，然後設定任何一檔個股只要符合這六項的其中兩項就被選出來

設定的畫面如下:

如些設定後挑出的股票共有269檔，我把符合條件較多項的列在下方

這269檔股票就是我們一般定義的價值型股，接下來我們就可以留意這269檔股票的營運是否出現轉機，若是出現轉機，就符合我所謂價值型轉機股的定義，而這種股票，應該會是今年大家買的較為安心的族群。

以上的流程，對於價值型股票的定義，大家可以自行調整或設計，但是尋找價值型轉機股的這個方法，大家不妨持續不斷地嚐試，小弟過往依賴這個方法，有不錯的實戰效果。

選股的招式百百款，有一招是當年入行時師兄們的入門款～高毛利低獲利但開始高成長的股票，這種股票因為低獲利，所以股價通常不高，但因為高毛利，一旦營收成長，對獲利的貢獻度就很明顯，等到最新財報公佈，數字經常會優於預期，挑股票就要挑會優於預期的，不然要挑什麼？　您說是吧（對不起，裝年輕，學一下泛舟哥！）

小弟剛入行的時候，call公司的時候，會遇見這領域的大咖研究員，從他們問上市公司的問題裡，偷學到很多，其中有一位大哥，別的研究員在問EPS之類的數字時他都很不屑，他問的都是那些今年再花多少資本支出？準備把錢花到那邊去？某個新產品的開發進度？等等很細的事情。

在有了一起抽過幾根煙的交情之後，有次趁一起抽煙的時候，我就很抖膽的請教他為何不問EPS？老是問那些很細的事情。

這位大哥跟我說，大家都知道的資訊無法創造比別人好的績效，要比別人強，就必須比別人看的早，他說我們CALL的這些公司，很多老闆都是看到時機來了，準備擴張，這樣的公司，之前在拼研發及佈局的時候，有很多的研發支出或行銷支出，這些支出都是營業費用，但因為營收還沒有達到經濟規模，所以會造成高毛利，但低獲利。可是一旦營收上來，而且不必再隨營收規模一直去作研發及行銷支出時，獲利就會很明顯的跳上來，我問的那些問題，就是想要找出這些公司裡有那一些公司已經開始進到這個階段，因為進到這種階段的公司，如果押對產品，後面的營收成長速度維持一定速度，但獲利會一直往上跳，這種公司何必去問下一季的EPS。

自從抽完那根煙，我覺得我的功力好像增加了一甲子，後來我自己也學著去尋找這種十年寒窗，但風生水起的公司。這類的公司，先前EPS不好，股價不高，所以我進場的價位都不算貴，但後來營收一跟上來，獲利三級跳，股價也跟著明顯上揚，那幾年我的績效裡，主要都是靠這類的股票在貢獻，反而是那些跟著上市公司發言人起舞的股票，總是來得快去的也快。

這些年離開了投信業，我基本上還是比較關注這樣的公司。

我最常以葡萄王為例，以前這家公司其實業績表現平平，但因為行業特性，毛利率一直都維持在三成以上，1997年它開發靈芝王，基本上就算開始要轉生技食品了，到了1998年它開始成立葡眾作直銷，這兩件事對它來說都是新的嚐試，也就是要花錢且短期看不到回報的事，所以它的財報裡到了1999年到2000年，本業其實都虧錢。

這樣的情況一直在持續，2001年到2003年它的營收從10億成長到12億，但EPS都是在五毛錢左右，even到了2004到2006年，營收也才再成長到14.9億，不過這時候EPS也明顯拉高到2.13元，這就是高毛利的好處，這家公司在最慘的時候毛利都還有三成，雖然營業利益率在2004年低到只有2.26%，但一旦後面營收衝上去，營益率很快跳到兩位數。

作為一個投資人，其實對我們最大的回報，就是這種高毛利低獲利的公司開始展開高成長的第一時間點，就被我們掌握住

去追蹤這樣的公司的好處是，因為先前獲利太差，所以沒有法人會來跟你搶，它的股價其實是到了2007年營收年增率明顯跳上去之後，才開始大漲。

為了不斷地尋找有這種可能的股票，我寫了以下的腳本

input:gr(45,"毛利率下限");
input:epsy(0.5,"最近一季每股稅後EPS上限");
input:gwr(10,"最近三個月營收yoy平均成長率下限");
value1=GetField("營業毛利率","Q");
value2=GetField("每股稅後淨利(元)","q");
value3=GetField("月營收年增率","M");
value4=average(value3,3);

 
if value1>= gr 
and value2<=epsy 
and value2>0
and value4>=gwr
then ret=1; 
outputfield(1,value1,0,"營業毛利率");
outputfield(2,value2,2,"最近一季EPS");
outputfield(3,value4,1,"最近三個月營收yoy平均成長率");

這個腳本要設定的參數如下圖

參數各位可以自行設定，資料讀取，最大引用及指定頻率這三項則千萬不要改錯。

用這腳本及設定，透過XS跑選股，今天挑出來的股票有53檔，毛利率較高的股票如下圖

這其中證券股及營建股因為營收的落點懸殊，應該濾掉，其他的股票值得我們後續持續去追蹤及研究。

我那些現實的朋友們，剛過完年，見面不說恭喜，也不慰問一下我這被地震搖的花容失色的災民，劈頭就問：＂這台股能買呢?　要買什麼？＂，今天就來跟大家分享一個市場老手在大跌後的選股策略：　＂急漲拉回轉強三部曲＂。

每次大盤回檔比較多之後，股市稍一轉強，就常被問：＂買什麼？＂

以前我也是問這問題的人。

後來有次問到一個我們營業檯的＂自營商＂，他教了我一招

當年電腦軟體不普及，他攤開財訊快報那一疊很厚的K線圖，然後叫我去挑那些

１．先前急漲

２．後來拉回

３．現在轉強

的股票

我把他的意思畫成下面這張圖

他說，根據他多年的觀察，很多後來基本面有所轉變，股價大漲數倍的股票，都先出現急漲，代表買的人知道未來會很好，所以很敢追價，但後來因為大盤不好，開始出現拉回，但拉回的幅度不會太大，且跌勢會比漲勢和緩，這種股票，一旦大盤好轉，開始轉強時，就要很留意。

我跟他說，當年我在當外匯交易員時，有稍稍學了點波浪理論，他的說法，很像五波中的第一跟第二波，他說：　孺子可教也。

事隔多年，我只記得他跟我說，先前急漲如果愈急且放量，愈要留意。

現在有了XS，我試著寫了一個腳本：

//波段高點距今一段時間
//起算點到波段高點不算長且漲幅不小
//波段高點到昨日收盤有一定的拉回幅度
//今天開高，出量且相對走強
var:period(20);//波段天期
input:up(25,"上漲幅度");
input:down(15,"上跌幅度");
value1=highest(high,period);
value2=highestbar(high,period);
value3=q_CashDirect;//成交比重
value4=q_OrderRatio;//委託買賣差佔總委託比
condition1=false;
condition2=false;
condition3=false;
for period=20 to 60
begin
if value1>=close[period-1]*(1+up/100)
then condition1=true;
//波段漲幅不小
if value2>period/3
then condition2=true;
//起算點到波段高點時間不算長
if close[1]<value1*(1-down/100)and close[1]>close[period-1]
then condition3=true;
//波段高點到昨日收盤有一定的拉回幅度
if condition1 and condition2 and condition3
and open>=close[1]*1.015//開高
and value3>average(value3,5)//量增
and value4>average(value4,5)//委買增

then ret=1;
end;

這個腳本其實沒有太考慮先前是否是急漲，只是挑出那些先漲後拉回再轉強的股票，如果要精確地挑出那些先前是急漲的股票，還需要作更多的定義，不過我想拋磚引玉，大家不妨以這個腳本為樣本，再自行調整修改成勝率更高的第三波主昇波起漲點腳本。