Author Archives: 發財橘子

在被問到台灣原生的程式語法平台跟Mutichart，Tradestation，HTS有什麼不一樣的地方時，籌碼相關的應用是我常常提到的一個亮點，籌碼分析的應用基本上分成內外盤，委買委賣，買進賣出分公司家數，法人，資券以及每筆成交張數等幾個方面的相關欄位，以下就根據不同的資料型態，一一來報告這些台股籌碼特殊欄位，如何被應用到程式交易裡。

首先，先整理一下，在自訂指標，策略雷達及選股時，可以使用的籌碼分類大致如下圖：

詳細的欄位如下表：

這麼多的欄位，要如何在設計腳本時拿來使用呢?

作法上跟取得其他欄位的方法是一致的，都是運用getfield這個語法，例如我們如果想要拿”控盤者成本線”這個欄位來畫圖，腳本可以這麼寫:

value1=GetField("分公司買進家數");
value2=GetField("分公司賣出家數");
value3=GetField("分公司交易家數");

plot1(value1,"分公司買進家數");
plot2(value2,"分公司賣出家數");
plot3(value3,"分公司交易家數");

這樣一來就可以把這些籌碼相關的欄位變成自設指標畫在圖上了。

這麼多的籌碼欄位，應該如何應用呢? 底下這張圖可以做個參考。基本上，大股東及法人站在買方，後市看好的機率大些，反之則下跌的機率較高。

那麼要如何分辨今天大股東及法人是站在買方或賣方呢?

未來幾天，我們來陸續介紹各種這些籌碼欄位的運用方法，來分辨大股東及法人，主力是站在買方還是賣方

今天，先來介紹的這個方法，是結合法人進出表及分公司進出表兩個不同的公佈數字，很單純地就只看每一天的買盤來源:

我設計的腳本如下:

input:period(5,"短移動平均線天期");
input:period1(20,"長移動平均線天期");
value1=GetField("主力買張");
value2=GetField("實戶買張");
value3=GetField("散戶買張");
value4=GetField("控盤者買張");
value5=GetField("法人買張");
value6=value1+value2+value3+value4+value5;
//合計的買張數當分母，這有可能超出成交量
value7=value1+value4+value5;
//主力+法人+控盤者的買張合計作為大戶的買張
if value6<>0
then value8=value7/value6*100;
//計算大戶買張佔各方勢力買張的比例
value9=average(value8,period)-average(value8,period1);
if value9>0
then 
begin
value10=value9;
value11=0;
end
else
begin 
value11=value9;
value10=0;
end;
plot1(value10);
plot2(value11);

我稱這個指標為買張大戶散戶分佈線，我把最近大家比較關注的股票用這個指標來呈現目前大戶法人主力是站在買方還是賣方?

從上面這幾張圖就可以發現，我們其實透過散戶與大戶佔買張比例的變化，可以清楚的看到當大戶比重持續上昇時，籌碼被收集後股價都較有表現的機會，反之則都屬於偏空或盤整的格局。

從這個例子我們就可以發現，當我們把所有可以拿來作運算的籌碼欄位都攤開來時，擷取其中一些欄位，加以運算，往往就可以自行創造出一些有意義且具有參考價值的指標，再從指標的共同特徵中進一步撰寫出創新的交易策略，把籌碼分析裡的龐大數據轉換成可以拿來決定交易策略的工具，這樣創造出來的策略，再和其他透過價量等數據所創造出來的交易策略結合，目標就是希望創造出勝率更高的交易策略，這種使用更多客觀數據來作交易決策的方法，就是孫子兵法中的”多算勝，少算不勝”的道理吧。

看到一篇寫的很好的文章，推薦給朋友們

http://www.stockfeel.com.tw/%E5%BE%9E%E9%96%B1%E8%AE%80%E5%84%AA%E8%B3%AA%E5%85%AC%E5%8F%B8%E9%96%8B%E5%A7%8B%EF%BC%8C%E7%B7%B4%E7%BF%92%E4%BB%A5%E4%B8%8D%E5%90%8C%E8%A7%92%E5%BA%A6%E6%80%9D%E8%80%83%E4%BA%8B%E6%83%85/

這篇文章來自stockfeel這個網站，這裡的文章寫的真的不錯，能對我們的投資思考有所啟發。

這篇文章的主軸是，就算覺得股價太貴不想買，但還是可以研讀一下那些成功公司的財報，了解這些公司成長的過程，找到一些蛛絲馬跡，再把這些蛛絲馬跡，應用在那些正準備冒出頭的公司上，讓我們可以在新興好公司才剛冒出頭時，就挑到他們。

從這篇文章裡，我學到了一些尋找明日之星的方法。

1。找擁有定價能力（pricing power)，高投資報酬率的公司。

2。尋找那些費用在下降，但營收在成長的公司，來自營運的現金流量在成長的公司。

3。尋找有規模經濟的商業模式，並且比別人提早看到未來會勝出的公司。

我試著用一些簡單的選股標準來尋找符合上述條件的股票

1。毛利率穩定。擁有定價能力的公司，毛利率應該丕至於持續下滑。

2。ROE達一定水準。高投資報酬率的公司，ROE不會太差。

3。來自營運的現金流量穩定成長中。

4。營收成長，但營業費用在減少。

我先試著尋找那些毛利率沒啥掉的公司，所以我寫了一個腳本如下：

value1=GetField("營業毛利率","Q");
input:ratio(10,"毛利率單季衰退幅度上限");
input:period(10,"計算的期間，單位是季");

if trueall(value1>value1[1]*(1-ratio/100),period)
then ret=1;

如果再加上連續兩年來自營運之現金流量成長的條件，符合的股票只剩下68檔，名單如下：

若是我換另一個角度，去尋找那些營收上昇且費用在降低的股票，於是我就寫了一個腳本如下：

value1=GetField("營業收入淨額","Q");//單位百萬
value2=GetField("營業費用","Q");//單位百萬
input:period(5,"計算的季別");
input:count(2,"符合條件之最低次數");

if countif(value1>value1[1]and value2<value2[1],period)>=count
then ret=1;

這個腳本如果參數是設過去七季有三季以上營收成長費用衰退時，共挑出了72檔股票，名單如下：

如果把這兩個條件合在一起，腳本可以這麼寫

value1=GetField("營業毛利率","Q");
value2=GetField("營業收入淨額","Q");//單位百萬
value3=GetField("營業費用","Q");//單位百萬
input:ratio(10,"毛利率單季衰退幅度上限");
input:period1(10,"計算的期間，單位是季");
input:period2(5,"計算的季別");
input:count(2,"符合條件之最低次數");

if trueall(value1>value1[1]*(1-ratio/100),period1)
and 
countif(value2>value2[1]and value3<value3[1],period2)>=count
then ret=1;

這樣挑出來的股票共有十八檔，名單如下：

透過這樣的方式可以節省不少一檔檔挑個股的時間，不過像有沒有經濟規模這種篩選條件，就有賴於仔細去了解該公司所處產業才能知曉的。

Anyway，讀到一篇好文章，是幸福，用好文章寫出選股程式，是更大的幸福，寫完後可以分享給大家參考，是大大的幸福。

去年 6月1日起單日漲跌幅限制從7%放大到10%，今年2月1日起，可以進行現股當沖的標的，開放到只要有信用交易就可以，所以可以現股當沖的股票，上市櫃加起來有1432檔，涵蓋了超過90%的上市櫃股票。這種制度上的變化，讓個股當沖交易成為一個比以前更值得研究的領域。不過由於現股當沖的交易成本，不考慮退佣的話是0.585%，就算有退佣，也差不多到千分之四到千分之五之間，所以要長期以現股當沖來累積財富，勢必要有一套尋找當日波動幅度大股票，並且在股價波動的起始點就進場的策略，今天想跟大家報告的，就是我對這個領域的研究心得。

我的研究方法分成幾個部份

一，先找出自去年六月一日以來，所有有信用交易股票，每日震盪幅度的總合，然後透過排序，去尋找那些股票波動幅度比較大。透過這個方法，先濾掉那些大牛股。

二，把濾掉大牛股之後的股票，找出它們這幾個月來曾經漲停的日子，然後去分析當日的波動型態

三，尋找這些當日漲停個股的共同特徵，寫成交易策略

四，透過回溯測試，修正交易策略

經過了這陣子的測試之後，我想要分享的當沖交易策略有三個，

第一個開高後不拉回

input:Ratio(2.5); setinputname(1,"開高幅度%");
 input:aRatio(1); setinputname(2,"拉回度%上限");
 input:TXT("僅適用於15分鐘以內"); setinputname(3,"使用限制"); 
if barfreq ="Min" and barinterval <=15 
and time <= 091500 
and q_DailyOpen > q_RefPrice *(1+Ratio/100)
 and q_Last > q_DailyHigh* (1- aRatio/100) 
then ret=1;

 以下是這類股票的示意圖

第二個則是橫向盤整後的旱地拔葱

if barfreq <> "Min" or barinterval <> 1 then RaiseRuntimeError("請設定頻率為1分鐘");
variable:KBarOfDay(0); if Date<> Date[1] then KBarOfDay = 1 else KBarOfDay+=1;


input:P1(60); setinputname(1,"狹幅盤整計算期間(分鐘)");

if high = q_DailyHigh and {來到今日最高價}
 KBarOfDay > 30 and {今日至少有30根K棒交易}
 TrueAll( AbsValue(Close[1]/Close[2]-1) < 0.005,KBarOfDay-1) and{必需只有小波動}
 AbsValue( Close[1]/Close[KBarOfDay-1]-1 ) < 0.02 {開盤到前分收K不超過2%}
then ret=1;

以下是這類股票的示意圖

第三個則是階段式向上

input:TXT1("僅適用1分鐘線"); setinputname(1,"使用限制");
input:TXT2("只於9:10判斷"); setinputname(2,"使用說明");

if barfreq = "Min" and barinterval = 1 and time =91000 and
 TrueAll(close >Close[1] ,10) then ret=1;

以下是這個腳本的示意圖

這三個腳本先前都介紹過，如果用1500檔股票去洗，出來的股票上漲的機率並不是那麼高，但我在研究那些失敗的股票後發現，當個股盤中出現上述三種走勢之後，最後無法順利收高的股票，往往有三種共同的特徵

1.先前成交量不大，意思是一個小咖咖的起心動念，就足以造成交易策略的訊號被觸發。等到小咖咖買完了，我們再進場，剛好套到最高點。

2.前幾天已有明顯上漲，今天再拉高馬上踫到獲利了結賣壓。

3.大盤偏空，指數出現較大的下挫，覆巢之下，個股很難收高。

於是我用以下的腳本來選股

input:b1(1.5,"三日漲幅上限");
if volume*close>=30000
and close<=close[2]*(1+b1/100)
then ret=1;

這個選股腳本要挑的股票必須符合兩個條件

1。前一日成交值超過3000萬

2。過去三個交易日漲幅很小。

並且把選出來的股票，只有在大盤週線在月線之上才開始啟動上述三個交易策略，讓符合上述三種情況的個股，在盤中送出訊號給我。

這是到目前為止，比較有機會有差價的先買後賣當沖策略腳本，我會繼續測試，有新的方向再跟大家報告。

這次AlphaGO的三勝一敗，讓人工智慧，再次回到聚光燈下。

我在開發交易策略的過程裡，深深體會人與機器之間那種1+1>2的力量，我認為人們運用機器大量運算，測試，不斷地學習改進，是找出有價值交易策略的一條更行之道。

把程式交易視為毒蛇猛獸，跟把人工智慧視為機器統治人類的前兆一樣，無法改變及面對機器運算能力持續進步的趨勢。

善用機器愈來愈強大的運算能力，可以讓人們收集整理分析及決策的力量，也跟著變大。

今天我想舉一個交易策略的形成過程作例子，說明機器的強大運算能力，可以協助我們做到什麼地步。

我經常跟大家分享的一個交易策略叫多次到頂而破。

一開始是我師父讓我把創新高的股票用Excel整理出來，每天送給他，後來我發現，不是每檔創新高的，接下來就一定會創新高，但那些衝了幾次都沒衝過去的高點，一旦衝過去了，後面都還會漲，所以我就寫了一個多次到頂而破的交易策略，腳本如下:

input:day(100);
input:band1(4);
setinputname(1,"計算區間");
setinputname(2,"三高點之高低價差");
value1=nthhighest(1,high[1],day);
value2=nthhighest(3,high[1],day);
value4=nthhighestbar(1,high,day);
value5=nthhighestbar(3,high,day);
value6=nthhighestbar(5,high,day);
value7=absvalue(value4-value6);
value8=absvalue(value5-value6);
value9=absvalue(value4-value5);
condition1=false;
if value7>3 and value8>3 and value9>3
then condition1=true;
value3=(value1-value2)/value2;

if value3<=band1/100
and close crosses above value1
and volume>2000
and condition1
then ret=1;

這個腳本是去找過去100根Bar中的最高三個點，而且高點之間差距都超過三根bar，且三個高點最高與最低差不超過4%

結果挑出來的股票例如昨天是跳出志聖2467與帛漢3299，跟我心理想的多次到頂而破有不少的差距，我心中的是像下面這張圖的樣子

後來這個腳本後來經過我同事的修改，變成以下的腳本

input:HitTimes(3); setinputname(1,"設定觸頂次數");
input:RangeRatio(1); setinputname(2,"設定頭部區範圍寬度%");
input:Length(20); setinputname(3,"計算期數");

settotalbar(300);
setbarback(50);

variable: theHigh(0); theHigh = Highest(High[1],Length); //找到過去其間的最高點
variable: HighLowerBound(0); HighLowerBound = theHigh *(100-RangeRatio)/100; // 設為瓶頸區間上界
variable: TouchRangeTimes(0); //期間中進入瓶頸區間的低點次數,每跟K棒要歸0
 
//回算在此區間中 進去瓶頸區的次數 
TouchRangeTimes = CountIF(High[1] > HighLowerBound, Length);
 
if TouchRangeTimes >= HitTimes and ( q_ask> theHigh or close > theHigh) then ret=1;

這個腳本就是XS雲端策略中心裡的多次到頂而破的腳本。

不過透過這個腳本挑出來的股票，勝率還是很不穩定。

後來，我看到底下這本書

書中有特別強調，要挑這些創新高的股票時，應該要留意其基本面是很穩固的，創新高代表的是更上一層樓的意思，因此我就不再把1500檔股票去拿去跑這個腳本，也是改成用過去五年每年ESP都超過0.5元的選股條件先把1500檔縮小範圍，然後再去跑，這樣目標族群就從1500檔縮小到484檔

透過這樣的過濾條件，在多頭市場這個腳本的勝率已經令我滿意，但在空頭市場還是當會追高後被套，於是我再設定，只有在加權指數週線在月線之上時，這個策略才開始執行。

到這裡，我算是完成了一個令我覺得還OK的交易策略。

回顧整個交易策略的演進，其實就像是下圖一般，不斷演進的過程，

這個過程裡，最大的敵人其實就是懶惰，我常被反應照某個腳本去賭會輸錢，然後呢? 其實該做的是找出那個腳本輸錢的股票具有什麼特色? 進一步根據這些特色去調整腳本，看是加濾網，還是調整腳本，最不該做的事情是: 放棄。

我認為，放棄電腦強大的運算能力，想靠經驗及直覺在市場上討生活的人，會像末代武士一樣，刀法很厲害，但別人都用槍。