Author Archives: 發財橘子

有多位朋友不約而同的提到如何透過語法去描述兩個時間序列的”背離”，我試著用線性回歸的角度來跟大家分享我自己設計的”背離”腳本。

首先，XS內建函數中有一個叫作線性回歸斜率(linearregslope)，如果您在腳本編輯器中按F1，會跳到函數的說明頁，您輸入linearregslope按enter，會看到以下的說明

什麼是線性迴歸呢?

就像上圖一樣，我們找出一條線， 這條線距離所有要計算的價位最近，就是所謂的線性迴歸，透過線性迴歸，我們可以找出價位群體的方向，這條線的斜率就是linearregslope。

當數據呈現上昇分佈時，線性迴歸的斜率是正的，下降分佈時，線性迴歸的斜率是負的。

我就是運用這個原理，寫出以下的背離函數

input:price(numericsimple),index1(numericsimple),length(numericsimple);
if length<5
then raiseruntimeerror("計算期別請超過五期");
value1=linearregslope(price,length);
value2=linearregslope(index1,length);

if value1>0 and value2<0
then deviate=-1
else
if value1<0 and value2>0
then deviate=1
else
deviate=0;

透過這個函數，我們就可以比較兩個數列，看看他們是否出現背離的情況，這個函數的寫法是當第一個值下跌而第二個值上昇時，函數的回傳值是 1 ，相反的則是-1 ，若兩個值同方向則是傳回0。

假設我們想找出收盤價下跌，但跟10日RSI上昇的股票，我們就可以運用這個函數，寫出下面這樣的腳本

value1=rsi(close,10);
if deviate(close,value1,10)=1
then ret=1;

透過這個函數，我們就可以隨時把兩個時間序列拿出來檢定是否有背離的現象了。

前天提到我朋友是價值型投資者，挑了一些股票讓我幫他寫盤中進場點的策略。

今天來分享他挑股票的邏輯

他挑的價值型股票基本上有三個原則

1.股價遠低於每股淨值。他認為這種股票有行情時走的比較遠。

2.來自營運的現金流量有達到一定水準。不然就會變成坐吃山空的股票。

3.流動資產減負債的淨額要超過總市值一定比例。

我根據這三個原則，設了一個選股法

其中第一條是一個我自己寫的選股腳本，內容如下:

input:ratio(80,"佔總市值百分比%");
if (GetField("流動資產","Q")-GetField("負債總額","Q"))/100>GetField("總市值","D")*ratio/100
then ret=1;

根據這三個條件選出來的股票如下圖

我們可以發現，除了證券股之外，大部份都是這幾年營運陷入衰退的公司，所以總市值才會跌到這麼低，不過由於營運現金流量達到一定的水準，代表這種公司元氣還在，就等轉型有成，找出一條新的路

這些公司，就讓電腦幫著留意盤中價量是否出現變化，畢竟春江水暖鴨先知，股價往往走在轉機消息的前面。

各位可以自行調整這三個條件的參數， 或是再加些條件， 調成你自己的價值型投資原則

先前有提到資深業內會進場的型態之一是平台整理後的突破與跌破，就像下面這個圖這樣的走勢。

剛好XQ系統內建有一個專門找出這種股票的腳本，我就直接PO上來給大家參考。

input:LS(0); setinputname(1,"多空設定");
settotalbar(300);
setbarback(50);

variable:HP(0);HP = Highest(H[1],20);
variable:LP(0);LP = Lowest(L[1],20);
variable:MID(0); MID = (HP+LP)/2;
variable:Q1(0); Q1 = (HP+MID)/2;
variable:Q2(0); Q2 = (MID+LP)/2;

variable:i(0),j(0);

j=0;
for i = 1 to 20
begin
if (C[i] > MID and C[i+1]< MID) or
 (C[i] < MID and C[i+1]> MID) then j+=1;
end;

condition1 = HP > LP*1.14 and j >8 and average(v,20)>200;

if LS>0 and H >HP and condition1 then ret=1;
if LS<0 and L <LP and condition1 then ret=1;

為了讓大家對程式交易有一個比較友善的學習途徑，安排了七堂課程

以下分別是這些課的課綱，投影片及影音檔

【課程影音檔】連結如下：

● 第一堂 ➤https://youtu.be/fLtjeLpyqdI

● 第二堂 ➤https://youtu.be/FHicmJETp5Y

● 第三堂 ➤https://youtu.be/IXhk4cv53Ho

● 第四堂 ➤https://youtu.be/fBmv__O3lj0

● 第五堂 ➤https://youtu.be/KCMCW1WDhLc

● 第六堂 ➤https://youtu.be/SeQQgsuzUPU

● 第七堂 ➤https://youtu.be/7RGb2AZNa_s

【投影片檔下載點】連結如下：

● 第一堂下載點 ➤https://xqcom.pse.is/4b3ma5

● 第二堂下載點 ➤https://xqcom.pse.is/47sclj

● 第三堂下載點 ➤https://xqcom.pse.is/4b4muu

● 第四堂下載點 ➤https://xqcom.pse.is/4aaly4

● 第五堂下載點 ➤https://xqcom.pse.is/4baequ

● 第六堂下載點 ➤https://xqcom.pse.is/4as7wz

● 第七堂下載點 ➤https://xqcom.pse.is/4a3q9d

這一波快速的拉回，到昨天指數跌了500點，個股跌超過15%的一大堆，小弟我很慘，有一檔股票跌了兩成，之所以這麼慘，是因為前幾天的下跌時我在忙，看它跌多了就想說等反彈再來賣，沒想到後來就一直破底。

為了防止這樣的慘案再次發生，我今天寫了一個腳本，準備搭配XQ新開放的自動下單機制，讓電腦幫我賣股票。

這個腳本如下:

//DMI賣出訊號
 input:Length(14); setinputname(1,"計算期數");
 variable: pdi(0), ndi(0), adx_value(0);
 DirectionMovement(Length, pdi, ndi, adx_value);
 if pdi<pdi[1] and ndi>ndi[1] and ndi crosses over pdi
 then ret=1
 else begin
   //KD高檔死亡交叉
   input: Length1(9), RSVt(3), Kt(3), HighBound(75);
   SetInputName(1, "計算期數");
   SetInputName(2, "RSVt權數");
   SetInputName(3, "Kt權數");
   SetInputName(4, "高檔區");
   variable: rsv(0), k(0), _d(0);
   Stochastic(Length1, RSVt, Kt, rsv, k, _d);
   if k>HighBound and k crosses under _d
   then ret=1
   else begin
     //MTM由正轉負
     input: Length2(10); SetInputName(1, "期數");
     if momentum(close,Length2) crosses under 0
     then ret=1
     else begin
       //投信法人都賣超
       if Open < Close[1] and Close < Close[1] and
          GetField("外資買賣超")[1]<0 and GetField("投信買賣超")[1]<0
       then ret=1
       else begin
         //MACD出現賣出訊號
         input: FastLength(12), SlowLength(26), MACDLength(9);
         SetInputName(1, "DIF短期期數");
         SetInputName(2, "DIF長期期數");
         SetInputName(3, "MACD天數");
         variable: difValue(0), macdValue(0), oscValue(0);
         MACD(weightedclose(), FastLength, SlowLength, MACDLength, difValue, macdValue, oscValue);
         if oscValue Crosses Below 0
         then ret=1
         else begin
           //RSI高檔死亡交叉
           input: Length4(6); SetInputName(1, "短期期數");
           input: Length5(12); SetInputName(2, "長期期數");
           input: HighBound1(75); SetInputName(3, "高檔區");
           value1=RSI(close,Length4);
           value2=RSI(close,Length5);
           if value1 crosses under value2 and value1>HighBound1
           then ret=1
           else begin
             //一舉跌破多根均線
             input: shortlength(5); setinputname(1,"短期均線期數");
             input: midlength(10); setinputname(2,"中期均線期數");
             input: Longlength(20); setinputname(3,"長期均線期數");
             variable: shortaverage(0);
             variable: midaverage(0);
             variable: Longaverage(0);
             shortaverage=Average(close,shortlength);
             midaverage=Average(close,midlength) ;
             Longaverage = Average(close,Longlength);
             if close crosses under shortaverage and
                close crosses under midlength and
                close crosses under Longaverage
             then ret=1;
           end;
         end;
       end;
     end;
   end;
end;

透過這個腳本，只要系統有出現以下七種狀況的其中一種，電腦就會自動通知我

1.DMI賣出訊號

2.KD高檔死亡交叉

3.MTM由正轉負

4.投信外資都賣超

5.MACD出現賣出訊號

6.RSI高檔死亡交叉

7.一舉跌破多根均線

然後把這個腳本拿去設成策略雷達，設定的畫面如下

執行商品設成庫存，如此一來，當出現賣出訊號時就會通知我了。

如果您的交易戶XQ有Support 的話，您也可以像我一樣，直接把單子下出去，不過目前這功能必須自行填交易張數，不能自動帶庫存。

今年的12月到現在為止，跌的好慘，往年我們都會期待有個所謂的年底作帳行情，當然也會想趁著十二月如果股價下跌時，買點便宜貨，因為等到明年一月，我們就可以坐等所謂的元月效應。

下面這張圖是加權指數的月線圖，過去幾年，十二月份及一月基本上都是漲多跌少，如果十二月跌多了，一月是長紅，只有2014年的元月是收黑。

所以一直以來，我都有一個”十二月找會作帳的股票”這樣的交易策略。

通常我都是找那些明年業績不會更差，今年沒啥漲到，往年年底都會拉一波的集團股。

以前最有名的是亞東集團的股票，不過這兩年這集團好像就沒有像以前那麼愛作帳。

今年有XS這個工具，所以我就改成用寫腳本，找過去幾年十二月份月線漲超過5%的股票。

我寫的腳本如下:

value1=getbaroffset(20141201);
value2=getbaroffset(20141231);
value3=getbaroffset(20131201);
value4=getbaroffset(20131231);
value5=getbaroffset(20121201);
value6=getbaroffset(20121231);
value7=getbaroffset(20111201);
value8=getbaroffset(20111231);
input:r1(5,"最低月報酬率%");

if close[value2]>close[value1]*(1+r1/100)
and close[value4]>close[value3]*(1+r1/100)
and close[value6]>close[value5]*(1+r1/100)
and close[value8]>close[value7]*(1+r1/100)
then ret=1;

挑出來的股票如下表。

不過這邊要特別說明幾件事

1.挑出來的都是過去四年每年十二月月線都漲超過5%的股票，但要濾掉那這幾年業績好靠業績支撐的股票。

2.有些產業有季節性因素，年底到農曆年前是旺季，例如遊戲類股。

3.上面用到一個函數叫getbaroffset

需要特別說明一下

getbaroffset這函數是您只要在函數的括號中填入某個日期，系統會回傳這個日期是最後一根bar之前的第幾根bar。

例如今天是12月10日，如果你寫value1=getbaroffset(20151209)，那麼電腦會傳回value1=1，因為12/09是今天這根bar的前”1″根。

這個函數在計算特定區間相關數據時非常有用。